HJÆLP...

hvad er der i text dokumentet?

Gi' dem et stykke papir, hvor formlen til at regne lix ud er på.. :-S .. Sig det er et TXT-dokument..

<--- Er lidt plat.. :)

Text dokumentet indeholder flg.:

49, c:\inetpub\wwwroot\oblig_opg\testtekst.txt
47, c:\inetpub\wwwroot\oblig_opg\testtekst.txt
46, c:\inetpub\wwwroot\oblig_opg\testtekst.txt
43, c:\inetpub\wwwroot\oblig_opg\testtekst.txt
41, c:\inetpub\wwwroot\oblig_opg\testtekst.txt
41, c:\inetpub\wwwroot\oblig_opg\testtekst.txt
36, c:\inetpub\wwwroot\oblig_opg\testtekst.txt

som er de dokumenter med højeste lix-tal

Jeg er jo nød til at splitte dokumentet ved linieskift - eller hvad???

Hvis du kan få kontakt med tekstfilen og udskrive den - så mangler du jo kun at skrive en ny tekstfil.

Hvis det kan hjælpe så er her koden for at skrive til en fil.

<%
  dim fso, f, filespec
  set fso = CreateObject("Scripting.FileSystemObject")
  filespec = Server.MapPath("\") & "\test\logfil.txt"
  Set f = fso.OpenTextFile(filespec,2) ' Åbn fil for skrivning
  f.WriteLine "Indhold af linie 1"
  f.WriteLine "Indhold af linie 2"
  f.Close
%>

i = 0 'arrays er nul-indekseret

'indlæs din text fil ind linje for linje vha. fso
'..for hver linje gør du sådan her:

arrLinje = split(denindlæstelinje,",")

'så kan du sætte:
arrFinalArray(0,i) = arrLinje(0)
arrFinalArray(1,i) = arrLinje(1)
i = i+1

'gå videre til næste linje indtil der ikke er flere linjer tilbage


forstår du, hvad jeg mener?

så vil du til sidst ha' et array der ser sådan her ud:

arrFinalArray(0,0) = "49"
arrFinalArray(1,0) = "c:\inetpub\wwwroot\oblig_opg\testtekst.txt"
arrFinalArray(0,1) = "47"
arrFinalArray(1,1) = "c:\inetpub\wwwroot\oblig_opg\testtekst.txt"

Problemet er at jeg ud fra et nyåbnet tekstdokument skal beregne lix tallet - det er klaret. Derefter skal jeg åbne en eksisterende highscore.txt. Så skal jeg tjecke om det nyfundne lix-tal er højt nok til at komme i highscore filen, som indeholder "top 10". Såfremt det er det - skal den nye lixtal lægges ind hvor den mindste lixtal lå. Derefter sorteres arrayet med top10 og ligges i et tekstdokument... Lidt af en opgave for en newbie

Var det ikke en ide at lægge hver linie i highscore.txt ind i en db-tabel. Derefter også den nye tekst-fil, men tilhørende lix-tal. Derefter trækkes de 10 (eller hvor mange der nu er på listen) tekstfiler med højeste lix-tal ud, og lægges over i en ny highscore.txt (der overskriver den gamle)

Ved godt det måske ikke er god programmerings-skik men på denne måde spares arbejdet på en sorterings-algoritme. (Den er jo indbygget i db'en)

wittnezz

Det er helt sikkert en god idé - men desværre ikke en del af opgaven :-(

mansk, tre spm:

- hvilken tekstfil er det, der skal hentes ind i et array??
- vil du ha' løsningen, eller vil du bare ha' koden?
- hvad betyder tallene 49, 47, 46, 43 etc.?

hvilken tekstfil er det, der skal hentes ind i et array??
- det er highscorelisten.
vil du ha' løsningen, eller vil du bare ha' koden?
- Koden ville være optimalt, men løsningen er ok...
hvad betyder tallene 49, 47, 46, 43 etc.?
- det er lixtallene for foregående beregninger - jo højere tal des højere placering skal de have. Hvis der fx kommer en beregning der giver 60 skal den sættes ind og den med det mindste tal smides ud...

Nu udskriver den 1. linie men melder derefter flg. fejl:

Der opstod en Microsoft VBScript-kørselsfejl fejl '800a000d'
Typerne stemmer ikke overens: 'ArrFinal'
/opg/lix.asp, linje 93

Jeg kunne ikke lade være - denne kode åbner filen og indlæser hver linie i et array - derefter genneløbes arrayet og linierne gemmes i samme fil og når det er passende så puttes den nye linie ind i mellem.

En indlæsning - sortering under udlæsning.

<%
  ' Funktion til udtræk at første tal i en linie
  function GetNum(L)
    GetNum = CInt(Left(L, inStr(L, ",") - 1)) ' Returner som Integer
  end function

  ' Ny linie som skal puttes ind i mellem
  NyLix = "42, c:\inetpub\wwwroot\oblig_opg\testtekst.txt"
  NyLixNum = GetNum(NyLix) ' Find værdien af nye linie

  dim fso, f, filespec
  dim arrLix

  ' *** Indlæs filen i arrLix
  set fso = CreateObject("Scripting.FileSystemObject")
  filespec = Server.MapPath("lix.max")
  Set f = fso.OpenTextFile(filespec, 1) ' Åbn inputfil for læsning
  arrLix = Split(f.ReadAll, vbCrLf) ' Læs hele filen og split den op linie for linie i arrLix
  f.Close ' Luk inputfilen igen

  ' Herefter udlæses linierne igen - og den nye linie puttes ind hvor NyLixNum passer i listen
  Set f = fso.OpenTextFile(filespec, 2) ' Åbn outputfil for skrivning
  Used = False ' Den nye linie er ikke læst ud i filen
  for each Line in arrLix ' Gennemløb alle linier i arrLix
    if Line <> "" then
      if not Used and (NyLixNum > GetNum(Line)) then
        f.WriteLine NyLix ' gem nye linie i fil
        Used = True ' Den nye linie er nu læst ud i filen
      end if
      f.WriteLine Line ' gem gamle linie i fil
    end if
  next
  f.Close ' Luk outputfilen igen
%>

Håber du kan få lidt ud af det.

Det virker!!! Tak...

Nu mangler jeg bare noget der kan fjerne den laveste placering og genoprette filen...

Den var værre man kan ikke bare skrive "for each Line in arrLix - 1"

Men det kan løses ved at "stacke" linierne i stedet for at skrive dem til filen direkte - således at det altid er den forrige linie der skrives til filen. (Eller kald det skrivning til fil med en linies forsinkelse og "glem" at skrive den sidste linie.)
her er koden. Jeg har skrevet TILFØJET efter de ændringer det har medført

<%
  ' Funktion til udtræk at første tal i en linie
  function GetNum(L)
    GetNum = CInt(Left(L, inStr(L, ",") - 1)) ' Returner som Integer
  end function

  ' Ny linie som skal puttes ind i mellem
  NyLix = "42, c:\inetpub\wwwroot\oblig_opg\testtekst.txt"
  NyLixNum = GetNum(NyLix) ' Find værdien af nye linie

  dim fso, f, filespec
  dim arrLix, StackLine ' TILFØJET StackLine

  sub StackL(Line) ' TILFØJET Funktion til skrivning til fil med 1 linies forsinkelse
    if StackLine <> "" then
      f.WriteLine StackLine ' Gem linie i fil
    end if
    if Line <> "" then
      StackLine = Line
    end if
  end sub

  ' *** Indlæs filen i arrLix
  set fso = CreateObject("Scripting.FileSystemObject")
  filespec = Server.MapPath("lix.max")
  Set f = fso.OpenTextFile(filespec, 1) ' Åbn inputfil for læsning
  arrLix = Split(f.ReadAll, vbCrLf) ' Læs hele filen og split den op linie for linie i arrLix
  f.Close ' Luk inputfilen igen

  ' Herefter udlæses linierne igen - og den nye linie puttes ind hvor NyLixNum passer i listen
  Set f = fso.OpenTextFile(filespec, 2) ' Åbn outputfil for skrivning
  Used = False ' Den nye linie er ikke læst ud i filen
  for each Line in arrLix ' Gennemløb alle linier i arrLix
    if Line <> "" then
      if not Used and (NyLixNum > GetNum(Line)) then
        Call StackL(NyLix) ' gem nye linie i fil TILFØJET Call StackL
        Used = True ' Den nye linie er nu læst ud i filen
      end if
      Call StackL(Line) ' gem gamle linie i fil TILFØJET Call StackL
    end if
  next
  f.Close ' Luk outputfilen igen
%>

Jeg prøver lige...

Det virker - takker 1000 gange... du får lige en bunke point, for en stor hjælp

Tak - tak :-)

eller - det vil sige at det ikke virker helt efter hensigten. Det var meningen at, hvis det nye lixtal ikke var større end nogle af de eksisterende, skulle der ikke ske noget som helst... men det gør der...