Skifte drevbogstav

Hvis det kun er dine egne computere skulle man vel kunne tildele usb pinden til et bestemt bogstav, så når den regisreres så får den dette bogstav. Vælg et bogstav lidt oppe i alfabetet.

Man tildeler drevbogstaver i diskhåndteringen.

Hej
Tak for indput, men det vidste jeg nu godt, men det er ikke kun mine egne computere den skal gå på, da jeg har prisberegner og andre ting includeret i arket, og det kan jeg finde på at tage med på job så jeg også kan passe forretningen på jobbet

1.
"Jeg har i et excel dokument noget VBA, som henter noget data fra C: drevet"

Hvis det er en fremmed computer, skal den vel ikke hente på C drevet ??.

2.

Du kan jo altid bruge koden 'Sti = ThisWorkbook.path', til at finde dine filer med, hvis Excel dukumentet med koden er samme sted, eller i underliggende biblioteker.

Godmorgen Kabbak
1000 tak, hvordan skal jeg så sætte den ind så dem passer med

Sub gemSom()
Const filstiNavn = "C:\Users\Peter\Desktop"
Dim navn As String, fakturaNr As String

Const filstiNavn = "C:\Users\Peter\Desktop"

Const filstiNavn = ThisWorkbook.path

Følgende kode illustrerer hvordan du kan finde alle "removable drives":

Declare Function myGetDriveType Lib "kernel32" Alias "GetDriveTypeA" (ByVal nDrive As String) As Long
Sub GetDriveInfo()
  Dim i As Integer
  Dim DriveLetter As String
  Dim s As String

  s = ""
  For i = 65 To 90 'A-Z
    DriveLetter = (Chr(i) & ":\")
    If (myGetDriveType(DriveLetter) = 2) Then s = s & Left(DriveLetter, 2) & vbCrLf
  Next
  MsgBox s
End Sub

Med den kan du måske komme videre?

Øv
Det er jeg sq nok for dum til, nu har jeg i begge formler prøvet på alle måder, men åbenbart ikke den rigtige
Jeg vedhæfter lige min VBA

Dim aktuelleCelle As String
Sub FakNr()
' FakNr Makro
' tildeler fakturanummer i feltet F8
Range("F8").Select
If ActiveCell.Value <> "" And IsNumeric(ActiveCell.Value) Then
' ingenting - er kørt tidligere bare sæt cursor i G8
  Range("B11").Select
Else
' opdater fakturanummer, og skriv i F8
  fil$ = "C:\Users\Peter\Desktop\FakNr.txt"
  Open fil$ For Input As 1
  Input #1, aktnavn
  Close 1
  aktnavn = aktnavn + 1
  Open fil$ For Output As 1
  Write #1, aktnavn
  Close 1
  ActiveCell.FormulaR1C1 = aktnavn
  Range("B11").Select
End If
End Sub
Sub gemSom()
Const filstiNavn = "C:\Users\Peter\Desktop"

Dim navn As String, fakturaNr As String
 
    navn = Range("B11")
    fakturaNr = Range("F8")
 
Rem Er der faktura-nr i F8
    If fakturaNr = "" Then
        ActiveWorkbook.SaveAs filstiNavn + "\prøvefakturaer\" & navn & ".xlsm"
    Else
        ActiveWorkbook.SaveAs filstiNavn + "\færdige fakturaer\" & fakturaNr & " " & navn & ".xlsm"
    End If
End Sub

prøv denne, du skal have FakNr.txt, samme sted som arket med koden her.

Dim aktuelleCelle As String
Dim filstiNavn  As String


Sub FakNr()
filstiNavn = ThisWorkbook.Path

' FakNr Makro
' tildeler fakturanummer i feltet F8
Range("F8").Select
If ActiveCell.Value <> "" And IsNumeric(ActiveCell.Value) Then
' ingenting - er kørt tidligere bare sæt cursor i G8
  Range("B11").Select
Else
' opdater fakturanummer, og skriv i F8
  fil$ = filstiNavn & "\FakNr.txt" ' samme bibliotek som denne excel mappe
  Open fil$ For Input As 1
  Input #1, aktnavn
  Close 1
  aktnavn = aktnavn + 1
  Open fil$ For Output As 1
  Write #1, aktnavn
  Close 1
  ActiveCell.FormulaR1C1 = aktnavn
  Range("B11").Select
End If
End Sub
Sub gemSom()

Dim navn As String, fakturaNr As String
filstiNavn = ThisWorkbook.Path
    navn = Range("B11")
    fakturaNr = Range("F8")
 
Rem Er der faktura-nr i F8
    If fakturaNr = "" Then
        ActiveWorkbook.SaveAs filstiNavn & "\prøvefakturaer\" & navn & ".xlsm"
    Else
        ActiveWorkbook.SaveAs filstiNavn & "\færdige fakturaer\" & fakturaNr & " " & navn & ".xlsm"
    End If
End Sub

1000 tak Kabbak
Ja jeg håber da jeg en dag finder de vise sten i VBA
lægger du ikk lige et svar :-)

;-))

Kan se der er blevet brugt noget kode fra min faktura skabelon.
Det er da super at det kan bruges.

Hej 220661
Ja det er en rigtig dejlig skabelon du sendte mig, jeg har brugt en masse fra den, men også lavet meget om på den, du kan måske også bruge nogle af mine ideer til din ?
og 1000 tak for hjælpen
Mvh
Peter

Velbekomme.