Jeg vil lære PHP, og her er grunden til det

Hej PHP/eksperter!

Jeg har et ASP script som virker fint på IIS, og bruger FSO (file system object) til at læse filer af typen ".htm" i en bestemt folder, og sorterer og viser links til disse .htm filer via ADODB (connection-less recordsets).

Når jeg uploader dette script til en unix-baseret maskine (som kører Sun ASP) går alle mulige ting galt! For det første, så er FSO understøttelsen fuldstændig udokumenteret, så man skal forsøge sig frem, og for det andet mangler standard kommandoer som .Append i Sun's implementering af ADODB!!

Så jeg har besluttet at lære PHP, men har selvfølgelig brug for inspiration til at komme i gang (og har ikke tænkt mig at tage en måned fri for at læse en tyk bog - det bliver nødt til at vente til sommerferien;-).

Derfor har jeg lagt funktionerne i min asp/vbscript løsning op i sin fulde længde, og håber at en flink person kan vise mig hvilke kommandoer jeg bedst kan anvende for at lave en lignende funktionalitet, blot i PHP (og som en gulerod giver jeg 250 point, selvom det jo nærmest burde være kr,-)

Jeg har tilføjet en del kommentarer (på engelsk!) - forhåbentlig er det tydeligt hvad der foregår. Ellers spørg, så jeg kan forsøge at uddybe nærmere...

Here goes!
---------------------------------------------------
<%
' Return a list of the files in the named directory
' (strFolder) that match the given file extension (strExt)
'
Function getDirContents(strFolder,strExt)

    Dim fso,oRs,file,outputStr,folderObject,filesObject,tmpPgTitle,tmpModif

    Set fso = CreateObject("Scripting.FileSystemObject")
    Set folderObject = fso.GetFolder(Server.MapPath(strFolder))
    Set filesObject = folderObject.Files

    'Use the recordset object to emulate a table.
    Set oRs = CreateObject("ADODB.Recordset")
        oRs.Fields.Append "ID", 3
        oRs.Fields.Append "Name", 200, 100
        oRs.Fields.Append "LastModified", 133
        oRs.Open

    ' Create the entries in the recordset
    For Each file In filesObject

        ' Only add files with an allowed extension
        If fso.GetExtensionName(Server.Mappath(file.Name)) = strExt Then

            ' Prepare for new item
            oRs.AddNew
           
            ' Fill in each field
            oRs.Fields("Name").Value = file.Name
            oRs.Fields("LastModified").Value = file.DateLastModified
           
            ' Add the item to the recordset
            oRs.Update
        End If
    Next

    ' Now we can release the file system object from memory
    Set filesObject = Nothing
    Set folderObject = Nothing
    Set fso = Nothing

    ' Use the ADODB to sort the recordset
    oRs.Sort = "LastModified DESC"

    ' Set cursor to the beginning of our recordset
    If Not oRs.BOF Then
        oRs.MoveFirst
    End If

    ' Loop through the recordset
    While not oRS.EOF


        ' Display just the date, not date+time format. Achived by
        ' including just the first 10 characters of "LastModified"
        tmpModif = Left(oRs.Fields("LastModified").Value,10)

        ' Get the <title> attribute if present. Otherwise, use the filename
        tmpPgTitle = extractTitleAttr(getFileContents(strFolder & oRs.Fields("Name").Value)) & ""
        If tmpPgTitle = "" Then
            tmpPgTitle = oRs.Fields("Name").Value
        End If

        ' HTML to output
        outputStr = outputStr + "<a href=""default.asp?url=" & strFolder & oRs.Fields("Name").Value & """><span class=""smaller"">" & tmpModif & "</span><br>" & tmpPgTitle & "</a><hr>"
        oRs.MoveNext

    Wend

    getDirContents = outputStr

    Set oRs = Nothing

End Function


' Extract the <title> attribute of a string
' using regular expressions
Function extractTitleAttr(strng)

    Dim regEx, Match, Matches, outputStr

    Set regEx = New RegExp 
    regEx.Pattern = "(\<TITLE\>)(\s*)(.+)(\s*)(\<\/TITLE\>)"
    regEx.IgnoreCase = True 
    Set Matches = regEx.Execute(strng)

    ' Iterate Matches collection
    For Each Match in Matches 
        ' Extract the 3rd submatch (the title)
        Set Match = Matches(0)
        extractTitleAttr = Match.SubMatches(2)
    Next

    Set regEx = Nothing
    Set Match = Nothing
    Set Matches = Nothing
    Set outputStr = Nothing

End Function


' Return the contents of a file as a string
'
Function getFileContents(strHTMLFile)

    Dim fso,objText
   
    ' Establish a connection to the FSO (FileSystemObject)
    Set fso = Server.CreateObject("Scripting.FileSystemObject")
   
    ' If the file passed as argument exist
    If fso.FileExists(Server.MapPath(strHTMLFile)) Then
        ' Read the contents of the file
        Set objText = fso.OpenTextFile(Server.MapPath(strHTMLFile))
        getFileContents = objText.ReadAll
        objText.Close
        Set objText = Nothing
    Else
        ' File does not exist - output message
        getFileContents = "Der opstod en fejl - prøv evt. et andet link"
    End If
    Set fso = Nothing
End Function

%>