Stort problem ... fejl på en pc, men ikke fejl på den anden!

Kan jeg ikke lige prøve at se hele din kode!

//>Rune

hvis det er en access database du bruger skal du vaere sikker paa at der er skrive adgang i det bibliotek som den ligger i. Mange udbyder har et bib som der er skrive adgang til.

mht. til om databasen ligger i en skrivebar mappe: det er i orden, den ligger under mappen /data, og der er skriveadgang. Desuden kan jeg køre det hele uden probs fra min og to andre computere.

Jeg velaegger lige koden:
<%
Session.LCID = 1030
response.buffer = true
Const adOpenKeyset = 1
Const adLockOptimistic = 3

Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "PROVIDER=MSDASQL;DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Server.MapPath("../../data/xyz.mdb") & ";UID=admin;PWD=;"

    Set rs = Server.CreateObject("ADODB.RecordSet")
    strSQL = "Select * From kalender"
    rs.Open strSQL, Conn, adOpenKeyset, adLockOptimistic

'--------------------------------------------------
' Klargøring af variablen NewString (--> rs("Eventtid"))
'--------------------------------------------------
myDay = request.form("dg")
myMonth = request.form("md")
myYear = request.form("aar")

if len(myDay) = 1 then Myday = "0" & Myday End if
if len(myMonth) = 1 then MyMonth = "0" & MyMonth End if
NewString = MyYear & "" & MyMonth & "" & MyDay

'--------------------------------------------------
' Klargøring af variablen Dato (--> rs("dato"))
'--------------------------------------------------
RigtigTid = myDay & "-" & myMonth & "-" & myYear
Dato = Day(RigtigTid) & ". " & MonthName (Month(RigtigTid)) &" " & Year (RigtigTid) & " " & WeekdayName (Weekday(RigtigTid))

'--------------------------------
' Bug-retning af e-mail-problem + tid-problem
'--------------------------------
'Persons e-mail
Email = Request.form("email")
If Email = "" then
    Email = " "
End if

'Arrangørs e-mail
ArrEmail = Request.Form("arranemail")
If ArrEmail = "" then
    ArrEmail = " "
End if

'Tid for arrangement
ArrTid = Request.Form("tid")
If ArrTid = "" then
    ArrTid = " "
End if


      rs.AddNew
      '--------------------------
      '1. del
      '--------------------------
      rs("AdNavn") = Request.form("navn")
      rs("AdAdresse") = Request.form("adresse")
      rs("AdPostnr") = Request.form("postnr")
      rs("AdBy") = Request.Form("by")
      rs("AdTelefon") = Request.Form("telefon")
      rs("AdEmail") = Email
     
      '---------------------------
      '2.del
      '---------------------------
      rs("Dato") = Dato 
      rs("Tid") = ArrTid
      rs("Navn") = Request.Form("arrangoer")
      rs("Email") = Request.Form("arranemail")
      rs("Overskrift") = request.form("overskrift")
      rs("Besked") = Request.form("beskrivelse")
      rs("Aflyst") = "Nej"
      rs("eventtid") = NewString
      rs("godkendt") = false
      rs("ip") = Request.ServerVariables("Remote_addr")
      rs.Update

    rs.Close
    Set rs = Nothing

Conn.Close
set Conn = Nothing
response.clear
response.write "<link rel=""stylesheet"" type=""text/css"" href=""../../data/css.css"">"
response.write ("<center>Dit arrangement er registreret!<br><a target=""main"" href=""java script:parent.main.history.go(-2)""><img border=""0"" src=""../../images/ikoner/tilbage.gif""> Tilbage</a>")
%>

Fejlen kan komme hvis du angiver tomme felter (NULL) og kolonne i databasen ikke tillader nullængde strenge.

Det kan også være fordi du indsætter en række, der forbryder sig mod en primær nøgle i tabellen. Hvis navn el. email er primær nøgle og du indsætter en værdi som findes i forvejen, går det ikke.

Prøv evt med en anden database driver, hvis udbyderen har en ældre kan det måske være derfor, prøv med OLE DB driveren:

connStr = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.Mappath("database.mdb")

Problemet er nu løst! Jeg ændrede provideren, og så stoppede det! Tax!

:) det var så lidt.

Du ska lige lukke spørgsmålet ved at acceptere et eller flere svar :)