check objekt script

Hallo kom nu lidt kvikt, det haster!!!!!!!!!!

Rolig nu. :)

Jeg har lavet et script, der kan teste om forskellige komponenter er installeret på en server. Tilføj evt. selv flere komponenter i array'et i toppen af siden, hvis du ønsker at teste på flere.

<html>
<head>
    <title>Server Info | <%=Request.ServerVariables("SERVER_NAME")%></title>
    <style>BODY, TD {font-family:Verdana;font-size:11px;color:#333333;}</style>
</head>
<body>
<%
Dim arrComponents, arrIsInstalled

arrComponents = Array("JMail.Message", "CDONTS.NewMail", "Microsoft.XMLDOM", "Microsoft.XMLHTTP", "Persits.Upload.1", "Scripting.FileSystemObject", "SMTPsvg.Mailer")

ReDim arrIsInstalled(UBound(arrComponents))

strServer = request.servervariables("SERVER_NAME")
strHost = request.servervariables("SERVER_SOFTWARE")
set objConn=server.createobject("ADODB.Connection")
strMDAC = objConn.version
set objConn= nothing
strScript = scriptenginemajorversion&"."&scriptengineminorversion

On Error Resume Next

For i = 0 To UBound(arrComponents)
   
    Set objTest = Server.CreateObject(arrComponents(i))
   
    If Err.number = 0 Then
   
        strVersion = objTest.Version
       
        If Len(strVersion) = 0 Then
       
            arrIsInstalled(i) = "Yes"
           
        Else
           
            arrIsInstalled(i) = "Yes (" & strVersion & ")"
           
        End If
       
        strVersion = ""       
       
    Else
   
        arrIsInstalled(i) = "No"   
   
    End If
   
    Err.Clear
   
    Set objTest = Nothing
   
Next

%>
<table width="100%" cellspacing="5" cellpadding="5" border="0">
    <tr>
        <td width="200"><b>Domain:</b></td>
        <td><%=strServer%></td>
    </tr>
    <tr>
        <td><b>Server Software:</b></td>
        <td><%=strHost%></td>
    </tr>
    <tr>
        <td><b>MDAC Version:</b></td>
        <td><%=strMDAC%></td>
    </tr>
    <tr>
        <td><b>VBScript Version:</b></td>
        <td><%=strScript%></td>
    </tr>
</table>
<br>
<table width="100%" cellspacing="5" cellpadding="5" border="0">
<% For i = 0 To UBound(arrComponents) %>
    <tr>
        <td width="200"><b><%=arrComponents(i)%>:</b></td>
        <td><%=arrIsInstalled(i)%></td>
    </tr>
<% Next %>
</table>
</body>
</html>

Det var et strålende script, tak - du får point.

Men du skulle vel ikke vide hvordan man installere CDONTS, for den mangler i min IIS SMTP server :-((

Eller hent: http://www.netsrac.dk/netsrac-dk/aspadmin/aspadminv20.zip