hej
du gør således:
<%
' Selected constants from adovbs.inc
Const adOpenStatic = 3
Const adLockPessimistic = 2
Dim cnnExcel
Dim rstExcel
Dim I
Dim iCols
' This is all standard ADO except for the connection string.
' You can also use a DSN instead, but so it'll run out of the
' box on your machine I'm using the string instead.
Set cnnExcel = Server.CreateObject("ADODB.Connection")
cnnExcel.Open "DBQ=" & Server.MapPath("dealers.xls") & ";" & _
"DRIVER={Microsoft Excel Driver (*.xls)};"
%>
<html>
<head>
<meta http-equiv="content-type" content="text/html;charset=iso-8859-1">
<title></title>
<link href="../external.css" rel="stylesheet" type="text/css" media="all">
</head>
<body>
<form method="post">
<table cellpadding="0" cellspacing="0" border="0">
<tr>
<td><h5>From Zip:</h5></td>
<td> </td>
<td><h5>To Zip:</h5></td>
</tr>
<tr>
<td><input type="text" name="zipstart" style="width:40px;" maxlength="4"></td>
<td></td>
<td><input type="text" name="zipend" style="width:40px;" maxlength="4"></td>
</tr>
<tr>
<td colspan="3"> </td>
</tr>
<tr>
<td colspan="3"><input type="submit" value="Search"></td>
</tr>
</table>
</form>
<%
' Same as any other data source.
' FYI: Pulje1 is my named range in the Excel file
Set rstExcel = Server.CreateObject("ADODB.Recordset")
dim zipstart, zipend
zipstart = Cint(Request.Form("zipstart"))
zipend = Cint(Request.Form("zipend"))
if zipstart <> 0 and zipend <> 0 then
rstExcel.Open "SELECT * FROM Dealers Where Zip Between " & zipstart & " AND " & zipend & ";", cnnExcel, _
adOpenStatic, adLockPessimistic
else
rstExcel.Open "SELECT * FROM Dealers;", cnnExcel, _
adOpenStatic, adLockPessimistic
end if
' Get a count of the fields and subtract one since we start
' counting from 0.
iCols = rstExcel.Fields.Count
%>
<table width="100%" border="0" cellspacing="0" cellpadding="2">
<tr>
<%
' Show the names that are contained in the first row
' of the named range. Make sure you include them in
' your range when you create it.
For I = 0 To iCols - 1
Response.Write "<td bgcolor=""#555555"" width=""40""><h4><b><font color=""white"">"
Response.Write rstExcel.Fields.Item(I).Name
Response.Write "</font></b></h4></td>" & vbCrLf
Next 'I
%>
</tr>
<%
rstExcel.MoveFirst
' Loop through the data rows showing data in an HTML table.
bgcolor = "#FFFFFF"
Do While Not rstExcel.EOF
Response.Write "<tr bgcolor=" & bgcolor & ">" & vbCrLf
For I = 0 To iCols - 1
Response.Write "<td><h5>"
Response.Write rstExcel.Fields.Item(I).Value
Response.Write "</h5></td>" & vbCrLf
Next 'I
Response.Write "</tr>" & vbCrLf
if bgcolor = "#FFFFFF" then
bgcolor = "#DDDDDD"
else
bgcolor = "#FFFFFF"
end if
rstExcel.MoveNext
Loop
%>
</table>
</body>
<%
rstExcel.Close
Set rstExcel = Nothing
cnnExcel.Close
Set cnnExcel = Nothing
%>
Som du kan se har jeg navngivet din zipstart og zipend i formen og tester på om de er forskellige fra 0
/hiks
Ny bruger
Nybegynder
Opret
Preview
