Deaktivere Klip og Indsæt samt Kopier og Indsæt

Hej

Jeg har et regneark som en række brugere skal anvende. Da anvendelse af klip og indsæt samt kopier og indsæt kan ødelægge en række af de formler og funktionaliteter der er i arket, så ville jeg gerne fjerne muligheden herfor.

Jeg har søgt på nettet og fundet følgende makroer:

********************************************************
Indsættes i "Module1" (eller lign.):
Option Explicit

Sub ToggleCutCopyAndPaste(Allow As Boolean)
    'Activate/deactivate cut, copy, paste and pastespecial menu items
    Call EnableMenuItem(21, Allow) ' cut
    Call EnableMenuItem(19, Allow) ' copy
    Call EnableMenuItem(22, Allow) ' paste
    Call EnableMenuItem(755, Allow) ' pastespecial
   
    'Activate/deactivate drag and drop ability
    Application.CellDragAndDrop = Allow
   
    'Activate/deactivate cut, copy, paste and pastespecial shortcut keys
    With Application
        Select Case Allow
        Case Is = False
            .OnKey "^c", "CutCopyPasteDisabled"
            .OnKey "^v", "CutCopyPasteDisabled"
            .OnKey "^x", "CutCopyPasteDisabled"
            .OnKey "+{DEL}", "CutCopyPasteDisabled"
            .OnKey "^{INSERT}", "CutCopyPasteDisabled"
        Case Is = True
            .OnKey "^c"
            .OnKey "^v"
            .OnKey "^x"
            .OnKey "+{DEL}"
            .OnKey "^{INSERT}"
        End Select
    End With
End Sub

Sub EnableMenuItem(ctlId As Integer, Enabled As Boolean)
    'Activate/Deactivate specific menu item
    Dim cBar As CommandBar
    Dim cBarCtrl As CommandBarControl
    For Each cBar In Application.CommandBars
        If cBar.Name <> "Clipboard" Then
            Set cBarCtrl = cBar.FindControl(ID:=ctlId, recursive:=True)
            If Not cBarCtrl Is Nothing Then cBarCtrl.Enabled = Enabled
        End If
    Next
End Sub

Sub CutCopyPasteDisabled()
    'Inform user that the functions have been disabled
    MsgBox "Sorry!  Cutting, copying and pasting have been disabled in this workbook!"
End Sub

**********************************************
Indsættes i "Denne_projektmappe":
Option Explicit

Private Sub Workbook_Activate()
    Call ToggleCutCopyAndPaste(False)
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Call ToggleCutCopyAndPaste(True)
End Sub

Private Sub Workbook_Deactivate()
    Call ToggleCutCopyAndPaste(True)
End Sub

Private Sub Workbook_Open()
    Call ToggleCutCopyAndPaste(False)
End Sub
*********************************************

Dette løser delvis opgaven. Men det er stadig muligt at anvende ikonerne i menu-fanen "Startside" og gruppen "Udklipsholder". Hvordan får jeg dette deaktiveret (og aktiveret igen, når filen lukkes)?

Skal siges, at jeg ikke er nogen makro-haj.

På forhånd tak