HJÆÆLP -=HASTER=-

på http://borrisholt.com finder du dels en løsning på hvordan du laver en rulle tekst, den liggerunder VCL hack.

Der udover er der også under Grapichs nogle grafik biblotekter til brug for folk der bil leje lidt meg grafik ...

Jens B

Jo men hvis du flytter selve componenten vil det altid flikker lidt.

Hvad er det for en component du flytter?

har du hentet eksemplet ?

Jens B

nej det vil ikk jeg ved ikk om det er min computer der pludselig ikk vil hente

og det er når jeg flytter TLabel at det hakker (skulle gerne være gennemsigtigt samme tid

og hvilken af disse er det???
ScrollText.zip (3,02 Kb)
VerticalText.zip (1,69 / 2,79 Kb)

Undgå at flytte component og tegn ligesom borrisholt(selv om det også er lidt svær kode at lave for mig)

i scroll eksemplet er teksten ikke gennemsigtigt og jeg kan ikke brgue fade eksemplet da det ikk forklarer hvorfor min egen kode er langsomere

cautoo  >>
det er ScrollText.zip du skal bruge. Du skal bare lave baggrunden transperent. Det er ikke så svært.
  Problemet med din kode er du au ændere een pixel af gangen og så tegner skærmen op. Det må nødvendig vis gå galt !

Jens B

jamen hvordan gør jeg så dette hutigere????

procedure TForm1.Button2Click(Sender: TObject);
var
  r,g,b: Integer;
  r1,g1,b1: Integer;
  X, Y: Integer;
  tal: Integer;
begin
  tal := TrackBar1.Position;
  Image3.Height := Image1.Height;
  Image3.Width := Image1.Width;
  for Y := 0 to Image1.Height do
  begin
    for X := 0 to Image1.Width do
    begin
      r:=GetRValue(Image1.Canvas.Pixels[x,y]);
      g:=GetGValue(Image1.Canvas.Pixels[x,y]);
      b:=GetBValue(Image1.Canvas.Pixels[x,y]);
      r1:=GetRValue(Image2.Canvas.Pixels[x,y]);
      g1:=GetGValue(Image2.Canvas.Pixels[x,y]);
      b1:=GetBValue(Image2.Canvas.Pixels[x,y]);
      r := Round((r/100*tal) + (r1/100*(100-tal)));
      g := Round((g/100*tal) + (g1/100*(100-tal)));
      b := Round((b/100*tal) + (b1/100*(100-tal)));
      Image3.Canvas.Pixels[x,y] := RGB(r,g,b);
    end;
  end;
  Label5.Caption := IntToStr(100-TrackBar1.Position);
  Label6.Caption := IntToStr(TrackBar1.Position);
end;

cautoo  >>
  Nu fortæller du ikke hvor mange farver der er i din bitmap der gik jeg ud fra der var 24Bit. Jeg loader mine bitmaps fra filer, me de kunne ligeså godt kommer fra en image kontrol. (vist i den ud kommenteret tekst.


  Jeg har med vilje ikke skrevet kommentarer til koden, fordi jeg syned du skal gøre det, fordi deraf får du forståelsen af hvad der sker. Det må være din opgave at re publicere koden med kommentarer, samt forklare den måbende hob hvordan det her skidt virker.


const
  PixelCountMax = 32768;

type
  pRGBArray  = ^TRGBArray;
  TRGBArray  = array[0..PixelCountMax-1] of TRGBTriple;
  EImageProcessingError = class (Exception);

procedure TForm1.Button2Click(Sender: TObject);
var
  OriginalBitmap1, OriginalBitmap2 : TBitmap;
  DetsBitmap : TBitmap;

  r,g,b: Integer;
  r1,g1,b1: Integer;
  X, Y: Integer;
  tal: Integer;

  RowOriginal1 :  pRGBArray;
  RowOriginal2 :  pRGBArray;
  RowProcessed :  pRGBArray;
begin
  OriginalBitmap1 := TBitmap.Create;
  OriginalBitmap1.LoadFromFile(\'D:\\PROGRAM FILES\\BORLAND\\Delphi6\\Projects\\P0004617.BMP\');
  //Assign(Image1.Picture.Bitmap);
  OriginalBitmap2 := TBitmap.Create;
//  OriginalBitmap2.Assign(Image2.Picture.Bitmap);
  OriginalBitmap2.LoadFromFile(\'D:\\PROGRAM FILES\\BORLAND\\Delphi6\\Projects\\P0004615.BMP\');


  if (OriginalBitmap1.PixelFormat = pf24bit) and (OriginalBitmap2.PixelFormat= pf24bit) then
  begin
    DetsBitmap := TBitmap.Create;
    DetsBitmap.PixelFormat := pf24Bit;

    tal := TrackBar1.Position;
    DetsBitmap.Height := OriginalBitmap1.Height;
    DetsBitmap.Width := OriginalBitmap1.Width;

    for Y := 0 to OriginalBitmap1.Height-1 do
    begin
      RowOriginal1  := pRGBArray(OriginalBitmap1.Scanline[y]);
      RowOriginal2  := pRGBArray(OriginalBitmap2.Scanline[y]);
      RowProcessed := pRGBArray(DetsBitmap.Scanline[y]);

      for X := 0 to OriginalBitmap1.Width-1 do
      begin
        r:= RowOriginal1[x].rgbtRed;
        g:= RowOriginal1[x].rgbtGreen;
        b:= RowOriginal1[x].rgbtBlue;

        r1 := RowOriginal2[x].rgbtRed;
        g1 := RowOriginal2[x].rgbtGreen;
        b1 := RowOriginal2[x].rgbtBlue;

        r := Round((r/100*tal) + (r1/100*(100-tal)));
        g := Round((g/100*tal) + (g1/100*(100-tal)));
        b := Round((b/100*tal) + (b1/100*(100-tal)));

        RowProcessed[x].rgbtRed  := r;
        RowProcessed[x].rgbtGreen := g;
        RowProcessed[x].rgbtBlue  := b;
      end;
    end;

    Label5.Caption := IntToStr(100-TrackBar1.Position);
    Label6.Caption := IntToStr(TrackBar1.Position);
  end;
  DetsBitmap.SaveToFile(\'Hest.bmp\');
  //Image3.Picture.Bitmap.assign(DetsBitmap);
end;

hvis dit billede kun har 8bit farver (256) eller 1bit (8) Så har jeg også en løsning på det, men først efter du har redegjort for hvordan der her virker ..

Jens B

ææh ups. Jeg fik aldrig rydet op efter mig ....

Brug det her kode i stedet :

const
  PixelCountMax = 32768;

type
  pRGBArray  = ^TRGBArray;
  TRGBArray  = array[0..PixelCountMax-1] of TRGBTriple;
  EImageProcessingError = class (Exception);

procedure TForm1.Button2Click(Sender: TObject);
var
  OriginalBitmap1, OriginalBitmap2, DetsBitmap : TBitmap;

  r,g,b: Integer;
  r1,g1,b1: Integer;
  X, Y: Integer;
  tal: Integer;

  RowOriginal1 :  pRGBArray;
  RowOriginal2 :  pRGBArray;
  RowProcessed :  pRGBArray;
begin
  OriginalBitmap1 := TBitmap.Create;
  OriginalBitmap1.LoadFromFile(\'D:\\PROGRAM FILES\\BORLAND\\Delphi6\\Projects\\P0004617.BMP\');
  //Assign(Image1.Picture.Bitmap);
  OriginalBitmap2 := TBitmap.Create;
//  OriginalBitmap2.Assign(Image2.Picture.Bitmap);
  OriginalBitmap2.LoadFromFile(\'D:\\PROGRAM FILES\\BORLAND\\Delphi6\\Projects\\P0004615.BMP\');

  DetsBitmap := TBitmap.Create;
  DetsBitmap.Height := OriginalBitmap1.Height;
  DetsBitmap.Width := OriginalBitmap1.Width;


  if (OriginalBitmap1.PixelFormat = pf24bit) and (OriginalBitmap2.PixelFormat= pf24bit) then
  begin
    DetsBitmap.PixelFormat := pf24Bit;

    tal := TrackBar1.Position;

    for Y := 0 to OriginalBitmap1.Height-1 do
    begin
      RowOriginal1 := pRGBArray(OriginalBitmap1.Scanline[y]);
      RowOriginal2 := pRGBArray(OriginalBitmap2.Scanline[y]);
      RowProcessed := pRGBArray(DetsBitmap.Scanline[y]);

      for X := 0 to OriginalBitmap1.Width-1 do
      begin
        r:= RowOriginal1[x].rgbtRed;
        g:= RowOriginal1[x].rgbtGreen;
        b:= RowOriginal1[x].rgbtBlue;

        r1 := RowOriginal2[x].rgbtRed;
        g1 := RowOriginal2[x].rgbtGreen;
        b1 := RowOriginal2[x].rgbtBlue;

        r := Round((r/100*tal) + (r1/100*(100-tal)));
        g := Round((g/100*tal) + (g1/100*(100-tal)));
        b := Round((b/100*tal) + (b1/100*(100-tal)));

        RowProcessed[x].rgbtRed  := r;
        RowProcessed[x].rgbtGreen := g;
        RowProcessed[x].rgbtBlue  := b;
      end;
    end;

    Label5.Caption := IntToStr(100-TrackBar1.Position);
    Label6.Caption := IntToStr(TrackBar1.Position);
  end;

  //Image3.Picture.Bitmap.assign(DetsBitmap);

  DetsBitmap.SaveToFile(\'Hest.bmp\');
  OriginalBitmap1.free;
  OriginalBitmap2.free;
  DetsBitmap.free;

end;

hva gør det hurtigere?

Hmmnnn. Det troede jeg var åbenlyst ....

Du henter din pixel helt ude på sklrmen, og stopper den tilbage HVER gang ....

I/O tager meget langtid, fordi man hvergang skal vente på Hardwaren.

Jeg der i mod ligger det hele ud i rammen. Så er det hele blot talt. Det er ikke pixels blot tal, som jeg laver nogle beregninger på. Det går stærkt !

Jens B

tak så må jeg bruge den kode fremover :-))

cautoo>> Du bør nu stasig væk sætte dig ned og finde ud præcis hvordan koden virker og hvorfor. For så at skrive kommentarer i koden.

Jens B

det eneste jeg ikk helt fatter er hva denne kommando gør:
      RowOriginal1 := pRGBArray(OriginalBitmap1.Scanline[y]);
      RowOriginal2 := pRGBArray(OriginalBitmap2.Scanline[y]);
      RowProcessed := pRGBArray(DetsBitmap.Scanline[y]);

cautoo >>
  En bitmap er byyger op af en BITMAPHEADDERINFO struktur, samt et to dimmensionelt array af pixels.

Afhænigt af hvilken type birmat det er 8bit, 24bit, 32Bit etc er disse pixels af forskelligt format.

De \"vandrette\" linjer i en bitmap klades Scanlinjer.

I dit tilfælde arbejder du med en 24Bits Bitmap, og her er en pixel en TRGBTriple.

en TRGBTriple er defineret i Windows således :

  tagRGBTRIPLE = packed record
    rgbtBlue: Byte;
    rgbtGreen: Byte;
    rgbtRed: Byte;
  end;
  TRGBTriple = tagRGBTRIPLE;

Altså en scanlinje er af typen  TRGBArray i et 24Bits bitmap. Hvis hu kalder OriginalBitmap1.Scanline[y] får du en pointer til ScanLine nummer \'y\'. da vi nu ved det er en 24Bits bitmap så ved vi at det er en pointer til et array af TRGBTriple. Desværre har borland ikke defineret sådan en type så derfor gør jeg det :

const
  PixelCountMax = 32768;
type
  pRGBArray  = ^TRGBArray;
  TRGBArray  = array[0..PixelCountMax-1] of TRGBTriple;


DDet smaret er nu at jeg bare kan indexsere ud i remmen fordi jeg kender højde og brede på min bitmap.

Hjalp det ?

Jens B

yep altid rart at kunne lære noget :-)


Tak for hjælpen.