Fejl

hvad lavede du da du fik den fejl?

der står bl.a. "Missing email recipient."..

er det noget mail noget?

give nogle flere detaljer.

Benyttet dette script.

  sub AddErrorMsg(msg)

    dim n

    ' Tilføj en fejlbesked til listen.

    n = UBound(errorMsgs)
    Redim Preserve errorMsgs(n + 1)
    errorMsgs(n + 1) = msg

  end sub

  function GetHost(url)

    dim i, s

    GetHost = ""

    ' Find host eller IP adressen og portnummeret, hvis de(t) eksisterer.

    if Left(url, 7) = "http://" then
      s = Mid(url, 8)
    elseif Left(url, 8) = "https://" then
      s = Mid(url, 9)
    end if
    i = InStr(s, "/")
    if i > 1 then
      s = Mid(s, 1, i - 1)
    end if

    getHost = s

  end function

  function IsValidEmail(email)

    dim names, name, i, c

    ' Check for valid syntaks i e-mail adressen.

    IsValidEmail = true
    names = Split(email, "@")
    if UBound(names) <> 1 then
      IsValidEmail = false
      exit function
    end if
    for each name in names
      if Len(name) <=  0 then
        IsValidEmail = false
        exit function
      end if
      for i = 1 to Len(name)
        c = Lcase(Mid(name, i, 1))
        if InStr("abcdefghijklmnopqrstuvwxyz_-.", c) <= 0 and not IsNumeric(c) then
          IsValidEmail = false
          exit function
        end if
      next
      if Left(name, 1) = "." or Right(name, 1) = "." then
        IsValidEmail = false
        exit function
      end if
    next
    if InStr(names(1), ".") <= 0 then
      IsValidEmail = false
      exit function
    end if
    i = Len(names(1)) - InStrRev(names(1), ".")
    if i <> 2 and i <> 3 then
      IsValidEmail = false
      exit function
    end if
    if InStr(email, "..") > 0 then
      IsValidEmail = false
    end if

  end function

  function FormFieldList()

    dim str, i, name

    ' Opbyg et array af formfeltnavne i den rækkefølge, de blev modtaget.

    str = ""
    for i = 1 to Request.Form.Count
      for each name in Request.Form
        if Left(name, 1) <> "_" and Request.Form(name) is Request.Form(i) then
          if str <> "" then
            str = str & ","
          end if
          str = str & name
          exit for
        end if
      next
    next
    FormFieldList = Split(str, ",")

  end function

  function SendMail()

    dim mailObj
    dim addrList

    ' Send e-mail baseret på mailkomponent. Brug global variable som parametre, da der er så mange.

    SendMail = ""

    ' Send e-mail (CDONTS version), understøtter ikke reply-to adressen og her ingen fejlchecking.

    if mailComp = "CDONTS" then
      set mailObj = Server.CreateObject("CDONTS.NewMail")
      mailObj.BodyFormat = 0
      mailObj.MailFormat = 0
      mailObj.From = fromAddr
      mailObj.To = recipients
      mailObj.Subject = subject
      mailObj.Body = body
      mailObj.Send
    end if

    ' Send e-mail (JMail version).

    if mailComp = "JMail" then
      set mailObj = Server.CreateObject("JMail.SMTPMail")
      mailObj.Silent = true
      mailObj.ServerAddress = smtpServer
      mailObj.Sender = fromAddr
      mailObj.ReplyTo = replyTo
      mailObj.Subject = subject
      addrList = Split(recipients, ",")
      for each addr in addrList
        mailObj.AddRecipient Trim(addr)
      next
      mailObj.ContentType = "text/html"
      mailObj.Body = body
      if not mailObj.Execute then
        SendMail = "Email send failed: " & mailObj.ErrorMessage & "."
      end if
    end if

    ' Send e-mail (ASPMail version).

    if mailComp = "ASPMail" then
      set mailObj = Server.CreateObject("SMTPsvg.Mailer")
      mailObj.FromAddress = fromAddr
      mailObj.RemoteHost  = smtpServer
      mailObj.ReplyTo = replyTo
      for each addr in Split(recipients, ",")
        mailObj.AddRecipient "", Trim(addr)
      next
      mailObj.Subject = subject
      mailObj.ContentType = "text/html"
      mailObj.BodyText = body
      if not mailObj.SendMail then
        SendMail = "Email send failed: " & mailObj.Response & "."
      end if
    end if

  end function %>

lukker