Listning af bibliotekter

Kan du bruge det her?


<%

Set filesys = CreateObject("Scripting.FileSystemObject")
Set demofolder = filesys.GetFolder(server.mappath("."))
Set folcoll = demofolder.SubFolders
Response.Write "Subfolders in current folder<br><br>"
For Each subfol in folcoll
Response.Write "<a href=""" & subfol.name & """>" & subfol.name & "</a><br>"
Next

Set demofile = filesys.GetFolder(server.MapPath("."))
Set filecoll = demofile.Files

Response.Write "<br>Files in current folder<br><br>"
For Each fil in filecoll
filist = filist & fil.name & "<br>"
Next
Response.Write filist


%>

Det kan jeg helt sikkert bruge - men når man klikker på linket skal man kunne få listet billederne!  helst i den design skabelon som jeg bruger på resten af siderne!

Jeg må tilstå at jeg endnu ikke er en 100% haj til ASP, så jeg kan desværre ikke hjælpe dig til hvordan du skal gøre. Det ovenstående script er bare et jeg havde liggende, som jeg har fået et andet sted. Men jeg vil tro at det kan tilpasses til dine behov, men der skal så nok nogle andre til som kan hjælpe.

Men denne linie :  Response.Write "<a href=""" & subfol.name & """>" & subfol.name & "</a><br>"

Må vel skulle laves om til noget i stil med

Response.Write "<a href='fotos.asp?mappe=" & subfol.name & "'>" & subfol.name & "</a><br>"

Og på fotos.asp  kan du så lave en 
mappe = Request.Querystring("mappe")

Så ved fotos.asp siden ihvertfald hvilken mappe der skal kigges i.

Sådan lister du filerne i en bestemt mappe (i dette tilfælde billeder):

FolderSpec = Server.Mappath(mappe)
Set FSO = Server.CreateObject("Scripting.FileSystemObject")
Set Folder = FSO.GetFolder(FolderSpec)
Set FolderCollection = Folder.Files
For Each File In FolderCollection
  Response.Write "<img src='" & File.Name & "'><br>"
Next

Tror jeg fik det til at virke... tjek  http://62.242.7.210/fotosystem

I hovedmappen til dit fotoalbum lægger du en fil med denne kode

<%

Set filesys = CreateObject("Scripting.FileSystemObject")
Set demofolder = filesys.GetFolder(server.mappath("."))
Set folcoll = demofolder.SubFolders
Response.Write "<h2>Følgende mapper findes i fotoalbummet</h2>"
For Each subfol in folcoll
Response.Write "<a href='foto.asp?mappe=" & subfol.name & "'>" & subfol.name & "</a><br>"
Next

%>


Og desuden en fil med navnet foto.asp som indeholder denne kode

<%

mappe = Request.Querystring("mappe")

Response.Write "<h2>" & mappe & "</h2>"

Set filesys = CreateObject("Scripting.FileSystemObject")
Set demofile = filesys.GetFolder(Server.Mappath("./" & mappe & "/"))
Set filecoll = demofile.Files

For Each fil in filecoll
If fil.name <> "Thumbs.db" Then
Response.Write "<a target='blank' href='" & mappe & "/" & fil.name & "'><img border='0' width='100' src='" & mappe & "/" & fil.name & "'></a><br><br>"
End If
Next

%>


I filen foto.asp kan du så redigere og sætte det op i det design som du vil have, og det vil så være gældende for alle subfolders i dit fotoalbum

Kunne du bruge det? Fik du det til at virke?

Skal vi snart ha´ lukket her???

Ja, bentbent - luk dit spørgsmål.

Og hvis du ikke ved, hvordan det gøres, så spørg!