Databse omskrivning?

Du skal bruge rs.Open for at paging virker det virk ikke med:
Set rs = Conn.Execute(strSQL)

Set rs = Server.CreateObject("ADODB.RecordSet")  'hvis du ikke har den
rs.Open SQL, Conn,1

Så det du siger er altså at jeg ikke kan bruge den  databaseforbindelse jeg har idag til at køre det her paging...
Men skal bruge den anden ik?

Hvor finder jeg mere info om den anden databaseforbindelse ?
PFT

Nej det siger jeg ikke. Jeg siger du skal åbne recordset'et på denne måde rs.Open

Du kan godt beholde din connection.

Stadig ikke helt med kan du ikke vise det i koden ?

Her er din kode nu:

Set Conn = Server.CreateObject("ADODB.Connection")
DSN = "DRIVER={Microsoft Access Driver (*.mdb)}; "
DSN = DSN & "DBQ=" & Server.MapPath("demo.mdb")
Conn.Open DSN

strSQL = "SELECT LinkURL FROM Links"
Set rs = Conn.Execute(strSQL)


---
Det skal laves om til dette:

Set Conn = Server.CreateObject("ADODB.Connection")
Set rs = Server.CreateObject("ADODB.RecordSet")
DSN = "DRIVER={Microsoft Access Driver (*.mdb)}; "
DSN = DSN & "DBQ=" & Server.MapPath("demo.mdb")
Conn.Open DSN

strSQL = "SELECT LinkURL FROM Links"
rs.Open SQL, Conn,1

sidste linie skal være med strSQL og ikke kun SQL:

rs.Open strSQL, Conn,1

Side 1 viker men det gør de andre ikke

<!--http://activedeveloper.dk/aspdigital/kapitel2/paging.asp-->

<html><head>
<title>Paging af et recordset</title>
</head><body>

<%
intPage = Request("page")
If isNumeric(intPage) = False Or intPage < 1 Then
    intPage = 1
End If

Set Conn = Server.CreateObject("ADODB.Connection")
Set rs = Server.CreateObject("ADODB.RecordSet")
DSN = "DRIVER={Microsoft Access Driver (*.mdb)}; "
DSN = DSN & "DBQ=" & Server.MapPath("demo.mdb")
Conn.Open DSN

strSQL = "SELECT LinkURL FROM Links"
rs.Open strSQL, Conn,1

If Not (rs.BOF Or rs.EOF) Then
    rs.PageSize = 10
    rs.AbsolutePage = intPage
    intRecCount = rs.PageSize
    intPageCount = rs.PageCount
    Response.Write "<p><b>Side " & intPage & " af " & intPageCount & "</b></p>"
    Do While Not rs.EOF And intRecCount > 0
        Response.Write rs("LinkURL") & "<br>"
    intRecCount = intRecCount - 1
    rs.MoveNext
    Loop
End If
rs.Close
Set rs = Nothing

Response.Write "<p>Gå til side "
For intNum = 1 To intPageCount
    Response.Write "<a href=paging.asp?page=" & intNum & ">" & intNum & "</a> "
Next

Response.Write "<p>"
If Clng(intPage) > 1 Then
    Response.Write "<a href=paging.asp?page=" & intPage - 1 & ">&lt;&lt;</a>"
Else
    Response.Write "&lt;&lt;"
End If

Response.Write "&nbsp;"

If Clng(intPage) < Clng(intPageCount) Then
    Response.Write "<a href=paging.asp?page=" & intPage + 1 & ">&gt;&gt;</a> "
Else
    Response.Write "&gt;&gt;"
End If
%>

</body></html>

Hedder filen paging.asp ?

den hedder paging.asp

Hvad sker der? Kommer der fejl, forkert side, blankside??

Der kom bare bare en blankside men idag virker det sjovt nok og jeg har ikke ændret i koden??? *Spøjst*

Mange tak for hjælpen eagleeye You R the man !!!!