DOS/Batch udtræk af sidste linie i fil

Jeg skulle mene det lille program "Tail" kan gøre det. Det virker på den måde, at du kan få det til at vise de sidste x-antal linier fra en fil. Syntaksen er således:

tail -0 filnavn.txt

hvis du vil dumpe outputtet til en text-fil, så gør sådan her:

tail -0 filnavn.txt > dump.txt

Tail.exe er en del af en bunke Microsoft server tools, du gratis kan hente her:
http://www.microsoft.com/downloads/details.aspx?FamilyID=9d467a69-57ff-4ae7-96ee-b18c4790cffd&DisplayLang=en

Og hvis du skal sende mails fra en dos-prompt, så vil jeg anbefale Blat.
Det kan du hente her: http://www.blat.net/194/

Kan man også putte outputtet fra tail ind i en variabel?

Jeg har et mailprogram der hedder wMailTo. Syntaxen er
wMailTo -s"Output fra fil %o" etellerandet@noget.bø

Så nu mangler jeg bare at få output fra tail over i %o.

VH Jacob

Godt spørgsmål, der må jeg sgu melde pas :/

Måske noget i stil med:

@echo off
setlocal
for /F "tokens=*" %%I in (sim.log) do @set YYY="%%I"

wMailTo -s%YYY% etellerandet@noget.bø

%YYY% bliver sat til at være sidste linie i filen + ""

bertelbrander -> Tak for hjælpen, det virker jo lige som det skal (vil du have point, må du lige lave et svar)!

spotgun -> Tak for forsøget!

To små tillægsspørgsmål:

1: Hvorfor virker følgende ikke, og hvordan kan jeg få det til at virke?
  @set YYY = tail -1 sim.log
(hvis jeg skriver "echo tail -1 sim.log" skriver den fint den streng, den skal)

2: Nu kunne jeg godt tænke mig at få flere linier med i selve mailen. Jeg tror det kan løses, hvis ovenstående løses. Så kunne jeg jo blot skrive tail -10 sim.log eller whatever. Men er der en bedre måde?

1: Hvis det er i en bat fil, ellers skal der bruges %I isf %%I
for /F "tokens=*" %%I in ('tail -1 sim.log') do set YYY=%%I

2: Man kan ikke lave en variabel der indeholder flere linier, men man kan sætte linierne sammen til en linie, f.ex adskilt af en ;

@echo off
setlocal
set YYY=
for /F "delims=" %%I in ('tail -6 whatever.txt') do call :ConCat "%%I"
echo %YYY%
goto :eof

:ConCat
Set YYY=%YYY%%~1;

Jeg lavede følgende script:

@echo off
setlocal
@set /a B=0

rem Find the last line for the subject of the mail
for /F "tokens=*" %%I in (%2) do (
  @set A=%%I
  set /a B+=1
)

set /a B-=80
if %B% LSS 1 set /a B=1

echo Log file: > tmp.log
for /F "delims=$ skip=%B%" %%I in (%2) do echo %%I>>tmp.log

wMailTo -s"%1 %A%" -ttmp.log  EMAIL@EMAIL.com

del tmp.log


Dvs finde den sidste linie samtidig med at jeg tæller, hvor mange linier der er i filen. Derefter flytte antal af linier - 80 (dvs de sidste 80) over i en temp fil, som jeg så sender til emailen.

Så pointene må jo nok gå til bertelbrander (hvis du lige vil svare).

Jeg vil helst ikke have point.

Så svarer jeg selv