skriv de 10 sidste linjer fra et tekstdokument

Du skal have et array med plads til 10 linier. Du læser tekstdokumentet 1 linie ad gangen og placerer den i den næste plads i array\'et, når du når til plads 10 i arrayet starter du forfra. Når du rammer end-of-file indeholder array\'et de 10 sidste linier, som du bare skal have skrevet ud i den rigtige rækkefølge.

hvordan gør jeg det kan du ikke lave et eksempel???

hæver lige point med 30

Jeg vil tro man også kan gøre det med SkipLine som nævnt her:

http://www.html.dk/tutorials/asp/lektion15.asp

  Dim lastLines(10)

  Const  ForReading = 1

  \' Open file
  Set fsoObj = Server.CreateObject(\"Scripting.FileSystemObject\")
  Set tsObj = fsoObj.OpenTextFile( \"c:\\temp\\test.txt\", ForReading, False )

  \' Read file, keep 10 last lines
  lastIndex = 0
  While Not tsObj.AtEndOfStream
      lastLines(lastIndex) = tsObj.ReadLine
      lastIndex = lastIndex + 1
      if lastIndex >= 10 then
        lastIndex = 0
      end if
  Wend

  tsObj.Close
  Set tsObj = Nothing
  Set fsoObj = Nothing

  \' print out last 10 lines
  Response.Write( \"Last 10 lines:<br>\" )

  for i = 1 to 10
      Response.Write( lastLines(lastIndex) & \"<br>\" )
      lastIndex = lastIndex + 1
      if lastIndex >= 10 then
        lastIndex = 0
      end if
  next

Du skal selvsagt rette filnavnet c:\\temp\\test.txt til det du selv skal bruge

Ellers tak for hjælpen mem jeg har fået et bedre svar i forumet på www.activeserverpages.dk
så jeg tager pointen selv

Men jespernaur du får alligevel 20 point

Jeg har kastet et blik på den anden løsning, og indrømmet: Den ser da umiddelbart mere elegant ud end min, men: Du skal være klar over, at den (i modsætning til min) kræver, at der er plads til hele filen i lageret (bliver læst ind med ReadAll). Dette er intet problem ved små filer, men hvis du kommer ud for meget store filer, kan du risikere at blive smidt at pga ressourcemangel. Hvor grænsen går kan ikke siges på forhånd, det afhænger af den server du bruger.