Søg
Avatar billede Slettet bruger
05. april 2005 - 17:03 Der er 42 kommentarer og
2 løsninger

Oprettelse af database felter

Jeg har følgende kode som jeg har fundet på nettet og virker
fint, nu er jeg bare kommet til at slette databasen og skal have oprettet en ny. Jeg er ikke vild stor ASP haj så jeg har lidt problemer med at finde ud af hvilke felter osv. der skal være i databasen så den virker til ASP filen.
Nogle der kan tyde det og hjælpe?
Mvh.
Henrik

<%@LANGUAGE="VBSCRIPT"%>
<!--#include file="../fotoDatabase.asp" -->

<%
set rsFiles = Server.CreateObject("ADODB.Recordset")
rsFiles.ActiveConnection = MM_ImgDatabase_STRING
rsFiles.Source = "SELECT *  FROM Files  WHERE FileID > 0  ORDER BY FileID DESC"
rsFiles.CursorType = 0
rsFiles.CursorLocation = 2
rsFiles.LockType = 3
rsFiles.Open()
rsFiles_numRows = 0
%>

<% ' Insert.asp %>
<!--#include file="Loader.asp"-->
<%
  Response.Buffer = True

  ' load object
  Dim load
      Set load = new Loader

      ' calling initialize method
      load.initialize

  ' File binary data
  Dim fileData
      fileData = load.getFileData("file")
  ' File name
  ' The filename will be changed, the new name will be the highest FileID number + 1 + the filename
  ' ex.: 123_filename.jpg
  Dim fileName
      fileName = LCase(load.getFileName("file"))
      fileName = (rsFiles("FileID")--1) &  "_" & fileName
  ' File path
  Dim filePath
      filePath = load.getFilePath("file")
  ' File path complete
  Dim filePathComplete
      filePathComplete = load.getFilePathComplete("file")
  ' File size
  Dim fileSize
      fileSize = load.getFileSize("file")
  ' File size translated
  Dim fileSizeTranslated
      fileSizeTranslated = load.getFileSizeTranslated("file")
  ' Content Type
  Dim contentType
      contentType = load.getContentType("file")
  ' No. of Form elements
  Dim countElements
      countElements = load.Count
  ' Value of text input field "Title"
  Dim nameInput
      nameInput = load.getValue("Title")
    ' Value of text input field "Description" 
    Dim FileText
    FileText = load.getValue("Description") 
    ' Value of text input field "Keywords"
    Dim KeyWord
    KeyWord = load.getValue("Keywords") 

    ' Date when file was uploaded
    Dim FileDate
    FileDate = load.getValue("FileDate")
  ' Path where file will be uploaded
  ' Change this value if you wan't to upload files to different folders
  ' Also notice that Flash-files will be uploaded/defined as images. Change this if you have a Flash Add-On
If Left(LCase(contentType), 5)="image" OR LCase(contentType)="application/x-shockwave-flash" Then

    FileType = ("images")
    FF = 1

Else
    FileType = ("documents")
    FF = 2               

End if

  Dim pathToFile
      pathToFile = Server.mapPath("/files/" & FileType) & "/" & fileName
           
  ' Uploading file data
  Dim fileUploaded
      fileUploaded = load.saveToFile ("file", pathToFile)

  ' destroying load object
  Set load = Nothing
%>

<html>
<head>
<title>Insæt fil</title>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<meta name="author" content="Eivind Savio">

</head>
<body>
<table width="100%" border="0" cellspacing="0" cellpadding="0" align="center">
  <tr>
    <td width="468" valign="top" align="left">
      <table width="100%" border="0" cellspacing="0" cellpadding="0">
        <tr>
          <td><strong><font size="3" face="Arial, Helvetica, sans-serif">Svar på upload af
            <%
            if FF = "1" then
            Response.Write "image"
            elseif FF = "2" then
            Response.Write "document"
            end if
            %>
          </font></strong></td>
        </tr>
        <tr>
          <td valign="top" align="left"> </td>
        </tr>
      </table>
    </td>
  </tr>
  <tr>
    <td width="468" align="left" valign="top">
      <table width="100%" border="0" align="center" cellpadding="0" cellspacing="0">
        <tr>
          <td>&nbsp;</td>
          <td>&nbsp;</td>
        </tr>
        <tr>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><strong>Filnavn</strong></font></td>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><%= fileName %></font></td>
        </tr>
        <tr>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><strong>Filsti</strong></font></td>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><%= filePath %></font></td>
        </tr>
        <tr>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><strong>Fuldstændig filsti</strong></font></td>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><%= filePathComplete %></font></td>
        </tr>
        <tr>
          <td valign="top""><font size="2" face="Arial, Helvetica, sans-serif"><strong>Filstørrelse</strong></font></td>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><%= fileSize %></font></td>
        </tr>
        <tr>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><strong>Ny filstørrelse</strong></font></td>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><%= fileSizeTranslated %></font></td>
        </tr>
        <tr>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><strong>Fil-type</strong></font></td>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><%= contentType %></font></td>
        </tr>
        <tr>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><strong>Titel</strong></font></td>
          <td valign="top"><font size="2" face="Arial, Helvetica, sans-serif"><%= nameInput %></font></td>
        </tr>
      </table>
      <font size="2" face="Arial, Helvetica, sans-serif"><br>
      <%
      If fileUploaded = True Then
        Response.Write fileName & " er uploaded..."
      Else
        Response.Write "<font color=""red"">Filen blev ikke uploaded..."
        Response.Write "</font>"
        Response.Write "<br>Vælg venligst en fil inden du trykker på 'Upload'"
        Response.Write " knappen."
      End If
  %>
    </font></td>
  </tr>
  <tr>
    <td width="468" align="left" valign="top"><font size="2" face="Arial, Helvetica, sans-serif">
   
      <%
' This code inserts the values into the database
rsFiles.AddNew
   
rsFiles("FileHeading") = nameInput
rsFiles("FileText") = FileText
rsFiles("FileURL") = ("files/" & FileType & "/") & fileName
rsFiles("FileKeyWords") = KeyWord
rsFiles("FileType") = FF
rsFiles("FileDate") = FileDate
rsFiles.Update
%>
    </font></td>
  </tr>
  <tr>
    <td class="ingresslarge"><font size="2" face="Arial, Helvetica, sans-serif"><a href="upload_include.asp">Upload flere billeder/dokumenter</a></font></td>
  </tr>
  <tr>
    <td><font size="2" face="Arial, Helvetica, sans-serif">&nbsp;</font></td>
  </tr>
</table>
</body>
</html>
<%
rsFiles.Close()
%>
Avatar billede busschou Praktikant
05. april 2005 - 17:08 #1
rsFiles.Source = "SELECT *  FROM Files  WHERE FileID > 0  ORDER BY FileID DESC"
Fortæller at tabellen hedder Files og har et felt FileID
FileID er sikkert primær nøgle og unik og oprettes automatisk ved nye indsættelser
Avatar billede busschou Praktikant
05. april 2005 - 17:10 #2
rsFiles("FileHeading") = nameInput
rsFiles("FileText") = FileText
rsFiles("FileURL") = ("files/" & FileType & "/") & fileName
rsFiles("FileKeyWords") = KeyWord
rsFiles("FileType") = FF
rsFiles("FileDate") = FileDate
----------------
Fortæller at der er felterne
FileHeading - streng
FileText - streng
FileUrl - streng
FileKeyWords - streng
FileType - streng
FileDate - Dato format
Avatar billede busschou Praktikant
05. april 2005 - 17:12 #3
selve database navnet må findes i en af de includede filer
Avatar billede Slettet bruger
06. april 2005 - 09:08 #4
Super, tak for det!
Så langt så godt! :-)
Så er jeg kommet en del længere, nu kommer den dog med en fejl i følgende kode:

Public Function saveToFile(name, path)

Den skriver "Path not found".
Du kan se koden herunder.
Er det selve "path" eller er det "path = sti på serveren" den mener
den ikke kan finde? Synes heller ikke stien på serveren er difineret
nogle steder? Noget du evt. kan se ?

<%
  ' -- Loader.asp --
  ' -- version 1.5
  ' -- last updated 6/13/2002

  ' Faisal Khan
  ' faisal@stardeveloper.com
  ' www.stardeveloper.com
  ' Class for handling binary uploads

  Class Loader
    Private dict

    Private Sub Class_Initialize
      Set dict = Server.CreateObject("Scripting.Dictionary")
    End Sub

    Private Sub Class_Terminate
      If IsObject(intDict) Then
        intDict.RemoveAll
        Set intDict = Nothing
      End If
      If IsObject(dict) Then
        dict.RemoveAll
        Set dict = Nothing
      End If
    End Sub

    Public Property Get Count
      Count = dict.Count
    End Property

    Public Sub Initialize
      If Request.TotalBytes > 0 Then
        Dim binData
          binData = Request.BinaryRead(Request.TotalBytes)
          getData binData
      End If
    End Sub
   
    Public Function getFileData(name)
      If dict.Exists(name) Then
        getFileData = dict(name).Item("Value")
        Else
        getFileData = ""
      End If
    End Function

    Public Function getValue(name)
      Dim gv
      If dict.Exists(name) Then
        gv = CStr(dict(name).Item("Value"))
       
        gv = Left(gv,Len(gv)-2)
        getValue = gv
      Else
        getValue = ""
      End If
    End Function
   
    Public Function saveToFile(name, path)
      If dict.Exists(name) Then
        Dim temp
          temp = dict(name).Item("Value")
        Dim fso
          Set fso = Server.CreateObject("Scripting.FileSystemObject")
        Dim file
          Set file = fso.CreateTextFile(path)
            For tPoint = 1 to LenB(temp)
                file.Write Chr(AscB(MidB(temp,tPoint,1)))
            Next
            file.Close
          saveToFile = True
      Else
          saveToFile = False
      End If
    End Function

    Public Function getFileName(name)
      If dict.Exists(name) Then
        Dim temp, tempPos
          temp = dict(name).Item("FileName")
          tempPos = 1 + InStrRev(temp, "\")
          getFileName = Mid(temp, tempPos)
      Else
        getFileName = ""
      End If
    End Function

    Public Function getFilePath(name)
      If dict.Exists(name) Then
        Dim temp, tempPos
          temp = dict(name).Item("FileName")
          tempPos = InStrRev(temp, "\")
          getFilePath = Mid(temp, 1, tempPos)
      Else
        getFilePath = ""
      End If
    End Function

    Public Function getFilePathComplete(name)
      If dict.Exists(name) Then
        getFilePathComplete = dict(name).Item("FileName")
      Else
        getFilePathComplete = ""
      End If
    End Function

    Public Function getFileSize(name)
      If dict.Exists(name) Then
        getFileSize = LenB(dict(name).Item("Value"))
      Else
        getFileSize = 0
      End If
    End Function

    Public Function getFileSizeTranslated(name)
      If dict.Exists(name) Then
        temp = 1 + LenB(dict(name).Item("Value"))
          If Len(temp) <= 3 Then
            getFileSizeTranslated = temp & " bytes"
          ElseIf Len(temp) > 6 Then
            temp = FormatNumber(((temp / 1024) / 1024), 2)
            getFileSizeTranslated = temp & " megabytes" 
          Else
            temp = FormatNumber((temp / 1024), 2)
            getFileSizeTranslated = temp & " kilobytes"
          End If
      Else
        getFileSizeTranslated = ""
      End If
    End Function

    Public Function getContentType(name)
      If dict.Exists(name) Then
        getContentType = dict(name).Item("ContentType")
      Else
        getContentType = ""
      End If
    End Function

  Private Sub getData(rawData)
    Dim separator
      separator = MidB(rawData, 1, InstrB(1, rawData, ChrB(13)) - 1)

    Dim lenSeparator
      lenSeparator = LenB(separator)

    Dim currentPos
      currentPos = 1
    Dim inStrByte
      inStrByte = 1
    Dim value, mValue
    Dim tempValue
      tempValue = ""

    While inStrByte > 0
      inStrByte = InStrB(currentPos, rawData, separator)
      mValue = inStrByte - currentPos

      If mValue > 1 Then
        value = MidB(rawData, currentPos, mValue)

        Dim begPos, endPos, midValue, nValue
        Dim intDict
          Set intDict = Server.CreateObject("Scripting.Dictionary")
   
          begPos = 1 + InStrB(1, value, ChrB(34))
          endPos = InStrB(begPos + 1, value, ChrB(34))
          nValue = endPos

        Dim nameN
          nameN = MidB(value, begPos, endPos - begPos)

        Dim nameValue, isValid
          isValid = True
         
          If InStrB(1, value, stringToByte("Content-Type")) > 1 Then

            begPos = 1 + InStrB(endPos + 1, value, ChrB(34))
            endPos = InStrB(begPos + 1, value, ChrB(34))
 
            If endPos = 0 Then
              endPos = begPos + 1
              isValid = False
            End If
           
            midValue = MidB(value, begPos, endPos - begPos)
              intDict.Add "FileName", trim(byteToString(midValue))

        begPos = 14 + InStrB(endPos + 1, value, stringToByte("Content-Type:"))
            endPos = InStrB(begPos, value, ChrB(13))

            midValue = MidB(value, begPos, endPos - begPos)
              intDict.Add "ContentType", trim(byteToString(midValue))

            begPos = endPos + 4
            endPos = LenB(value)

            nameValue = MidB(value, begPos, endPos - begPos)
          Else
            nameValue = trim(byteToString(MidB(value, nValue + 5)))
          End If

          If isValid = true Then
            intDict.Add "Value", nameValue
            intDict.Add "Name", nameN

            dict.Add byteToString(nameN), intDict
          End If
      End If

      currentPos = lenSeparator + inStrByte
    Wend
  End Sub
 
  End Class

  Private Function stringToByte(toConv)
    Dim tempChar
    For i = 1 to Len(toConv)
      tempChar = Mid(toConv, i, 1)
      stringToByte = stringToByte & chrB(AscB(tempChar))
    Next
  End Function

  Private Function byteToString(toConv)
    For i = 1 to LenB(toConv)
      byteToString = byteToString & chr(AscB(MidB(toConv,i,1)))
    Next
  End Function
%>
Avatar billede busschou Praktikant
06. april 2005 - 09:22 #5
Det er jo en funktion.. så det er stien den ikke kan finde
Det må være den funktion som kalder SaveToFile du skal kigge i
Avatar billede Slettet bruger
06. april 2005 - 09:25 #6
Ok. Ja, nu når du siger det kan jeg godt se det er der
det går galt. Tak. Prøver lige at se om jeg kan finde der
hvor funktionen bliver kaldt.
Avatar billede Slettet bruger
06. april 2005 - 10:00 #7
Jo nu går det fremad.
Det eneste den mangler nu er at skrive filmen, men jeg kan dæmle ikke få lavet den rigtige sti på serveren. Den skriver hele tiden Path not found, medmindre jeg laver en ../ som du kan se her:

  pathToFile = Server.mapPath("../" & FileType) & "/" & fileName

Men så skriver den permission denied da der kun er skriverettighed i /upload/
på min server.
Men har prøvet alt som ../../upload/ osv. osv. med flere ../ og mindre så alt er forsøgt.. Hvordan dælen kan det lige lade sig gøre. Og stien eksisterer og det hele... Super belastende..
Avatar billede busschou Praktikant
06. april 2005 - 10:07 #8
hvis du har den absolutte sti..altså fx c:\blabla\blabla\dinfil.type
Så prøv den i stedet
Avatar billede busschou Praktikant
06. april 2005 - 10:08 #9
ahh skriverettighedder :o)
Ja så må du jo enten finde dig i det og benytte det katalog upload
Eller også snakke med din udbyder
Men det er højst sandsynligt af sikkerhesmæssige årsager at der kun er skriverettighedder der
Avatar billede Slettet bruger
06. april 2005 - 10:10 #10
Kan jeg skrive direkte sti ind som det står der?
Den burde jeg godt kunne finde. Så burde det jo virke.

Ja, det er sikkerhedsårsager. Faktisk fordi min hjemmeside blev hacket
så lavede de hele deres system om.. hehe.. ;-)
Avatar billede busschou Praktikant
06. april 2005 - 10:10 #11
prøv evt lave følgende:
response.write(Server.mapPath("../" & FileType) & "/" & fileName)
pathToFile = Server.mapPath("../" & FileType) & "/" & fileName
Så du får skrevet stien ud
Så kan du måske se om det er fordi der er noget galt i variablerne så den laver en forkert sti eller noget
Avatar billede busschou Praktikant
06. april 2005 - 10:10 #12
haha ..så var der jo nok en god grund ;o)
Avatar billede busschou Praktikant
06. april 2005 - 10:11 #13
Ja - server.mappath bruger man for at slippe for at skrive den fulde sti
Det er en fordel når din udbyder engang bygger om ..for så ville du skulle rette alle dine fulde stier
Avatar billede Slettet bruger
06. april 2005 - 10:34 #14
Den kommer med en fejl når jeg bruger fuld sti:

Server.MapPath() error 'ASP 0172 : 80004005'

Invalid Path

/upload_insert.asp, line 82

The Path parameter for the MapPath method must be a virtual path.
A physical path was used.
Avatar billede busschou Praktikant
06. april 2005 - 10:37 #15
Det er fordi du har skrevet
pathToFile = Sever.MapPath(dinfuldesti)
Nøjes med
pathToFile = dinfuldesti
....
Det jeg foreslog 10:10:08 er kun hvis du stadig bruger den relative sti :o) hvis du er med
Avatar billede Slettet bruger
06. april 2005 - 10:39 #16
ahhh, ok - jeg misforstod dig lige. Troede man kunne bruge relativ path
til det hele. Synes heller ikke det lød logisk. ;-)
Jeg prøver lige.
Avatar billede Slettet bruger
06. april 2005 - 10:49 #17
Den skriver stadig path not found og jeg har skrevet den rigtige sti.
Det er MEGET MEGET underligt. Så længe jeg har fået "permission denied" må det
jo virke...
Avatar billede Slettet bruger
06. april 2005 - 10:51 #18
Hvis jeg skriver fuld stinavn på serveren og ingen path efter
så skriver den permission denied, men sætter jeg /upload bagefter eller /upload/
som eksisterer skriver den path not found.. Underligt..
Avatar billede busschou Praktikant
06. april 2005 - 10:52 #19
har du skrevet stien ud med en Response.Write?
Avatar billede Slettet bruger
06. april 2005 - 10:56 #20
ja, det giver den rigtige sti og jeg får jo også permission denied som
vil sige den ikke kan skrive på den sti som jeg har skrevet da det er roden,
men sætter jeg så /upload/ på så går det galt og det giver path not found.
Avatar billede busschou Praktikant
06. april 2005 - 10:58 #21
ok du er nød til at vælge upload hvis det er den som har permission
Men har du så udskrevet stien til upload med en response.write? og dobbeltjekket at den ser sådan ud på serveren?
For så er det wierd
Avatar billede Slettet bruger
06. april 2005 - 11:04 #22
Upps.. sorry, havde ikke lige lavet den rigtige sti til upload, men kun på
roden. Og da det var upload skulle det først være /upload\ (Altså først slash
og derefter backslash)Svært at gætte.. hehe..
Meeeen nu skriver den sgu permission denied og i upload er der altså
skriverettigheder... Det er da lidt underligt. Det er der jeg smider
alle andre uploads og det virker.
Avatar billede busschou Praktikant
06. april 2005 - 11:08 #23
ok der må jeg være dig svar skyldig.
Hvis du 100% har peget på den rigtige sti og den siger "ingen adgang"
Så vil jeg foreslå dig at snakke med din udbyder
Avatar billede Slettet bruger
06. april 2005 - 11:09 #24
2 sec. Har lige lavet en fejl.
Avatar billede Slettet bruger
06. april 2005 - 11:18 #25
hmm.. troede jeg har lavet en fejl.
Det er godt nok underligt. Synes den skifter lidt mellem
path not found og permission denied selvom jeg skriver det samme.
Men jeg må lige bøvle lidt med det.
Men mange mange tak for din hjælp, det har været kanon og har også
lært lidt om det samtidig.. :-)
Avatar billede busschou Praktikant
06. april 2005 - 11:23 #26
Det var så lidt håber du finder ud af resten
Du må evt gerne skrive herinde når du finder løsningen :o)
Avatar billede Slettet bruger
06. april 2005 - 11:31 #27
JEG FANDT SGU LØSNINGEN!!! yahuuuuuuuuuuuuuuuuuuuuuu.... hehe..
Men det var takke tvære dig! :-)
Jeg fjernede de sidste  "/" som den ville have inden filnavnet,
det var det der var forkert. Det kunne jeg se i stien. Dejligt.
Avatar billede busschou Praktikant
06. april 2005 - 11:33 #28
kanon :o) Det er sku rart når det virker :o)
Avatar billede Slettet bruger
06. april 2005 - 11:53 #29
har lige et hurtig spørgsmål mere hvis du har tid. :-)
Avatar billede busschou Praktikant
06. april 2005 - 11:54 #30
spørg bare løs.. svarer så hurtig jeg kan :o)
Avatar billede Slettet bruger
06. april 2005 - 11:55 #31
Nu virker billede upload osv. og beskrivelsen ligger fint i databasen
og billederne ligger i kataloget. Nu skal jeg så bare have udskrevet
dem og den kommer med følgende fejl:

Data type mismatch in criteria expression ... line 47

Det er følgende kode:
<%
Dim rsImages__varImgSearch
rsImages__varImgSearch = "%"
If (Request.QueryString("ImgSearch") <> "") Then
  rsImages__varImgSearch = Request.QueryString("ImgSearch")
End If
%>
<%
set rsImages = Server.CreateObject("ADODB.Recordset")
rsImages.ActiveConnection = MM_ImgDatabase_STRING
rsImages.Source = "SELECT FileHeading, FileText, FileURL, FileID, FileKeyWords, FileDate, FileType  FROM Files  WHERE FileType = 1 AND FileKeyWords LIKE '%" + Replace(rsImages__varImgSearch, "'", "''") + "%' AND FileID > 1  ORDER BY FileHeading"
rsImages.CursorType = 0
rsImages.CursorLocation = 2
rsImages.LockType = 3
rsImages.Open()
rsImages_numRows = 0
%>

Linje 47 er denne:
rsImages.Open()


Har du nogen ide om hvad det kan være?
Avatar billede busschou Praktikant
06. april 2005 - 11:57 #32
prøv at udskrive din rsImages.Source
For det må betyde at der er en uoverensstemmelse i din Select statement
Avatar billede Slettet bruger
06. april 2005 - 12:09 #33
Jeg skriver følgende: (Ved ikke om det er rigtigt sted osv.)
<%
set rsImages = Server.CreateObject("ADODB.Recordset")
rsImages.ActiveConnection = MM_ImgDatabase_STRING
rsImages.Source = "SELECT FileHeading, FileText, FileURL, FileID, FileKeyWords, FileDate, FileType  FROM Files  WHERE FileType = 1 AND FileKeyWords LIKE '%" + Replace(rsImages__varImgSearch, "'", "''") + "%' AND FileID > 1  ORDER BY FileHeading"
rsImages.CursorType = 0
rsImages.CursorLocation = 2
rsImages.LockType = 3
response.write(rsimages.source)
%>

Så kommer den med følgende resultat:

SELECT FileHeading, FileText, FileURL, FileID, FileKeyWords, FileDate, FileType FROM Files WHERE FileType = 1 AND FileKeyWords LIKE '%%' AND FileID > 1 ORDER BY FileHeading

Dvs. at det jo faktisk bare er teksten den får ind?
Avatar billede busschou Praktikant
06. april 2005 - 12:14 #34
Data type mismatch in criteria expression ... line 47
Det betyder jo at der står en type foran = og en anden efter... vil jeg tro
Er FileType tal eller streng i databasen?
Avatar billede Slettet bruger
06. april 2005 - 12:16 #35
De er allesammen sat op til at være streng i databasen undtagen FileID som er autonummering og dato som er dato.
Avatar billede busschou Praktikant
06. april 2005 - 12:17 #36
ok så skal der nok være en pling omkring sådan her
rsImages.Source = "SELECT FileHeading, FileText, FileURL, FileID, FileKeyWords, FileDate, FileType  FROM Files  WHERE FileType = '1' AND FileKeyWords LIKE '%" + Replace(rsImages__varImgSearch, "'", "''") + "%' AND FileID > 1  ORDER BY FileHeading"
Avatar billede Slettet bruger
06. april 2005 - 12:33 #37
Du er sgu en klog mand... :-)
Så kom selve linket til billederne frem, men den kan ikke finde selve billederne.
Den skriver:
File not found og med koden:

set fsd=Server.CreateObject("Scripting.FileSystemObject")
set fod=fsd.GetFile (Request ("APPL_PHYSICAL_PATH") & rsImages("FileURL"))
Response.Write Round(fod.Size/1024, 2) & " Kb"

(Det er den miderste linje der melder fejl i).
Det er vel "APPL_PHYSICAL_PATH" jeg skal ændre til hele stien som i upload??
Jeg har så prøvet, men den skriver det samme.
Avatar billede busschou Praktikant
06. april 2005 - 13:53 #38
Undskyld svar tiden...skulle lige lidt ud :o)
Har du prøvet at lave en
Response.Write (Request ("APPL_PHYSICAL_PATH") & rsImages("FileURL"))
Bare for at se hvordan det hele ser ud i sammenhæng
Hvis den ikke kan finde filen ...så tjek om den overhovedet er der
Eller om der måske står filnavne i databasen som ikke er at finde på serveren
Avatar billede Slettet bruger
06. april 2005 - 13:59 #39
Det er helt ok! :-)
Er glad for du gider hjælpe.
Jeg kæmper på livet løs med det, nu har jeg fundet ud af at stinavnet var forkert
i databasen så det kæmper jeg lige med at få rigtigt nu.
Giver lige besked om hvordan det går. :-)
Avatar billede Slettet bruger
06. april 2005 - 14:49 #40
Nå, nu begynder jeg at nærme mig.. hehe.. det er noget skummelt kode...

Følgende linje:
set fod=fsd.GetFile (Request ("c:\webs\FULDSTI\upload\cms") & rsImages("FileURL"))

Giver følgende:
c:\webs\FULDSTI/http://WEBADRESSE\upload\cms\images7_fakeslo4uo.jpg

Så jeg skal vel bare fjerne det første ser det ud til?

Men hvordan laver jeg kodelinjen om så det har den rigtige syntax så jeg
kan få det første væk?
Avatar billede Slettet bruger
06. april 2005 - 16:41 #41
JUBIIIIIIII.. Så virker det!! :-)
Jeg hader når koden ikke virker, det er til at få grå hår af!
Det var godt nok noget mærkeligt kode, men jeg fandt hoved og hale
i det .. dejligt... Men kunne ikke have gjort det uden dig.
SÅ TUSIND TAK! Fedt der er nogle der gider hjælpe.
Ps. min hjemmeside hedder www.hyggestedet.dk hvis du skulle have lyst
til at kigge forbi...
Avatar billede Slettet bruger
06. april 2005 - 16:42 #42
Har prøvet at accepterer dit svar, men der sker ikke noget?
Avatar billede busschou Praktikant
06. april 2005 - 16:46 #43
hmm det kommer forhåbentlig....bedste er at det endelig virker...og det var så lidt :o)
Avatar billede busschou Praktikant
06. april 2005 - 17:09 #44
kan da lige lægge et svar til og se om det hjælper :o)
Avatar billede Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Loading billede Opret Preview
Kategori
Programmeringssprog kurser
Kurser inden for grundlæggende programmering
Se alle Programmeringssprog kurser

Flere spørgsmål fra ASP kategorien

Titel Indlæg Oprettet Seneste aktivitet
Jeg bakser med noget Database og If Then med ASP - hvad gør jeg galt? Af Peer i ASP 9 25/06/202622:20 29/06/202621:55
Tjek alle checkbox i form Af bsn i ASP 4 18/05/202601:57 19/05/202613:33
Lost focus Af bsn i ASP 1 07/11/202415:34 01/01/202514:58
ASP classic Af bsn i ASP 8 28/10/202423:11 30/10/202422:51
Classic - filer vist med sidste fil først Af bsn i ASP 5 23/05/202409:56 24/05/202400:02
Se alle spørgsmål i kategorien Opret spørgsmål

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Opret Log ind

Du kan også logge ind via nedenstående tjenester

Alle kategorier på Eksperten
Seneste spørgsmål Seneste aktivitet
I dag 13:55 Ukendt sender e-mails fra - og til min e-mail adresse Af mort1 i Andet sikkerhed
I går 11:08 Forskel mellem klokkeslet start aften slut næste morgen Af krasmussen i Excel
23/0715:10 WINDOWS KOMPABILITET Af snestrup2000 i Windows
22/0720:19 DVB T2 tuner med optagefunktion Af ErikHg i Andet hardware
20/0716:00 Fildeling mellem 2 windows 11 systemer Af knudg i Windows
White papers
Flere white papers »