En lidt primitiv måde, at gøre det på, men som virker.
Du skriver brugernavn og password direkte i ASP filen, men dette kan udvides til, at kunne gemmes i en tekstfil og hentes derfra m.m.
Hvis user/pass er forkert, så sker der ikke noget, men hvis user/pass er rigtigt, så bliver indholdet af filen udført.
I dette tilfælde er det en fil, som en bruger kan hente, men kun hvis bruger's user/pass er rigtigt...
---- kode ----
<%@ Language=VBScript %>
<% Option Explicit %>
<HTML>
<head><Link Rel="stylesheet" HRef="style.css" Type="text/css">
</head>
<body>
<%
Dim DoLogin, UserName, Password, FileName, FilePath, st, MIMEType
'On Error Resume Next ' Gå ikke ned ved fejl (f.eks. hvis filen ikke eksisterer)
DoLogin = (Request.Form("username") <> "") ' Er brugeren ved at logge ind?
If DoLogin Then ' Ja?
Session("LoginUsername") = LCase(Request.Form("username")) ' Gem brugernavn
Session("LoginPassword") = Request.Form("password") ' og adgangskode i session-variabler
' Reload siden: - for at undgå at man møder boksen 'Vil du sende (post)informationen igen?'
Response.Redirect Request.ServerVariables("SCRIPT_NAME") & "?" & _
Request.ServerVariables("QUERY_STRING")
End If
UserName = Session("LoginUsername") ' Hent brugernavn
Password = Session("LoginPassword") ' og adgangskode i session-variabler
' Tjek brugernavn og adgangskode: (kan tjekke vilkårligt mange brugere, hvis man ønsker det)
If (UserName = "test" And Password = "tester") Or (UserName = "user2" And Password = "pwd2") Then
' Brugeren er nu logget ind!
' Evt. kan brugeren logges ud med det samme igen, vha. følgende to linier:
' I så fald får han kun lov til at downloade én fil ad gangen før login igen.
'
Session("LoginUsername") = Empty
Session("LoginPassword") = Empty
'
FileName = Replace(Replace(Request.QueryString("file"), "/", ""), "\", "")
FilePath = "C:\Inetpub\wwwroot\images\" & FileName
Response.Buffer = True ' Vent med at sende output til scriptet er færdigt
Set st = Server.CreateObject("ADODB.Stream") ' Åben Stream-objektet
st.Type = 1 ' Sæt fil-typen til binær
st.Open ' Åben objektet
st.LoadFromFile FilePath ' Åben fil angivet i QyeryStringen: ?file=xxxx
Response.Clear ' Rens output-bufferen
MIMEType = Right(FileName, 4)
select case MIMEType
case ".doc" Response.ContentType = "application/msword"
case ".exe" Response.ContentType = "application/octet-stream"
case ".jpg" Response.ContentType = "image/jpg"
case ".gif" Response.ContentType = "image/gif"
case ".mp2" Response.ContentType = "video/mpeg"
case ".mp3" Response.ContentType = "video/mpeg"
case ".mpa" Response.ContentType = "video/mpeg"
case ".mpe" Response.ContentType = "video/mpeg"
case ".mpg" Response.ContentType = "video/mpeg"
case "mpeg" Response.ContentType = "video/mpeg"
case ".pdf" Response.ContentType = "application/pdf"
case ".rar" Response.ContentType = "application/zip"
case ".txt" Response.ContentType = "plain/txt"
case ".wav" Response.ContentType = "audio/x-wav"
case ".zip" Response.ContentType = "application/zip"
case else Response.ContentType = "image/jpg" ' Default
end select
Response.AddHeader "content-disposition", "inline;filename=" + FileName
Response.BinaryWrite st.Read() ' Udskriv filen til brugeren: (I første omgang bufferen)
st.Close ' Luk Stream-objektet
Set st = Nothing ' Ryd op
Response.End ' Afslut scriptet
Else
' Brugeren er ikke logget ind. Vis login-skærm:
%>
<form method="post" action="<% = Request.ServerVariables("SCRIPT_NAME") & "?" & Request.ServerVariables("QUERY_STRING") %>">
<p>Brugernavn: <input type="text" name="username"></p>
<p>Adgangskode: <input type="password" name="password"></p>
<p><input type="submit" value="Login"></p>
</form>
<%
End If
%>
</Body>
</HTML>
Slettet bruger
Ny bruger
Nybegynder
Opret
Preview
