Find antal forekomster af ord

Du kan bruge regular expresstion:


str =  "manden er en stor person"

ord = "er"
Set regEx = New RegExp
regEx.Global = true
regEx.IgnoreCase = true
regEx.Pattern = "(^|[^a-zæøå\d])" & ord & "([^a-zæøå\d]|$)"
antal = 0
Set Matches = regEx.Execute(str)
For Each Match in Matches
  antal = antal + 1
Next
Set regEx = Nothing

Response.Write antal

ok...fedt. Forstår ikke lige:
regEx.Pattern = "(^|[^a-zæøå\d])" & ord & "([^a-zæøå\d]|$)"
Hvad sker der der?

Eller den her:

<%

  strng="Der er for langt mellem mælk og og, og og og smør"

  Dim regEx, Match, Matches  ' Create variable.
  Set regEx = New RegExp  ' Create a regular expression.
  regEx.Pattern = "[\wæøåÆØÅ]+"    ' Set pattern.
  regEx.IgnoreCase = True  ' Set case insensitivity.
  regEx.Global = True  ' Set global applicability.
  Set Matches = regEx.Execute(strng)  ' Execute search.
  Set dict = Server.CreateObject("Scripting.Dictionary")
  For Each Match in Matches  ' Iterate Matches collection.
    m = "" & Match
    dict(m) = dict(m)+1
    response.write Match & " "
  Next
  response.write "<br>"
  response.write "Og forekommer " & dict("og") & " gange<br>"
  response.write "langt forekommer " & dict("langt") & " gange<br>"   

  for each word in dict
    response.write word & " occurs " & dict(word) & " times<br>"
  next
%>

Det er et pattern den søger efter hele ord:

"(^|[^a-zæøå\d])" & ord & "([^a-zæøå\d]|$)"

^  betyder når den står ført start p åstrengen så den an finde ordet hvis det står først i en streng.

|  betyder eller

^a-zæøå\d  betyder Ikke match bogstavder og tal lige før søge ordet og lige efter søge ordet så den ikke finder er i person.

$  betyder slut på strengen.


du kan se meget mere omkring det her:
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/script56/html/vspropattern.asp