Sum af hver anden

=SUM(HVIS(REST(RÆKKE($A$1:$A$500);2)=0;$A$1:$A$500;0))

Skal læses som tag summen af de celler mellem A1 og A500 (området kan du selv ændre), som opfylder den betingelse at resten af rækkenummeret delt med 2 skal være 0. Denne betingelse opfyldes af alle lige rækkenumre. Altså A2, A4 osv.

Hvis du i stedet skal have de ulige celler, A1, A3 osv, skal du rette =0 ca. midt i formlen til =1.

Det hele skal tastes, og når du er færdig trykker du ikke Enter som sædvanligt, men Ctrl+Shift+enter samtidigt for at oprette en matrix formel. Det er en formel som regner på flere celler samtidigt.

Lad mig oversætte formlen indefra:

RÆKKE($A$1:$A$500)finder rækkenummeret på hver af rækkerne. Det er her matrixformlen kommer ind, da du jo skal regne på mange rækker samtidigt.

REST(RÆKKE($A$1:$A$500);2) dividerer rækkenummeret med 2 og finder resten efter divisionen.

HVIS(REST(RÆKKE($A$1:$A$500);2)=0;$A$1:$A$500;0) undersøger om denen rest er = 0. Hvis den er bruger den de tal, der står i de relevaqnte celler. Hvis resten er forskellig fra 0, bruger den et 0. Omvendt, hvis du sætter =1 i formlen.

=SUM(HVIS(REST(RÆKKE($A$1:$A$500);2)=0;$A$1:$A$500;0))

lægger så alle de tal sammen, som er fundet med HVIS funktionen.

Og husk altså at indtaste som en matrixformel, ellers får du et forkert resultat.

Hvis du i stedet skal tællec hver tredje række, skal du dividere med 3 i stedet for 2, altså:

=SUM(HVIS(REST(RÆKKE($A$1:$A$500);3)=0;$A$1:$A$500;0))

Det giver alle celler, hvor 23 går op i rækkeantallet, fx A3, A6, A9 osv.

=1, giver de næste celler, fx A1, A4, A7, A110

og =2 giver de sidste, fx A2, A5, a8, A11 osv.

Jeg håber at du forstår systemet, ellers må du spørge igen.

Hej og mange tak for hurtig svar.

det hjælper lidt på forståelsen, specielt efter dit andet indlæg. Men noget fungere ikke....

Jeg har nu følgende formel:
=SUM(IF(MOD(ROW($B$6:$Y$6);2)=0;$B$6:$Y$6;0))
med {} udenfor formelen.

og med den formel ønsker jeg altså, at hver andet tal lægges sammen (b6+d6+e6 osv). Problemet er bare, at det gøre den ikke. Omtalte formel lægger bare hvert eneste tal sammen, for mig virker, som om den gør sum(b6:y6).

Hvad gør jeg forkert?

Det er vigtigt at du ikke taster { og }. Du skal bare taste selve formlen, og så skulle tuborgparentserne gerne komme når dyu trykker Ctrl+Shift+Enter.

Det gør de også, jeg bruger Ctrl+Shift+Enter, som du skrev.
Det skal dog siges, at jeg intet viste om matrixformler, før du nævnte det.

Prøv lige at ændre dine semikolonner til kommaer

=SUM(IF(MOD(ROW($B$6:$Y$6),2)=0,$B$6:$Y$6,0))

Så får jeg fejl fra Excel, som lyder:
"The formula you typed contains an error ...."

Har du mulighed for at sende regnearket til mig?

kronsell @ adslhome.dk

E-mail er på vej :-)

Ah!. Du arbejder i kolonner, ikke i rækker som jeg troede. sådan kan det gå når man ikke kan læse indenad :-)

Ret ROW til COLUMN, så skulle det gerne køre i olie.

Doh! Nu fungere det!
Tænk at der ikke skal mere til.... og jeg som startede for snart 2 timer siden :-/


PS, jeg har lige øget pointene til 100, for super hjælp og gode forklaringer.

Jeg takker mange gange. Glad for at kunen hjælpe.