hjælp til "Hot or not" som er lavet af Thomas Daugaard

Det er fordi du skal bruge en MySQL database... Den MySQL database skal angives hvor den ligger henne... Her kan jeg se at den er angivet til at ligge på din Localhost, hvilket er din egen computer.. Du skal så her skrive IP adressen / domænenavnet for din MySQL database, som evt. kunne ligge hos din udbyder...

//>Rune

Det her giver nok en lidt bedere forståelse:

mySQL

mySQL (ODBC)

objConn.Open "Driver={mySQL}; Server=ServerNavn; Option=16834; Database=DatabaseNavn;"
mySQL (remote) (ODBC)

objConn.Open "Driver={mySQL}; Server=host.domain.com; Port=3306; Option=131072; Stmt=; Database=DatabaseNavn; uid=Brugernavn; pwd=Adgangskode;"


//>Rune

Medions>> nu er jeg ikke lige den store haj til det med Databaser og asp......  men hvor er det lige jeg skal lave det om henne?

Prøv at vis mig de linjer som fejlene kommer i.. Så skal jeg prøve at replace det for dig...

//>Rune

Response.Buffer = True
    Session.LCID = 1030
    Randomize

%><!--#include file="inc_settings.asp" --><%

    ' ------------------------------------------------------------------------------------------
    '/ ADVARSEL: Hvis koden under denne linie ændres er det ikke sikkert at systemet            \
    '\          fortsat vil virke korrekt, med mindre det er angivet!                            /
    ' ------------------------------------------------------------------------------------------

    Set Conn = Server.CreateObject("ADODB.Connection")
    Conn.Open "DRIVER=mysql; SERVER=" & sql_Server & "; DATABASE=" & sql_DB & "; UID=" & sql_UID & "; PWD=" & sql_PWD

    strMode = LCase(Request("mode"))
    strPID = Request("pid"):          If Not IsNumeric(strPID) Then strPID = ""
    strLastPID = Request("last_pid"): If Not IsNumeric(strLastPID) Then strLastPID = ""
    Page_ShowMenu = True

    bolWasPosted = (Request.ServerVariables("HTTP_METHOD") = "POST")
    SessionID = Request.Cookies("sessionid")
    If SessionID = "" Then
        Response.Cookies("sessionid") = Session.SessionID
        Response.Cookies("sessionid").Expires = DateAdd("yyyy", 1, Now)
        SessionID = Session.SessionID
    End If
    RemoteAddress = Request.ServerVariables("REMOTE_ADDR")

    If strMode = "list" Then
        strGender = Request("gender"): If strGender = "" Then strGender = "1"
        strType = Request("type"):      If strType = "" Then strType = "0"

        Select Case strType
            Case "0": Page_Caption = "Seneste " & ListSize
            Case "1": Page_Caption = "Top " & ListSize
        End Select

        Select Case strGender
            Case "1": Page_Caption = Page_Caption & " kvinder"
            Case "2": Page_Caption = Page_Caption & " mænd"
            Case "3": Page_Caption = Page_Caption & " børn"
        End Select
    ElseIf strMode = "savefakereport" And bolWasPosted Then
        strReason = Request("reason")

        strMail = Replace(strEMOF, "#pid", strPID) & strReason

        bolIsOK = SendMail(OwnerEmail, "Anmeldelse af fake billede!", strMail)
        strMode = "report_fake"

        Page_Caption = "Anmeld fake billede"
        Page_ShowMenu = False
    ElseIf strMode = "savecomment" And bolWasPosted Then
        strName = DeMessSQL(Server.HTMLEncode(Request("name")))
        strEmail = DeMessSQL(Request("email"))
        strSubject = DeMessSQL(Server.HTMLEncode(Request("subject")))
        strComment = DeMessSQL(Server.HTMLEncode(Request("comment")))

        Conn.Execute "INSERT INTO comments (pid,fromname,email,subject,comment,datetime) VALUES (" & strPID & ",'" & strName & "','" & strEmail & "','" & strSubject & "','" & strComment & "',now())"
        Set Rs = Conn.Execute("SELECT name,email FROM persons WHERE id=" & strPID)

        strText = Replace(strEMOC, "#navn", Rs(0))
        bolSuccess = SendMail(CStr(Rs(1)), "Besked til dig på Hot Or Not...", strText)

        Page_Caption = "Kommentar sendt!"
        Response.Redirect "default.asp?mode=commentsent&pid=" & strPID
    ElseIf strMode = "delete_comment" Then
        strID = Request("id"): If strID = "" Or Not IsNumeric(strID) Then Response.Redirect "default.asp?mode=read_comments"

        Conn.Execute "DELETE FROM comments WHERE id=" & strID & " AND pid=" & Session("id")

        Response.Redirect "default.asp?mode=read_comments"
    ElseIf strMode = "vote" And bolWasPosted Then
        Session("onlyvote") = Request("onlyvote")
        strVote = Request("vote")

        strLastGender = Request("gender")
        If strLastGender = "1" Then strLastGender = "2" Else strLastGender = "1"

        bolVoteIsOK = False

        Set Rs = Conn.Execute("SELECT id FROM votes WHERE sessionid='" & SessionID & "' AND pid=" & strPID)
        If Rs.BOF And strVote > "" And IsNumeric(strVote) Then
            If CInt(strVote) > 0 And CInt(strVote) < 11 Then
                Conn.Execute "UPDATE hits SET raters=raters+1,vote" & strVote & "=vote" & strVote & "+" & strVote & " WHERE pid=" & strPID
                Conn.Execute "INSERT INTO votes (sessionid,pid,ip,vote,datetime) VALUES ('" & SessionID & "'," & strPID & ",'" & RemoteAddress & "'," & strVote & ",now())"

                bolVoteIsOK = True
            End If
        End If

        strWhere = " WHERE id<>" & strPID
        If Session("onlyvote") > "" And Not Session("onlyvote") = "0" Then strWhere = strWhere & " AND gender=" & Session("onlyvote")

        Set Rs = Conn.Execute("SELECT id,rand() AS rnd FROM persons" & strWhere & " ORDER BY rnd LIMIT 0,1")
        If Not Rs.BOF Then
            strNewPID = Rs(0)

            Select Case bolVoteIsOK
                Case True:  Response.Redirect "default.asp?last_pid=" & strPID & "&gender=" & strLastGender & "&pid=" & strNewPID
                Case False: Response.Redirect "default.asp?gender=" & strLastGender & "&pid=" & strNewPID
            End Select
        Else
            Response.Redirect "default.asp?mode=np"
        End If
    ElseIf strMode = "logout" Then
        Session.Abandon
        Response.Redirect "default.asp"
    ElseIf strMode = "login" Then
        strEmail = DeMessSQL(Request("email"))
        strPass = DeMessSQL(Request("pass"))

        Page_Caption = "Redigér profil"
        Page_ShowMenu = False

        bolLoginSuccessfull = True
        If strEmail > "" And strPass > "" And bolWasPosted Then
            Set Rs = Conn.Execute("SELECT id,email,password FROM persons WHERE email='" & strEmail & "' AND password='" & strPass & "'")
            If Not Rs.BOF Then
                Session("id") = Rs(0)
                Session("email") = Rs(1)
                Session("pass") = Rs(2)

                Response.Redirect "default.asp?mode=login"
            Else
                bolLoginSuccessfull = False
            End If
        End If

        bolIsValid = (Session("email") > "" And Session("pass") > "" And Session("id") > "")
    ElseIf strMode = "delete_pic" And Session("id") > "" Then
        Set Rs = Conn.Execute("SELECT picturefile FROM persons WHERE id=" & Session("id"))
        strPicture = Rs(0)

        Set fso = Server.CreateObject("Scripting.FileSystemObject")
        fso.DeleteFile Server.MapPath("pictures/" & Session("id") & "_" & strPicture), True
        Set fso = Nothing

        Conn.Execute "DELETE FROM persons WHERE id=" & Session("id")
        Conn.Execute "DELETE FROM hits WHERE pid=" & Session("id")
        Conn.Execute "DELETE FROM comments WHERE pid=" & Session("id")

        Response.Redirect "default.asp"
    ElseIf strMode = "commentsent" Then
        Page_Caption = "Kommentar sendt :-)"
        Page_ShowMenu = False
    ElseIf strMode = "send_comment" Then
        Page_Caption = "Send kommentar"
        Page_ShowMenu = False
    ElseIf strMode = "signup" Or strMode = "confirm" Then
        Page_Caption = "Tilmelding"
        Page_ShowMenu = False
    ElseIf strMode = "report_fake" Then
        Page_Caption = "Anmeld fake billede"
        Page_ShowMenu = False
    ElseIf strMode = "read_comments" Then
        Page_Caption = "Kommentarer"
        Page_ShowMenu = False
    ElseIf strMode = "read_comment" Then
        Page_Caption = "Læs kommentar"
        Page_ShowMenu = False
    ElseIf strMode = "np" Then
        Page_Caption = "Ingen profiler"
        Page_ShowMenu = False
    ElseIf strMode = "edit_profile" And Session("id") > "" Then
        Page_Caption = "Ret dine informationer"
        Page_ShowMenu = False
    ElseIf strMode = "pic_stat" And Session("id") > "" Then
        Page_Caption = "Din statistik"
        Page_ShowMenu = False
    ElseIf strMode = "upload_new" And Session("id") > "" Then
        Page_Caption = "Upload nyt billede"
        Page_ShowMenu = False
    ElseIf strMode = "" Then
        Page_Caption = "Vis profil"

        If strPID = "" Then
            If Session("onlyvote") > "" And Not Session("onlyvote") = "0" Then strWhere = " WHERE gender=" & Session("onlyvote")
            Set Rs = Conn.Execute("SELECT id,rand() AS rnd FROM persons" & strWhere & " ORDER BY rnd LIMIT 0,1")
            If Not Rs.BOF Then
                strPID = Rs(0)
                Response.Redirect "default.asp?pid=" & strPID
            Else
                Response.Redirect "default.asp?mode=np"
            End If
        End If
    End If

    If Page_Caption > "" Then
        Page_Header = Page_Caption
        Page_Caption = " - " & Page_Caption
    End If
%>

Hmm det var ikke nok, jeg skal oxo lige se denne fil:

inc_settings.asp

//>Rune

<%
    ' Liste størrelser i personer
    Const ListSize = 25
    ' Hvor mange der skal have stemt på en, før brugeren kan komme på en Top liste.
    Const RatersBeforeTop = 20   
    ' Sitets base adresse. (SKAL ende på /)
    Const BaseAddress = "http://tdaugaard.place.nu/"
    ' Emailen på ejeren af sitet (en gyldig POP3 email)
    Const OwnerEmail = "hotornot@tdaugaard.dk"
    ' Ret til din egen SMTP server
    Const SMTPServer = "mail.data-doktorn.nu"
    ' Ret til dit site's navn
    Const SenderName = "Hot Or Not"
    ' Max billede størrelse i bytes
    Const MaxFileSize = 204800 ' 200 KB

    ' Din mySQL server
    Const sql_Server = ""
    ' Dit brugernavn til mySQL'en
    Const sql_UID = ""
    ' Dit password til mySQL'en
    Const sql_PWD = ""
    ' mySQL database navnet
    Const sql_DB = ""

    ' Emailen der bliver sendt til en bruger når der bliver skrevet en kommentar. (EMOC=EMailOnComment)
    ' #navn bliver erstattet med brugerens navn.
    strEMOC = "Hej #navn," & vbCrLf
    strEMOC = strEMOC & "Du har modtaget en besked inde på Hot Or Not." & vbCrLf & vbCrLf
    strEMOC = strEMOC & "Klik dig ind på " & BaseAddress & "default.asp?mode=login for at læse den." & vbCrLf & vbCrLf
    strEMOC = strEMOC & "Med venlig hilsen, Hot Or Not."
   
    ' Emailen der bliver sendt når en person opretter sig i systemet. (EMVO=EMailVedOprettelse)
    ' #navn og #pid bliver erstattet med hhv. personens navn samt ProfileID.
    strEMVO = "Hej #navn," & vbCrLf
    strEMVO = strEMVO & "Du er nu oprettet på Hot Or Not." & vbCrLf & vbCrLf
    strEMVO = strEMVO & "Du kan se dit billede samt tekst på:" & vbCrLf & vbCrLf & "  " & BaseAddress & "default.asp?pid=#pid" & vbCrLf & vbCrLf
    strEMVO = strEMVO & "Du kan logge ind og rette din profil til hver en tid på" & vbCrLf & vbCrLf & "    " & BaseAddress & "default.asp?mode=login" & vbCrLf & vbCrLf
    strEMVO = strEMVO & "Mvh, Hot Or Not"

    ' Emailen der bliver sendt når der bliver rapporteret om et fake billede. (EMOF=EMailOnFake)
    ' #pid bliver erstattet med brugerens ProfileID.
    strEMOF = "Hejsa!" & vbCrLf & vbCrLf
    strEMOF = strEMOF & "En anmeldelse vedr. et fake billede er blevet sendt:" & vbCrLf & vbCrLf
    strEMOF = strEMOF & "-------------------------------" & vbCrLf
    strEMOF = strEMOF & "Billede ID: #pid" & vbCrLf & vbCrLf
   
    ' Forskellinge funktioner der bruges til diverse ting. RET IKKE I DEM!

    Function SendMail(strTo, strSubject, strMail)
        Set JMail = Server.CreateObject("JMail.SMTPMail")

        JMail.ServerAddress = SMTPServer
        JMail.SenderName = SenderName
        JMail.Sender = CStr(OwnerEmail)

        JMail.AddRecipient strTo
        JMail.Subject = strSubject
        JMail.Body = strMail
        JMail.Silent = True

        SendMail = JMail.Execute()
    End Function

    Function IsEmail(strEmail)
        Set objRegExpEMail = New RegExp

        objRegExpEMail.Pattern = "([\w\._-]+@[\w\._-]+\.[A-Za-z]{2,4}\S*)"
        objRegExpEMail.Global = False
        objRegExpEMail.IgnoreCase = True

        IsEmail = objRegExpEMail.Test(strEmail)

        Set objRegExpEMail = Nothing
    End Function

    Function DeMessSQL(strSource)
        DeMessSQL = Replace(strSource, "'", "''")
    End Function

    Function ResizeIImage(strImage, lngMaxWidth)
        Set Image = Server.CreateObject("AspImage.Image")

        Image.LoadImage strImage

        If Image.MaxX > lngMaxWidth Then
            intRatio = ((lngMaxWidth * 100) / Image.MaxX)
            intNewY = CInt(Image.MaxY * (intRatio / 100))
            Image.ResizeR lngMaxWidth, intNewY

            Select Case (LCase(Right(strImage, 3)) = "jpg")
                Case True
                    Image.ProgressiveJPEGEncoding = True
                    Image.ImageFormat = 1
                Case False
                    Image.ImageFormat = 3
            End Select

            Image.FileName = strImage
            Image.SaveImage
        End If

        Set Image = nothing   
    End Function
%>

Det er så disse felter du skal udfylde med dine oplysninger til din MySQL database:

    ' Din mySQL server
    Const sql_Server = ""
    ' Dit brugernavn til mySQL'en
    Const sql_UID = ""
    ' Dit password til mySQL'en
    Const sql_PWD = ""
    ' mySQL database navnet
    Const sql_DB = ""

Det kune fx. være :

    ' Din mySQL server
    Const sql_Server = "80.16.226.226"
    ' Dit brugernavn til mySQL'en
    Const sql_UID = "medions"
    ' Dit password til mySQL'en
    Const sql_PWD = "medionsdk"
    ' mySQL database navnet
    Const sql_DB = "hotornotsys"

-men du er jo nødt til at ha' en udbyder der supportere en MySQL database... Har du det?

//>Rune

Thx 4 Poinz

//>Rune