oprette mapper hvis de ikke findes udfra celle navn

Jeg har ingen tests lavet, så det må du lige selv kigge på, og noter også, at jeg ændret på dit fil name i denne demo :-)

Public Sub Demo()
    Dim sDrive As String
    Dim sPath As String
    Dim sFileName As String
    Dim sKundeNr As String
    Dim sFakturaNr As String
   
    ' Variabel værdier
    sKundeNr = Sheets("faktura").Range("faktura_kundenr").Value
    sFakturaNr = Sheets("faktura").Range("faktura_nr").Value
    sDrive = "G:\"
    sPath = sDrive & "\document\"
    ' Check om mappe eksisterer ellers opret en mappe
    If Not CBool(Len(Dir(sPath & sKundeNr & "\", vbDirectory))) Then
        ChDrive sDrive
        ChDir sPath
        MkDir sKundeNr
    End If
    sPath = sPath & sKundeNr & "\"
   
    sFileName = sPath & "FakturaNr_" & sFakturaNr & "_" & sKundeNr & ".pdf"
   
    ' Check om fil eksisterer - Gem/Advarsel
    If Not CBool(Len(Dir(sFileName))) Then
        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=sFileName, _
            Quality:=xlQualityStandard, IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, OpenAfterPublish:=True
    Else
        MsgBox ("Der findes allerede en fil med dette navn")
    End If
End Sub

Den virker lige efter hensigten.
Mange tak for hjælpen

:-)

Lige et lille tillægsspørgsmål.

Hvis filen findes i forvejen. Kan man så få den til at slette / overskrive den gamle fil istedet for at give mig meddelelsen om at filen allerede findes?

Mener at ExportAsFixedFormat automatisk overskriver... så test ved at inaktivere lidt kode...

    ' Check om fil eksisterer - Gem/Advarsel
    If Not CBool(Len(Dir(sFileName))) Then
        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=sFileName, _
            Quality:=xlQualityStandard, IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, OpenAfterPublish:=True
    Else
        MsgBox ("Der findes allerede en fil med dette navn")
    End If


så det kommer til at se sådan ud - så der kun køres en linie


    ' Check om fil eksisterer - Gem/Advarsel
    'If Not CBool(Len(Dir(sFileName))) Then
        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=sFileName, _
            Quality:=xlQualityStandard, IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, OpenAfterPublish:=True
    'Else
    '    MsgBox ("Der findes allerede en fil med dette navn")
    'End If

Det overskriver desværre ikke automatisk.

Hvis der findes en fejl stopper koden i den linje der gemmer filen.
Så jeg tror vi skal ud i at slette filen først.

sæt denne ind lige før du gemmer
  If CBool(Len(Dir(sFileName))) Then Kill (sFileName)

Det viker 100%
Ikke mindst nu hvor det oprindelige spørgsmål er besvaret. :-)

Jeg mente:

Tusind tak for hjælpen....
Ikke mindst nu hvor det oprindelige spørgsmål er besvaret. :-)