Hvordan oprettes link mellem Excel og Outlook ?

Har ikke meget forstand på det, men prøv at se på dette link:

http://support.microsoft.com/default.aspx?scid=kb;EN-US;220595

Dvs. du har f.eks:

Subject i kolonne A
StartDate i kolonne B
DueDate i kolonne C  ?

Efter lange overvejelser, er grundlaget for sprøgsmålet blevet ændret, en link mellem Access og Outlook er ønsket i stedet for... sprøgsmålet flyttes hermed til Access.

Jeg smider den op alligevel, det kan være der er nogen andre der kan få glæde af den. :-)

Løsningen forudsætter:
1. Outlook er startet.
2. Der er en liste af opgaver i det aktive Excelark, sat op som
skrevet ovenfor.

Bemærk:
- Kolonne D bruges til at indeholde et unikt "EntryID" for den enkelte task, så man undgår at oprette den samme opgave flere gange. Skjul Kolonne D hvis du ikke gider se på den.

Følgende kode copy/pastes ind i et Excel kodemodul:
--------------------------

Public Sub GetOutlookTasks()

Dim OlApp As Outlook.Application
Set OlApp = GetObject(, "Outlook.Application")

Dim OlNS As Outlook.NameSpace
Set OlNS = OlApp.GetNamespace("MAPI")

Dim OlTasks As Outlook.MAPIFolder
Set OlTasks = OlNS.GetDefaultFolder(olFolderTasks)

Dim i As Integer

For i = 1 To OlTasks.Items.Count
    ThisWorkbook.ActiveSheet.Cells(i, 1) = OlTasks.Items(i).Subject
    ThisWorkbook.ActiveSheet.Cells(i, 2) = OlTasks.Items(i).StartDate
    ThisWorkbook.ActiveSheet.Cells(i, 3) = OlTasks.Items(i).DueDate
    ThisWorkbook.ActiveSheet.Cells(i, 4) = OlTasks.Items(i).EntryID
Next i


' Luk og sluk
Set OlApp = Nothing
Set OlTasks = Nothing

End Sub

Public Sub CreateOutlookTasks()

On Error GoTo Fejl

Dim OlApp As Outlook.Application
Set OlApp = GetObject(, "Outlook.Application")

Dim OlNS As Outlook.NameSpace
Set OlNS = OlApp.GetNamespace("MAPI")

Dim OlTasks As Outlook.MAPIFolder
Set OlTasks = OlNS.GetDefaultFolder(olFolderTasks)

Dim myOlTask As Outlook.TaskItem

Dim rowCount As Integer
Dim colCount As Integer
Dim maxRows As Integer
Dim i As Integer
Dim j As Integer

maxRows = ActiveSheet.[A1].CurrentRegion.Rows.Count

For i = 1 To maxRows
    If Cells(i, 4) = "" Then  'Task does not exist
        Set myOlTask = OlTasks.Items.Add(olTaskItem)
        With myOlTask
            .Subject = Cells(i, 1)
            .StartDate = Cells(i, 2)
            .DueDate = Cells(i, 3)
            .Save
        End With
    Else ' Task exists already
        ' Find task in Outlook tasklist
        For j = 1 To OlTasks.Items.Count
            If OlTasks.Items(j).EntryID = Cells(i, 4) Then ' Task Found
                With OlTasks.Items(j) 'Update task
                    .Subject = Cells(i, 1)
                    .StartDate = Cells(i, 2)
                    .DueDate = Cells(i, 3)
                    .Save
                End With
            End If
        Next j
    End If
   
Next i

'MsgBox i - 1 & " tasks oprettet i Outlook"

' Luk og sluk
Set OlApp = Nothing
Set OlTasks = Nothing
Set OlNS = Nothing
Set myOlTask = Nothing

'Refresh
GetOutlookTasks

Exit Sub

Fejl:
MsgBox "Der opstod en fejl. Noter fejlen og spørg en eller anden på www.eksperten.dk :-) "


End Sub
--------------------------

For at lukke spørgsmålet skal du selv oprette et svar og acceptere dit eget svar.

Flot svar, Blackadder. Den napper jeg lige :-)

ps. hvis du lige laver det nummer her i begge subs og sætter reference til outlook behøver outlook ikke være åben.

Dim OlApp As New Outlook.Application
''Set OlApp = GetObject(, "Outlook.Application")

Ok, den kendte jeg ikke, tak for det :-)
Ellers kan man vel bruge CreateObject metoden ?

yeps, en anelse langsommere, men til gengæld får ikke problemer med "missing references" når man kører koden på en maskine der har en andet ofice version.
Faktisk er det nok det smarteste at gøre ved outlook, da den er beregnet til at køre multisessioner...men fordelen ved New-metoden er mens du skriver koden har du alle metoder og properties tilrådighed

Lukkes...

blackadder> din metode checker kun om en aftale oprettet fra Excel arket er oprettet i Outlook - hvad nu hvis der ligger en anden aftale oprettet på anden vis?
cwc> prøv at tage et kig på http://www.eksperten.dk/spm/522837 der ligger funktionerne til det. Jeg vil tro at de kan flyttes til Access sådan bare lige med et par små ændringer.

GetOutlookTasks() henter de tasks der er oprettet i Outlook på det øjeblik du kører den, uanset hvordan de tasks er oprettet. Du kan herefter tilføje tasks ved at skrive i kolonnerne under de allerede oprettet tasks og så køre CreateOutlookTasks()
.

Hvordan man gører det fra Access, ved jeg ikke.

Hvad gør jeg forkert... Kode er copieret ind i et Excel kodemodul, men i linien :
OlApp As Outlook.Application
kommer der en fejl : Can't find project or library.