Excel2K: Udskrive multipel markering på eet ark.

Du kan ikke printe multiple selektions på en side pr default.

Du kan dog gøre flg:
Set print area for det du vil have printet.
Hide kolonner og rows for det du vil udelade.

En halv løsning, men det bedste excel kan gøre.

Ved hjælp af lidt VBA kan det godt lade sig gøre.
Marker dine områder og kør følgende makro.
Så vil dine områder blive skrevet ud på én side, hvis de da ikke fylder for meget.

Sub PrintSelectedCells()
' prints selected cells, use from a toolbar button or a menu
Dim aCount As Integer, cCount As Integer, rCount As Integer, i As Integer, j As Long, aRange As String, rHeight() As Single, cWidth() As Single, AWB As Workbook, NWB As Workbook
    If UCase(TypeName(ActiveSheet)) <> "WORKSHEET" Then Exit Sub ' useful only in worksheets
    aCount = Selection.Areas.Count
    If aCount = 0 Then Exit Sub ' no cells selected
    cCount = Selection.Areas(1).Cells.Count
    If aCount > 1 Then ' multiple areas selected
        Application.ScreenUpdating = False
        Application.StatusBar = "Printing " & aCount & " selected areas..."
        Set AWB = ActiveWorkbook
        rCount = ActiveSheet.Cells.SpecialCells(xlLastCell).Row
        cCount = ActiveSheet.Cells.SpecialCells(xlLastCell).Column
        ReDim rHeight(rCount)
        ReDim cWidth(cCount)
        For i = 1 To rCount ' find the row height of every row in the selection
            rHeight(i) = Rows(i).RowHeight
        Next i
        For i = 1 To cCount ' find the column width of every column in the selection
            cWidth(i) = Columns(i).ColumnWidth
        Next i
        Set NWB = Workbooks.Add ' create a new workbook
        For i = 1 To rCount ' set row heights
            Rows(i).RowHeight = rHeight(i)
        Next i
        For i = 1 To cCount ' set column widths
            Columns(i).ColumnWidth = cWidth(i)
        Next i
        For i = 1 To aCount
            AWB.Activate
            aRange = Selection.Areas(i).Address ' the range address
            Range(aRange).Copy ' copying the range
            NWB.Activate
            With Range(aRange) ' pastes values and formats
                .PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
                .PasteSpecial Paste:=xlFormats, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
            End With
            Application.CutCopyMode = False
        Next i
        NWB.PrintOut
        NWB.Close False ' close the temporary workbook without saving
        Application.StatusBar = False
        AWB.Activate
        Set AWB = Nothing
        Set NWB = Nothing
    Else
        If cCount < 10 Then ' less than 10 cells selected
            If MsgBox("Are you sure you want to print " & cCount & " selected cells ?", vbQuestion + vbYesNo, "Print celected cells") = vbNo Then Exit Sub
        End If
        Selection.PrintOut
    End If
End Sub

Janvogt:
Jeg kender ikke til makro, så her er hvad jeg gjorde:
Funktioner -Makroer -> VB editor -> Pastede dit forslag og gemte
Markerede mine celler og Funktioner->Makro->PrintSelectedCells()-> Dobbeltklikkede, for AFSPIL var nedtonet.
Men intet skete der.
Hvad gør jeg galt

Sådan gør du:
Tryk ALT+F11 og paste koden ind under "ThisWorkbook"
Marker dine celler og tryk ALT+F8 for at afspille makroen "PrintSelectedCells"

Gert>Fik du det til at virke?
Det virker perfekt her hos mig.

Det virker bare PERFEKT.
1000 tak, du har gjort mange glade!!!

Rart at kunne hjælpe :-)