Find navn på et felt ved hjælp af TabIndex

Hm. Det lader til at man skal gå via Properties:

Sub Test_NextTab()
  Debug.Print NextTab
End Sub

Function NextTab() As String
  Dim varTab As Integer
  Dim Ctl As Control
  Dim Prp As Property
 
  varTab = Screen.ActiveControl.TabIndex
 
  NextTab = "?"
  For Each Ctl In Screen.ActiveForm.Controls
    For Each Prp In Ctl.Properties
      If Prp.Name = "TabIndex" Then
        If Prp.Value = (varTab + 1) Then NextTab = Ctl.Name
      End If
    Next Prp
  Next Ctl
End Function

eller denne løsning: (den løber ikke alle properties igennem)
skift debug.print ud med en variabel.
(controltype 100 og 101 har ikke tabindex)


Sub NavnPåNæsteControl()
Dim D As Integer, E As Integer, K As Integer

  K = Me.ActiveControl.TabIndex

  For E = 0 To Me.Controls.Count - 1
      If Me.Controls(E).ControlType > 101 Then
        D = Me.Controls(E).TabIndex
        If D = K + 1 Then
            Debug.Print Me.Controls(E).TabIndex & ": " & Me.Controls(E).Name
            Exit For
        End If
      End If
  Next E
 
End Sub

@ MSchlamovitz
Har forsøgt mig med noget i den stil. Udfordringen er dog, at jeg ikke kan bruge Me. i en public function i særskilt modul.

@fdata
Din løsning virker efter hensigten. Udfordringen er dog, at jeg skal bruge srengværdien sammen med .Enabled property.

Kort fortalt, skal det bruges til, at 'næste' felt bliver valgbart, når der er udfyldt en værdi i det eksisterende felt og i stedet for at lave en:

Private Sub Afdeling_AfterUpdate()
    If Nz(Me.Afdeling, "") <> "" Then
        Me.Team.Enabled = True
    Else
        Me.Team.Enabled = False
    End If
End Sub

for alle tabs, ville jeg bare gerne have en funktion, der kunne klare det for dem alle sammen på en gang.

For at bruge dit eksempel så skal bruge noget ligende nedenstående i den kaldte procedure.

Sub Test_NextTab()
        Dim thisTab As String
   
    thisTab = Screen.ActiveControl.name
   
    If Nz(thisTab, "") <> "" Then
        NextTab.Enabled = True
    Else
        NextTab.Enabled = False
    End If
End Sub

He he. Du bad jo bare om navnet på næste felt; men ok.

I alle felternes AfterUpdate lægger du (i stedet for [Hændelsesprocedure]) et kald af en funktion, der ligger i formularens kode, f.eks. "=ÅbnNæsteFelt()"

Function ÅbnNæsteFelt()
  NextTab
End Function

NextTab skal så rettes til:

Sub NextTab()
  Dim varTab As Integer
  Dim Ctl As Control
  Dim Prp As Property
 
  If IsNull(Screen.ActiveControl.Value) Then Exit Sub
 
  varTab = Screen.ActiveControl.TabIndex
 
  For Each Ctl In Screen.ActiveForm.Controls
    For Each Prp In Ctl.Properties
      If Prp.Name = "TabIndex" Then
        If Prp.Value = (varTab + 1) Then Ctl.Enabled = True
      End If
    Next Prp
  Next Ctl
End Sub

Jeg tester det først på mandag, men kan din kode også tage højde for, at værdien også kan ændres til "False"? Eller kan jeg bare smide If Nz(nameTab, "") <> "" Then ind så koden kommer til at se sådan ud:

Sub NextTab()
  Dim varTab As Integer
  Dim nameTab As string
  Dim Ctl As Control
  Dim Prp As Property
 
  If IsNull(Screen.ActiveControl.Value) Then Exit Sub

  nameTab = Screen.ActiveControl.name
  varTab = Screen.ActiveControl.TabIndex
 
  For Each Ctl In Screen.ActiveForm.Controls
      For Each Prp In Ctl.Properties
          If Prp.Name = "TabIndex" Then
              If Prp.Value = (varTab + 1) Then 'Ctl.Enabled = True
                  If Nz(nameTab, "") <> "" Then
                      Ctl.Enabled = True
                  Else
                      Ctl.Enabled = False
                  End If
              End If
          End If
      Next Prp
  Next Ctl
End Sub

Det er jo lidt svært at følge med, når du hele tiden ændrer formuleringerne ;O)

Du skrev: "... 'næste' felt bliver valgbart, når der er udfyldt en værdi i det eksisterende felt ...". Mit svar er baseret på dette.

Men jeg fornemmer, at du er helt på hjemmebane og sagtens selv kan tilrette funktionen.

PS:
Nu kender jeg jo ikke din opgave; men jeg ser lille udfordring i din seneste kommentar.

Eksempel:
- brugeren udfylder de første 3 felter
- herefter går han tilbage og sletter indholdet i felt 2
- nu er felt 3 udfyldt; men disabled, og kan ikke rettes før der er skrevet et eller andet i felt 2

Det kan måske forvirre, at man skal udfylde et felt for at rette et andet.

Måske en lille warning (når felt 2 slettes) kunne hjælpe brugeren på rette vej?

Bare en lille, venlig strøtanke.

Ja, det er også tarveligt at holde hen på den måde. ;)

Jeg takker for dit svar, der er helt sikkert noget jeg kan arbejde videre med.
Havde godt tænkt tanten omkring rettelser i tidligere felter og hvad der skulle ske derefter, men tak for kommentaren og her er dine mere end velfortjente point! :)

Jamen, selv tak for de pæne ord og point  ;O)