Problemer med nedlukning efter instalation af Exchange 2003

Hej bug30
Måske dette link kan hjælpe dig:
http://www.petri.co.il/slow_shutdown_of_exchange_2003_server_installed_on_dc.htm

Det er et kent problem at det kan tage enddog meget lang tid at lukke en server med Exchange 2003 ned som er installeret på en DC idet at Active Directory lukker ned inden Exchange serveren. Jeg bruger selv bat filen du kan se hvis du følger linket. Håber det kan hjælpe dig.

mvh

Mik

det virker kun hvis jeg selv går ind og lukker de sservices, inden jeg lukker,,, så tak for svaret,,,

kan du ikke ligge et svar, til point

Jeg vil gerne give dig et svar, men jeg er ikke helt med. Har du lavet en batfil som beskrevet og forsøgt at eksekverer den. Du skal kun køre den. Hvis du f.eks vil genstarte den skal du køre filen og trykke 2, og ikke gøre mere så skulle den gerne genstarte automatisk.

Mvh

Mik

kunne du ikke ligge den bat fil ud så jeg kan downloade den,

Her er batfilen. Kopier nedenstående til Notepad og gem det ex. i roden på c-drevet på exchangeserveren som ex. shutdown.bat. Jeg har ikke lige et sted jeg kan lægge den op på nettet.

@ECHO OFF
REM This is a batch file to shutdown an Exchange 2003 server on Windows 2003
REM The idea is to control the order of the shutdown process.
REM The main issue is to stop Exchange before Active Directory is stopping.

ECHO Stopper ver 1.00 by Yizhar Hurwitz
ECHO.
ECHO 1. Shut Down the server (shutdown /s).
ECHO 2. Reboot the server (shutdown /r).
ECHO 3. Abort shutdown (shutdown /a).
ECHO 0. Do nothing.
ECHO.
CHOICE /C 1230

IF ERRORLEVEL 4 GOTO END
IF ERRORLEVEL 3 GOTO ABORT
IF ERRORLEVEL 2 GOTO REBOOT
IF ERRORLEVEL 1 GOTO SHUTDOWN
IF ERRORLEVEL 0 GOTO END
GOTO END

:ABORT
shutdown /a
GOTO END

:REBOOT
SET PARAMETERS=/r /c "Stopper - Rebooting server"
GOTO STOPSERVICES

:SHUTDOWN
SET PARAMETERS=/s /c "Stopper - Shutting down the server"
GOTO STOPSERVICES


:STOPSERVICES
ECHO ON
REM - While we are waiting for the main Exchange services to stop,
REM - Some peripheral services will be closed in the background.
start /min net stop MSExchangeMGMT /yes
start /min net stop RESvc /yes
start /min net stop POP3Svc /yes
start /min net stop IMAP4Svc /yes
start /min net stop NntpSvc /yes
start /min net stop SMTPSVC /yes

REM - Stop Exchange main services before shutdown to avoid timing conflicts.

net stop MSExchangeES /yes
net stop MSExchangeIS /yes
net stop MSExchangeMTA /yes
net stop MSExchangeSA /yes

REM - Well, why not stop other services in the background just for fun?
REM - Stopping IISADMIN will stop other dependant services like W3SVC, and HTTPFilter (SSL).
start /min net stop IISADMIN /yes
start /min net stop MSSEARCH /yes
start /min net stop Spooler /yes

REM - Now it's time to reboot or shutdown the server.
shutdown %PARAMETERS% /t 10

REM To abort, type:
REM shutdown /a
:END

jeg takker, smid et svar,

Glad for at høre....