Avatar billede dontron Nybegynder
27. marts 1999 - 00:00 Der er 12 kommentarer og
1 løsning

Lav en View SourceCode, som viser HTML tags og ASP på en side (hvordan?)

Jeg vil gerne ha så jeg kan lave
<a href="MinSide.asp">Prøv den</a>
og
<a href="VisMinSide.asp">Se sourcekoden</a>

Den der VisMinSide.asp skal så vise sourcen for brugeren.

Jeg ved kan kan bruge
Response.Write Server.HTMLEncode("    <td>bla bla</td>") osv...
Men det tager eddermame laaang tid når ens source er på 400 linier. Findes der ikke en måde at gøre dette på som er lettere??

Takker på forhånd

- DånTrån :-))
Avatar billede Dan Nim Seniormester
27. marts 1999 - 01:15 #1
jo, det gør der !. Finde den lige
Avatar billede reupke Nybegynder
27. marts 1999 - 01:16 #2
Dette her skulle hjælp dig på vej :)

<%
Sourcefil = "MinSide.asp"

fil = Request.ServerVariables("APPL_PHYSICAL_PATH") + Sourcefil

Set filesystemObject=CreateObject("Scripting.FileSystemObject")
Set mFile = fileSystemObject.GetFile(fil)
Set openFile = mFile.OpenAsTextStream(1, TristateUseDefault)   

do while not openFile.AtEndOfStream
    line=openFile.ReadLine               
    response.write Server.HTMLEncode(line) 
    response.write "<br>" & chr(10)
loop
openFile.close
%>
Avatar billede Dan Nim Seniormester
27. marts 1999 - 01:22 #3
Hvorfor viser du ike bare siden som en TXT fil ?
Avatar billede Dan Nim Seniormester
27. marts 1999 - 01:24 #4
Eller prøv at sætte <XMP> & </XMP> rundt om alt dit html kodening
Avatar billede asp Nybegynder
27. marts 1999 - 01:27 #5
Det hjælper ikke meget at sætte <xmp></xmp> omkring sine ASP koder! :-(
Avatar billede Dan Nim Seniormester
27. marts 1999 - 01:30 #6
ASP : Nej. men jeg skrev alsår også HTML koder !.

dontron gav som eks.

Response.Write Server.HTMLEncode("    <td>bla bla</td>")

Hvis du fjerner
Response.Write Server.HTMLEncode("

Så bliver det sq til HTML koder, har jeg ret ?
Avatar billede asp Nybegynder
27. marts 1999 - 01:38 #7
JA, men ønsket var jo "Lav en View SourceCode, som viser HTML tags og ASP på en side", bemærk OG ASP
Derfor skriver jeg at det ikke hjælper at sætte <xmp>... bl.a.

Hvis man skulle bruge <xmp> skulle han jo have 2 "ens" dokumenter til at ligge og flyde på serveren, Har jeg ret..?
Avatar billede Dan Nim Seniormester
27. marts 1999 - 01:41 #8
Hummmm. Hvis han vil lave en View SOURCE i en bowser, kan han jo ikke se noget ASP, men kun HTML.
Avatar billede asp Nybegynder
27. marts 1999 - 01:44 #9
Det er ikke korrekt, hvis han bruger idéen fra reupke, kan han faktisk få eksponeret ASP Sourcen, i browseren.
Avatar billede Dan Nim Seniormester
27. marts 1999 - 01:47 #10
`hummm. Okay. Jeg trækker mig ( har ikke prøvet scripte, men det skal nok passe )
Avatar billede wall Nybegynder
27. marts 1999 - 01:57 #11
View Active Server Page Source

<script LANGUAGE="VBScript" RUNAT="Server">



FUNCTION fValidPath (ByVal strPath)
  If InStr(1, strPath, "/din mappe/", 1) Then
    fValidPath = 1
  Else
    fValidPath = 0
  End If
END FUNCTION
</script>
<script LANGUAGE="VBScript"
RUNAT="Server">
REM Returns the minimum number greater than 0
REM If both are 0, returns -1
FUNCTION fMin (iNum1, iNum2)
  If iNum1 = 0 AND iNum2 = 0 Then
    fMin = -1
  ElseIf iNum2 = 0 Then
    fMin = iNum1
  ElseIf iNum1 = 0 Then
    fMin = iNum2
  ElseIf iNum1 < iNum2 Then
    fMin = iNum1
  Else
    fMin = iNum2
  End If
END FUNCTION
</script>
<script LANGUAGE="VBScript" RUNAT="Server">
FUNCTION fCheckLine (ByVal strLine)

  fCheckLine = 0
  iTemp = 0

  iPos = InStr(strLine, "<" & "%")
  If fMin(iTemp, iPos) = iPos Then
    iTemp = iPos
    fCheckLine = 1
  End If
 
  iPos = InStr(strLine, "%" & ">")
  If fMin(iTemp, iPos) = iPos Then
    iTemp = iPos
    fCheckLine = 2
  End If

  iPos = InStr(1, strLine, "<" & "SCRIPT", 1)
  If fMin(iTemp, iPos) = iPos Then
    iTemp = iPos
    fCheckLine = 3
  End If

  iPos = InStr(1, strLine, "<" & "/SCRIPT", 1)
  If fMin(iTemp, iPos) = iPos Then
    iTemp = iPos
    fCheckLine = 4
  End If

END FUNCTION
</script>
<script
LANGUAGE="VBScript" RUNAT="Server">
SUB PrintHTML (ByVal strLine)
    iSpaces = Len(strLine) - Len(LTrim(strLine))
    i = 1
    While Mid(Strline, i, 1) = Chr(9)
        iSpaces = iSpaces + 5
        i = i + 1
    Wend
  If iSpaces > 0 Then
    For i = 1 to iSpaces
      Response.Write("&nbsp;")
    Next
  End If
  iPos = InStr(strLine, "<")
  If iPos Then
    Response.Write(Left(strLine, iPos - 1))
    Response.Write("&lt;")
    strLine = Right(strLine, Len(strLine) - iPos)
    Call PrintHTML(strLine)
  Else
    Response.Write(strLine)
  End If
END SUB
</script>
<script LANGUAGE="VBScript" RUNAT="Server">
SUB PrintLine (ByVal strLine, iFlag)
  Select Case iFlag
    Case 0
      Call PrintHTML(strLine)
    Case 1
      iPos = InStr(strLine, "<" & "%")
      Call PrintHTML(Left(strLine, iPos - 1))
      Response.Write("<FONT COLOR=#ff0000>")
      Response.Write("&lt;%")
      strLine = Right(strLine, Len(strLine) - (iPos + 1))
      Call PrintLine(strLine, fCheckLine(strLine))
    Case 2
      iPos = InStr(strLine, "%" & ">")
      Call PrintHTML(Left(strLine, iPos -1))
      Response.Write("%&gt;")
      Response.Write("</FONT>")
      strLine = Right(strLine, Len(strLine) - (iPos + 1))
      Call PrintLine(strLine, fCheckLine(strLine))
    Case 3
      iPos = InStr(1, strLine, "<" & "SCRIPT", 1)
      Call PrintHTML(Left(strLine, iPos - 1))
      Response.Write("<FONT COLOR=#0000ff>")
      Response.Write("&lt;SCRIPT")
      strLine = Right(strLine, Len(strLine) - (iPos + 6))
      Call PrintLine(strLine, fCheckLine(strLine))
    Case 4
      iPos = InStr(1, strLine, "<" & "/SCRIPT>", 1)
      Call PrintHTML(Left(strLine, iPos - 1))
      Response.Write("&lt;/SCRIPT&gt;")
      Response.Write("</FONT>")
      strLine = Right(strLine, Len(strLine) - (iPos + 8))
      Call PrintLine(strLine, fCheckLine(strLine))
    Case Else
      Response.Write("FUNCTION ERROR -- PLEASE CONTACT ADMIN.")
  End Select
END SUB
</script>
<% strVirtualPath = Request("source") %>

/Wall
Avatar billede wall Nybegynder
27. marts 1999 - 01:59 #12
Ups..

Du skal bruge code.asp?source=din.asp


/wall
Avatar billede dontron Nybegynder
28. marts 1999 - 03:41 #13
1000 tak til alle
Hva ka jeg sige, eksperten.dk - der får man da svar med det samme, også om natten :-).
Den henleder mig til følgende slogan.

"Jeg kan trygt anbefale eksperten.dk - Sprængfyldt med gode råd - anbefales af topopdrættere"

*ROFL*

Avatar billede Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Loading billede Opret Preview
Kategori
Kurser inden for grundlæggende programmering

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester