Replace include

Hvad er der i din Tagwall/index.asp fil?
Hvis det er en string kan du vel bare inkludere den ovenfor og bruge stringen?

<!-- #include file='Tagwall/index.asp'-->

<%besked = Replace(rs("text"),"[gæstebog]",strReplaceWith)
Response.Write besked%>

I min Tagwall/index.asp er der en gæstebog... Det skal bruges da admins selv skal kunne indsætte gæstebogen hvordan den skal være.. Så når de skriver at der på selve siden skal være [gæstebog] skal den hentes der inde fra... Ved ikke om det skal gøres på en helt anden måde?

Ligger gæstebogen som html-kode, eller bliver den generet af asp til en htmlkode?

Den bliver genereret af ASP... Altså ikke ren HTML i den...

Måske noget i denne stil. Den kan klare flere tags.

<%
Function GuestBook
    %><!-- #include file='Tagwall/index.asp'--><%
End Function

Function TestFunktion
    Response.Write "en test"
End Function

Function ParseText(str)
    Dim dic, re, pos, match, matches

    Set dic = Server.CreateObject("Scripting.Dictionary")
    dic.Add "gæstebog", "GuestBook"  'ved "gæstebog" kald GuestBook-funktionen
    dic.Add "test", "TestFunktion"
   
    Set re = New RegExp
    re.Global = True
    re.IgnoreCase = True
    re.Pattern = "\[(gæstebog|test)\]"  'find alle gæstebog og test
   
    Set matches = re.Execute(str)
   
    pos = 1
   
    For Each match In matches
        Response.Write Mid(str, pos, match.FirstIndex-pos+1)
        pos = match.FirstIndex + match.Length + 1
        Execute "Call " & dic(match.SubMatches(0))
    Next

    If pos <= Len(str) Then Response.Write Mid(str, pos)
End Function


besked = rs("text")
ParseText(besked)
%>

Hvis jeg skal have flere funktioner med, skal jeg så bare tilføje noget her:
Function kal
    %><!-- #include file='Kalender/index.asp'--><%
End Function

dic.Add "kalender", "kal"  'ved "kalender" kald GuestBook-funktionen

    re.Pattern = "\[(gæstebog|test|kalender)\]"  'find alle gæstebog og test

Right?

Havde helt glemt det, men det virkede.. :-D Kom endeligt med et svar.. :-D

Vil du ikke have dine point?

morhan?

Jeps.. morhan

?

lukketid