Slet bestemt linje i text fil plus alt med #

lytter lige med

'Her er en sub, som kan benyttes til at slette én bestemt linie:
'---------------------------------------

Sub DeleteLine(lngLine As Long, strFilePath As String)
    Dim _
        FSO As New Scripting.FileSystemObject, _
        vFile As TextStream, _
        strText As String, _
        L As Long, _
        I As Long, _
        blnGetLine As Boolean
   
    'Check om filen eksisterer:
    If Not FSO.FileExists(strFilePath) Then
        MsgBox "Filen eksisterer ikke!"
        Exit Sub
    End If
   
    Set vFile = FSO.OpenTextFile(strFilePath)
   
    'Hent alle linier, undtagen lngLine:
    Do Until vFile.AtEndOfStream
        If vFile.Line <> lngLine Then
            strText = strText & vFile.ReadLine & vbCrLf
        Else
            vFile.SkipLine
        End If
    Loop
   
    'Luk filen:
    vFile.Close
   
    'Overskriv den gamle fil med
    'den nye, rettede version:
    Set vFile = FSO.CreateTextFile(strFilePath, True)
   
    'Skriv til den nye fil:
    vFile.Write strText
   
    'Luk filen:
    vFile.Close
End Sub

'Denne sub kan fx. kaldes på følgende måde:

Private Sub Command1_Click()
    'Slet linie nr. 11 i filen C:\list.m3u:
    DeleteLine 11, "C:\list.m3u"
End Sub


/Mikbj

'Her er så en sub, som kan benyttes til at slette alle linier, som starter med #:
'--------------------------------------------

Public Sub DeleteComments(strFilePath)
    Dim _
        FSO As New Scripting.FileSystemObject, _
        vFile As TextStream, _
        strText As String, _
        strLine As String

    'Check om filen eksisterer:
    If Not FSO.FileExists(strFilePath) Then
        MsgBox "Filen eksisterer ikke!"
        Exit Sub
    End If
   
    Set vFile = FSO.OpenTextFile(strFilePath)
   
    'Hent alle linier som ikke starter med #:
    Do Until vFile.AtEndOfStream
        strLine = vFile.ReadLine
       
        If Left(strLine, 1) <> "#" Then
            strText = strText & strLine & vbCrLf
        End If
    Loop
   
    'Luk filen:
    vFile.Close
   
    'Overskriv den gamle fil med
    'den nye, rettede version:
    Set vFile = FSO.CreateTextFile(strFilePath, True)
   
    'Skriv til den nye fil:
    vFile.Write strText
   
    'Luk filen:
    vFile.Close
End Sub

'Denne sub kan fx. kaldes på følgende måde:

Private Sub Command1_Click()
    'Slet alle linier som starter med #
    DeleteComments "C:\list.m3u"
End Sub


/Mikbj

Bemærk, at du skal tilføje referencen "Microsoft Scripting Runtime" til dit projekt.

Dette gøres med at åbne menuen:
Project > References...

Og vælg så Microsoft Scripting Runtime på listen og tryk OK.

/Mikbj

'Her til sidst har jeg lavet en sub, som gør begge dele på én gang, denne kalder jeg DoDelete:
'----------------------------------------

Sub DoDelete(lngLine As Long, strFilePath As String)
    Dim _
        FSO As New Scripting.FileSystemObject, _
        vFile As TextStream, _
        strText As String, _
        strLine As String, _
        L As Long, _
        I As Long
   
    'Check om filen eksisterer:
    If Not FSO.FileExists(strFilePath) Then
        MsgBox "Filen eksisterer ikke!"
        Exit Sub
    End If
   
    Set vFile = FSO.OpenTextFile(strFilePath)
   
    'Hent linier fra tekstfilen:
    Do Until vFile.AtEndOfStream
   
        'Hvis den aktuelle linie
        'er den, som skal fjernes,
        'skal den springes over:
        If vFile.Line <> lngLine Then
            strLine = vFile.ReadLine
           
            'Hvis den istedet starter med #
            'skal den også springes over:
            If Left(strLine, 1) <> "#" Then
                strText = strText & strLine & vbCrLf
            End If
        Else
            vFile.SkipLine
        End If
    Loop
   
    'Luk filen:
    vFile.Close
   
    'Overskriv den gamle fil med
    'den nye, rettede version:
    Set vFile = FSO.CreateTextFile(strFilePath, True)
   
    'Skriv til den nye fil:
    vFile.Write strText
   
    'Luk filen:
    vFile.Close
End Sub

'Denne sub kan fx kaldes på flg. måde:

Private Sub Command1_Click()
    'Slet linie 3 og alle linier, der starter med #
    DoDelete 3, "C:\list.m3u"
End Sub

Nu har du lidt at vælge imellem - håber det kan bruges ! :)

/Mikbj

Mange tak det var lige det jeg stod og manglede.

Bortset fra at den lige skulle fjerne linjerne med # før den sletter den bestemte linje så man fjerner den linje sangen står i og ikke resikere at det kun er en kommentar den fjerner. Men det er nu det mindste problem for mig at rette.

Så 1000 tak herfra.

np :)