.:: Indsætte tekst + billede som på netstationen.dk ?? ::.

Nu ved jeg ikke lige hvordan det er lavet på www.n.dk, men jeg ville uploade billedet i en database og lave felter til de informationer der skal være til billedet ...

Hvis du vil lave det på denne måde skal jeg vide lidt mere om hvilken database du bruger på din hjemmeside og om du har adgang til nogle upload-komponenter såsom aspSmartUpload på dit webhotel (er gratis) for at kunne hjælpe dig

Men jeg er nok ikke hjemme resten af dagen så her får du nogle links som du kan kigge på indtil jeg kan hjælpe dig:

http://activedeveloper.dk/aspdigital/kapitel2/sqlimage.asp
http://www.sagas.net/asp/displayone.asp?id=93

Håber du kan finde ud af det ... ellers kan du jo bare spørge :-)

Hvis du har aspSmartUpload kan du på www.aspsmart.com læse hvordan du uploader billeder i en database ... og bruge artiklen fra activedeveloper til at hive billedet ud igen ...

Tja... jeg tror det nemmest kan laves ved at du på activedeveloper.dk / 3wp.dk henter ArtikelEditor / Gæstebog og så bruger en del at det script, hvor man kan opsætte tekst og billeder samt uploade.

mvh
Christian

Ups, jeg kom til at smide koden i et andet spg., men her er det ...

Men jeg bruger en fil 'pullimage.asp' til at trække billederne ud af en database:

-----------------------------------

<%
Response.Buffer = True

Const adOpenForwardOnly = 0, adOpenStatic = 3, adLockReadOnly = 1, adLockOptimistic = 3, adCmdText = 1, adCmdTable = 2

Dim objConn, objRS
Dim twID

Dim strPathToDB
strPathToDB = "D:\mappetildinhjemmeside\data\"

twID = Replace(Replace(Replace(Request.Querystring("ID"), "'", "''"), "%", ""), " ", "")

Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strPathToDB & "Gallery.mdb"

Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.Open "SELECT * FROM [tblGallery] WHERE [fldID] = " & twID & ";", objConn, adOpenStatic, adLockOptimistic, adCmdText

If Not objRS.EOF Then
  If Request.Querystring("mode") = "thumbnail" Then
      Response.ContentType = objRS("fldContentTypeThumbnail")
      Response.BinaryWrite objRS("fldFileThumbnail")
  End If
End If

objConn.Close
Set objConn = Nothing
%>

-----------------------------------

For at uploade til en database skal jeg vide om du har adgang til nogle komponenter på din server til formålet (eller om du har mulighed for at få installeret aspSmartUpload som jo er gratis).

Hvis du vælger at bruge aspSmartUpload kan du lave en anden fil addnew.asp og indsætte følgende kode i den:

-----------------------------------

<%
Dim objSmartUpload, objSmartUploadFile
Dim twTextText, twTextLink, twSelectCategory
Dim strError, strCategory

Dim strPathToDB
strPathToDB = "D:\mappetildinhjemmeside\data\"

Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strPathToDB & "Gallery.mdb"

If (Request.ServerVariables("REQUEST_METHOD") = "POST") Then
  Set objSmartUpload = Server.CreateObject("aspSmartUpload.SmartUpload")
  objSmartUpload.Upload

  twTextText1 = Replace(Replace(objSmartUpload.Form("twTextText1"), "'", "''"), "%", "")
  twTextText2 = Replace(Replace(objSmartUpload.Form("twTextText2"), "'", "''"), "%", "")

  Set objRS = Server.CreateObject("ADODB.Recordset")
  objRS.Open "SELECT * FROM [tblGallery];", objConn, adOpenStatic, adLockOptimistic, adCmdText

  objRS.AddNew
  If Not objSmartUpload.Files.Item(1).IsMissing Then
    objSmartUpload.Files.Item(1).FileToField objRS.Fields("fldFile")
    objRS("fldFileName") = objSmartUpload.Files.Item(1).FileName
    objRS("fldFileSize") = objSmartUpload.Files.Item(1).Size
    objRS("fldContentType") = objSmartUpload.Files.Item(1).ContentType
  End If
  objRS("fldText1") = twTextText1
  objRS("fldText2") = twTextText2
  objRS.Update

End If
%>

<form action="addnew.asp" enctype="multipart/form-data" method="post">
Billede-fil:<br><input name="twFileFile" style="width:300px" type="file"><br><br>
Tekst1:<br><input maxlength="255" name="twTextText1" style="width:300px" type="text" value=""><br><br>
Tekst2:<br><input maxlength="255" name="twTextText2" style="width:300px" type="text" value=""><br><br>
<input type="submit" value="Opret"></form>

-----------------------------------

På den hjemmeside hvor du så skal udskrive alle billederne skal du så løbe denne tabel i gennem og udskrive teksterne ... Du skal så også udskrive billedet ved at skrive:

Response.Write "<img src=""pullimage.asp?id=" & objRS("fldID") & "">"

Håber du kan bruge det til noget ... ellers må du gi' nogle flere informationer om hvad du vil ha' lavet ...