Langsomme streng behandling

Svaret er meget kort nej. VBScript har kun én datatype variant (god med subtyper). Når indholdet er tekst opfatter VBScript subtypen som text automatisk og så er det altid en variabel længde størrelse.

Det er muligvis anderledes med ASP skrevet i JScript, men det kender jeg ikke alverden til :-)

Er der så nogen der har en ide om hvordan man forbedre preformance på et loop der samler en stor streng?

Læg det i et com objekt - det giver ekstra hastighed. Her kan du evt. skrive objektet i c++ hvis du virkeligt skal have hastighed.

har ikke mulighed for COM objekter.
Kan man ikke lave en buffer i ASP ?

som så kan lægges over i en streng

Sikke en omgang vrøvl jeg fik skrevet. \"god med subtyper\" skulle have været \"godt nok med subtyper\" :-)

Jeg har aldrig set en stringbuffer som man kender dem fra eks. JAVA. Den eneste buffer jeg kender til, er den fra response objektet og den tror jeg ikke hjælper meget.

næ det tror jeg heller ikke....

Hvad er det præcist du foretager dig og hvad er din defination af \"langsom\" ? snakker vi om at du vil optimere et par fladbankede nanosekunder eller ?

nej flere sekunder. looper ca. 200 gange og lave 10-15 concatineringer i hvert loop, og det kører meget langsomt på min computer. 350 mhz

Lyder som om memory er den eneste mulighed tilbage at optimere på. Hvor meget kører du med, hviken server/version og hvad kører ellers på maskinen ?

tror lige jeg tester det inden vi kører videre ikke?
Det bliver ikke lige i dag.....

Der fik jeg dig :-)

øhh fik mig hvor ?

Her en test i kan køre på jeres computer. Jo større strengen bliver jon langsommer bliver den....


<script language=\"JScript\" runat=\"Server\">
timerBegin = new Date();
function myTimer() {
    tmpTime = new Date();
    Response.Write(\"<br>\" + (tmpTime.getTime() - timerBegin.getTime()))
}
</script>


<%


for i=0 to 200

Call myTimer()
Response.Write \" ms.</b> at afvikle dette script.</p>\"

    temp=temp & \"Ladfgå ksdføghksdæøfh sødfæh sfæødhl øsdæfh sødæfh sødfælhk dæøfhk dfhKj\"
    temp=temp & \"Ladfgå ksdføghksdæøfh sødfæh sfæødhl øsdæfh sødæfh sødfælhk dæøfhk dfhKj\"
    temp=temp & \"Ladfgå ksdføghksdæøfh sødfæh sfæødhl øsdæfh sødæfh sødfælhk dæøfhk dfhKj\"
    temp=temp & \"Ladfgå ksdføghksdæøfh sødfæh sfæødhl øsdæfh sødæfh sødfælhk dæøfhk dfhKj\"
    temp=temp & \"Ladfgå ksdføghksdæøfh sødfæh sfæødhl øsdæfh sødæfh sødfælhk dæøfhk dfhKj\"
    temp=temp & \"Ladfgå ksdføghksdæøfh sødfæh sfæødhl øsdæfh sødæfh sødfælhk dæøfhk dfhKj\"
    temp=temp & \"Ladfgå ksdføghksdæøfh sødfæh sfæødhl øsdæfh sødæfh sødfælhk dæøfhk dfhKj\"
    temp=temp & \"Ladfgå ksdføghksdæøfh sødfæh sfæødhl øsdæfh sødæfh sødfælhk dæøfhk dfhKj\"
    temp=temp & \"Ladfgå ksdføghksdæøfh sødfæh sfæødhl øsdæfh sødæfh sødfælhk dæøfhk dfhKj\"
    temp=temp & \"Ladfgå ksdføghksdæøfh sødfæh sfæødhl øsdæfh sødæfh sødfælhk dæøfhk dfhKj\"

   
next

%>

ahaa.......

http://www.15seconds.com/howto/pg000929.htm

her er en ny test:

<script language=\"JScript\" runat=\"Server\">
timerBegin = new Date();
function myTimer() {
    tmpTime = new Date();
    Response.Write(\"<br>\" + (tmpTime.getTime() - timerBegin.getTime()))
}
</script>

<%


\' Use this class to concatenate strings in a much more
\' efficient manner than simply concatenating a string
\' (strVariable = strVariable & \"your new string\")
Class StringBuilder
    Dim arr     \'the array of strings to concatenate
    Dim growthRate  \'the rate at which the array grows
    Dim itemCount  \'the number of items in the array

    Private Sub Class_Initialize()
        growthRate = 50
        itemCount = 0
        ReDim arr(growthRate)
    End Sub

    \'Append a new string to the end of the array. If the
    \'number of items in the array is larger than the
    \'actual capacity of the array, then \"grow\" the array
    \'by ReDimming it.
    Public Sub Append(ByVal strValue)
        If itemCount > UBound(arr) Then
            ReDim Preserve arr(UBound(arr) + growthRate)
        End If

        arr(itemCount) = strValue
        itemCount = itemCount + 1
    End Sub

    \'Concatenate the strings by simply joining your array
    \'of strings and adding no separator between elements.
    Public Function ToString()
        ToString = Join(arr, \"\")
    End Function
End Class


Dim objBuilder, i
Set objBuilder = new StringBuilder

For i = 0 To 500
Call myTimer()
Response.Write \" ms.</b> at afvikle dette script.</p>\"

    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
    objBuilder.Append(\"dasrg lksdfghæ kdføh ksdøfh sdøæfh øsdæfh sødæfh sdæøfh dfæøh \")
Next

Response.Write objBuilder.ToString()

%>

Jeg mente bare at jeg fik dig kørt træt for den dag :-)

Jeg har desværre ingen erfaring med om din seneste løsning holder.

den er meget hurtigere....
Min kode der tog 8-10 sekunder tager nu omkring 1/2 sekund.

så jeg accepterer min egne løsning :)