her er kilden til ordercust:
<% OPTION EXPLICIT %>
<!-- #include file="usercheck.asp" -->
<!-- #include file="sessioncookie.asp" -->
<!-- #include file="connect.asp" -->
<!-- #INCLUDE FILE="adovbs.inc" -->
<html><head><title>Ordre</title></head><body>
<%
dim strAction
strAction = request("action")
dim arrStatusTXT(2)
arrStatusTXT(0) = "Modtaget."
arrStatusTXT(1) = "Ekspederet."
arrStatusTXT(2) = "Annulleret."
select case strAction
case "view"
ViewOrder
case "place"
WriteOrder
ViewOrder
case else
ViewOrder
end select
' -------------------------------------
' Funktioner/procedurer
' -------------------------------------
sub ViewOrder()
dim strSQLOrder, objRSOrder
dim strSQLLine, objRSLine
dim dblOrderAmount
strSQLOrder = "SELECT ordernum, orderdate, shipdate, orderstatus FROM orders " & _
"WHERE custid = " & Session("activeuser") & _
" ORDER BY Orderdate DESC"
set objRSOrder = server.createobject("ADODB.Recordset")
set objRSLine = server.createobject("ADODB.Recordset")
with objRSOrder
.open strSQLOrder, strConnect, adOpenForwardOnly, adLockReadOnly, adCmdText
while not .EOF
' skriv header
response.write "<h4>Ordrenr: " & .Fields("ordernum") & "</h4>" & _
"Ordredato: " & .Fields("orderdate")
if isnull(.Fields("shipdate")) then
response.write " Sendt: (Ikke afsendt)"
else
response.write " Sendt: " & .Fields("shipdate")
end if
response.write " Status: " & arrStatusTXT(.Fields("orderstatus")) & "<br>"
strSQLLine = "SELECT orderlines.ItemID, items.ItemTXT, " & _
"orderlines.amount, items.price, cancel FROM orderlines " & _
"INNER JOIN items ON " & _
"(orderlines.itemid = items.itemid) " & _
"WHERE ordernum = " & .Fields("ordernum")
dblOrderAmount = 0.0
objRSLine.open strSQLLine, strConnect, adOpenForwardOnly, adLockReadOnly, adCmdText
response.write "<table border=1><tr>" & _
"<td><b>Varenr</b></td>" & _
"<td align=right><b>Antal</b></td>" & _
"<td><b>Navn</b></td>" & _
"<td align=right><b>Pris</b></td>" & _
"<td align=right><b>Pris i alt</b></td>" & _
"</tr>"
while not objRSLine.EOF
' skriv detaljer
response.write "<tr>" & _
"<td>" & objRSLine("ItemID") & "</td>" & _
"<td align=right>" & objRSLine("amount") & "</td>" & _
"<td>" & objRSLine("ItemTXT") & "</td>"
if objRSLine("cancel") = 0 then
response.write _
"<td align=right>" & objRSLine("price") & "</td>" & _
"<td align=right>" & objRSLine("amount")*objRSLine("price") & "</td>"
dblOrderAmount = dblOrderAmount + objRSLine("amount")*objRSLine("price")
else
response.write "<td colspan=2><i>Annulleret!</i></td>"
end if
response.write "</tr>"
objRSLine.movenext
wend
response.write "</table>"
response.write "<p>Beløb i alt: " & dblOrderAmount & "</p>"
objRSLine.close
.movenext
wend
.close
end with
set objRSOrder = Nothing
set objRSLine = Nothing
end sub
sub WriteOrder()
dim strSQL, objCMD
dim intOrderNum
set objCMD = server.createobject("ADODB.Command")
with objCMD
.ActiveConnection = strConnect
.CommandType = adCmdStoredProc
.CommandText = "WriteOrder"
.Parameters.Append .CreateParameter("return", adInteger, _
adParamReturnValue)
.Parameters.Append .CreateParameter("@ordernum", adInteger, _
adParamOutput)
.Parameters.Append .CreateParameter("@custid", adInteger, _
adParamInput)
.Parameters("@custid") = session("activeuser")
.Execute
intOrderNum = .Parameters("@ordernum")
end with
strSQL = "INSERT INTO orderlines " & _
"(itemid, amount, price, ordernum) " & _
"(SELECT basket.itemid, amount, price, " & intOrderNum & " FROM basket " & _
"INNER JOIN items ON (basket.itemid = items.itemid) " & _
"WHERE basket.sessionid = '" & strSessionID & "')"
with objCMD
.ActiveConnection = strConnect
.CommandType = adCmdText
.CommandText = strSQL
.execute
end with
strSQL = "DELETE FROM basket WHERE sessionid = '" & strSessionID & "'"
with objCMD
.ActiveConnection = strConnect
.CommandType = adCmdText
.CommandText = strSQL
.execute
end with
set objCMD = Nothing
end sub
%>
</body></html>
