Import af data fra Excel til Access online

Mangler lige en lille detalje ... det er ikke 100% nødvendigt at det skal være en Excel fil, kunne også være en ganske almindelig kommaseperaret tekstfil

Nu kender jeg ikke hvordan en Excel fil er bygget op, men du kan godt gøre det med en kommaseperaret tekstfil :-)

.. du bruger bare nogle funktioner til manipulation af strenge:
http://www.w3schools.com/vbscript/vbscript_ref_functions.asp#string

Og lidt ASP+Access kode:
Lektionerne 17-22 på http://html.dk/tutorials/asp/

du kan arbejde med excel på næsten samme måde som med access på nettet, men jeg har aldrig selv prøvet det

Hvis det er en kommasepareret txt-fil kan du let gøre det vha FSO (FileScriptingObject)

FSO eksempel: http://www.w3schools.com/asp/showasp.asp?filename=demo_readlines

hvis du bruger en kommaseperaret fil er det jo ingen sag at skulle importere filen, og bygge din SQL op efter den,...

montego >> 10/04-2004 18:33:23?

og: 10/04-2004 18:25:02 + 10/04-2004 18:29:13 :-)

Og det ville være en god ide, at bruger arrays: http://html.dk/tutorials/asp/lektion8.asp

nok måske lige en idé at undlade arrays og alt muligt andet før filen (excel eller txt) i det hele taget er læst ind :)

og feedback ville måske være at foretrække som det aller aller første ;)

"at undlade arrays og alt..." - synes du? ;-)
Det ville jo være meget nemt med array.. så behøver man ikke en masse Left, Mid, Right, InStr funktioner..

Men man skal muligvis bruge dem alligevel..

jeg er helt enig med dig i at der skal arbejdes med arrays såfremt det er en komma (eller noget andet) sepereret fil... men så længe vi ikke ved det er det svært (=umuligt) at rådgive om hvordan der skal arbejdes med dataene.

keysersoze> Fuldstændigt korrekt :-)

Spørgeren har dog skrevet:
"Mangler lige en lille detalje ... det er ikke 100% nødvendigt at det skal være en Excel fil, kunne også være en ganske almindelig kommaseperaret tekstfil"

Excel kan eksportere ti CSV-filer.. så er det optimalt at gøre det, hvis han kan nøjes med arrays :-)

Han nævner også "foruddefineret regler"..

Men som du skrev.. noget feedback ville være nice.. :-)
..han får et chok, når han ser 13 mails i sin mailbox.. ;-)

Chokket har lagt sig ... og har selv gået og tænkt lidt over det, det bliver en kommaseperaret fil. Grunden til jeg skrev Excel er fordi jeg er erhvervsskadet. Mit daglige arbejde består af at lave rapporter og statistikker i Excel :)

Jeg skal ærligt indrømme at jeg ikke er så stærk i asp programmering mere som jeg har været da mit job og familie har taget det meste af min tid de sidste mange måneder (par år).

Så lidt kildekode ville være en sindsyg stor hjælp, har aldrig arbejdet med Array, men det jeg kender til det så ville det helt klart være en fordel det kan jeg godt se

Du burde kunne lave scriptet, ud fra de links jeg har skrevet.
Men hvis du smider et eksempel, på din CSV (Comma Separeted Values / kommaseparerede værider) fil, kan vi nemmere lave koden til dig..

Jeg vil dog prøve at lave et eksempel, i løbet af dagen.

Eksemplet består af:
* tilfoj.asp - scriptet der læser værdierne fra filen "test.csv", og tilføjer dem til databasen ("db1.mdb")
* se.asp - scriptet henter alle værdierne fra databasen, og udskriver dem til skærmen
* test.csv - filen med værdierne.. struktur: "navn","hjemmeside","email adresse"
* db1.mdb - selve databasen


***** databasen:

* filnavn: "db1.mdb"
* placering: i samme mappe som asp filerne
* tabel - navn: "tblInfo"
* felt - navn: "navn", type: "tekst"
* felt - navn: "hjemmeside", type: "tekst"
* felt - navn: "email", type: "tekst"



***** tilfoj.asp:

<%
option explicit ' man undgår stavefejl, da *alle* variabler skal defines, med: dim variabelnavn

''' definer variablerne:
dim fs, f
dim tmp, arr, i
dim strNavn, strHjemmeside, strEmail
dim Conn, DSN, strSQL

' Her oprettet FSO objektet:
Set fs=Server.CreateObject("Scripting.FileSystemObject")

' Her åbnes vores CSV fil:
Set f=fs.OpenTextFile(Server.MapPath("test.csv"), 1)

tmp = ""
do while f.AtEndOfStream = false ' så længe at vi ikke er nået slutningen filen, udføres:
tmp = tmp & f.ReadLine & ";" ' tilføj linie fra filen, til variablen "tmp", og tilføj ";"
loop ' loop, dvs gentag

f.Close ' luk filen igen

' frigør objekterne (spar på ressourcerne)
Set f=Nothing
Set fs=Nothing


''''' Databasen

' Opret forbindelsen til database:
Set Conn = Server.CreateObject("ADODB.Connection")

' Vælg database-driveren:
DSN = "DRIVER={Microsoft Access Driver (*.mdb)}; "

' Vælg database-fil:
DSN = DSN & "DBQ=" & Server.MapPath("db1.mdb")

' Åben forbindelsen med vores data:
Conn.Open DSN

arr = split(tmp, ";") ' Vi bruger "Split" til at splitte "tmp" op, ved ";" tegnet:
for i = lbound(arr) to ubound(arr) - 1 ' denne loop starter ved arrays første værdi (LBound) og slutter ved sidste værdie (UBound), minus 1 (da den starter ved 0, og ikke 1)

    tmp = arr(i) ' smid værdien "Hans Hansen,http://www.hansen.dk,hans@hansen.dk" (osv..) over i tmp

    strNavn = left(tmp, InStr(tmp, ",") - 1) ' indholdet af strNavn: fra venstre og til positionen af ",", minus 1 tegn
    tmp = mid(tmp, len(strNavn)+2) ' indholdet af tmp: fra længden af indholdet af strNavn, plus 2 tegn, og resten af linien

    strHjemmeside = left(tmp, InStr(tmp, ",") - 1) ' indholdet af strHjemmeside: fra venstre og til positionen af ",", minus 1 tegn
    tmp = mid(tmp, len(strHjemmeside) + 2)' indholdet af tmp: fra længden af indholdet af strHjemmeside, plus 2 tegn, og resten af linien

    strEmail = tmp ' den sidste værdi er bare resten af linien

    ' Vi tester værdier.. hvis du ikke har databasen endnu:
    response.write "Navn: " & strNavn & "<br>Hjemmeside: " & strHjemmeside & "<br>Email: " & strEmail & "<br><br>"

    ' Gem i databasen (vores "indsættelelses"-kommando):
    strSQL = "Insert into tblInfo ("

    strSQL = strSQL & "navn, "
    strSQL = strSQL & "hjemmeside, "
    strSQL = strSQL & "email) "

    strSQL = strSQL & "values( "

    strSQL = strSQL & "'" & strNavn & "', "
    strSQL = strSQL & "'" & strHjemmeside & "', "
    strSQL = strSQL & "'" & strEmail & "')"
   
    Conn.Execute(strSQL) ' udfør vores "indsættelses"-kommando
next

' Luk forbindelsen til database, og frigør:
Conn.Close
Set Conn = Nothing

response.write "<br><br><br>Alle værdierne er tilføjet"
end if
%>



***** se.asp:

<%
option explicit

dim Conn, DSN, rs, strSQL

' Opret forbindelsen til database:
Set Conn = Server.CreateObject("ADODB.Connection")

' Vælg database-driveren:
DSN = "DRIVER={Microsoft Access Driver (*.mdb)}; "

' Vælg database-fil:
DSN = DSN & "DBQ=" & Server.MapPath("db1.mdb")

' Åben forbindelsen med vores data:
Conn.Open DSN

strSQL = "Select * from tblInfo order by navn"

' Smid database poasterne over i "rs":
Set rs = Conn.Execute(strSQL)

if not(rs.bof or rs.eof) then ' hvis vi hverken er ved start eller ved slutningen, er der mindst 1 post -> udfør:

' Gennemløb Recordset (rs) med en løkke
Do while not rs.eof

  ' Udskriv værdien af kolonnen Fornavn og fødselsdato
  response.write "Navn: " & rs("navn") & "<br>Hjemmeside: " & rs("hjemmeside") & "<br>Email: " & rs("email") & "<br><br>"

  ' Gå til næste Record i rs
  rs.MoveNext

' Fortsæt indtil rs er gennemløbet (EOF = End Of File)
Loop
end if

' Luk forbindelsen til database, og frigør:
Conn.Close
Set Conn = Nothing

%>



***** test.csv (struktur: "navn","hjemmeside","email adresse"):

Hans Hansen,http://www.hansen.dk,hans@hansen.dk
Jens Jensen,http://www.jensen.dk,jens@jensen.dk

---

Hvis du har spørgsmål, er du meget velkommen til at stille dem.

Jeg kigger på det lige så snart jeg kan få min latterlige computer til at virke med IIS igen

lukker

eh? Hvad sker der?