Vil ikke vise store bogstaver?

Det virker fint med overskriften, men ikke i selve beskeden.

Du har vel ikke en lcase på inden du skriver det til browseren?

Hej steent, hvordan ser jeg om jeg har det.?

Prøv at smide koden der skriver beskeden ud.

Jeg tro nok det er dette, uden at vide det med sikkerhed


<div id="indhold">

<h1 style="margin-bottom:0px"><%Response.Write strTitle%></h1>

<%

intPage = Request("page")
If isNumeric(intPage) = False Or intPage < 1 Then
  intPage = 1
End If

function smiley(felt)
'opsætning
felt=Replace(felt,vbNewLine, "<br>")
felt=Replace(felt,"  ","&nbsp; ")
'Smileys
felt=Replace(felt,":)","<img src=""img/smiley/smileys141[1].gif"" align=""middle"" alt="""">")
felt=Replace(felt,";S","<img src=""img/smiley/smileys147[1].gif"" align=""middle"" alt="""">")
felt=Replace(felt,":P","<img src=""img/smiley/smileys121[1].gif"" align=""middle"" alt="""">")
felt=Replace(felt,":|","<img src=""img/smiley/smileys113[1].gif"" align=""middle"" alt="""">")
felt=Replace(felt,":D","<img src=""img/smiley/smileys118[1].gif"" align=""middle"" alt="""">")
felt=Replace(felt,":'(","<img src=""img/smiley/smileys126[1].gif"" align=""middle"" alt="""">")
felt=Replace(felt,":(","<img src=""img/smiley/smileys125[1].gif"" align=""middle"" alt="""">")
'Bandeord
felt=Replace(LCase(felt),"fuck","f*ck")
felt=Replace(LCase(felt),"idiot","slettet")
felt=Replace(LCase(felt),"luder","slettet")
felt=Replace(LCase(felt),"pik","slettet")
felt=Replace(LCase(felt),"fisse","slettet")
felt=Replace(LCase(felt),"spasser","slettet")
smiley=felt
end function

Set rs = Server.CreateObject("ADODB.RecordSet")
strSQL = "SELECT * FROM Guestbook ORDER BY Dato DESC;"
strDSN = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ="&Server.MapPath("/jaja.mdb")
rs.Open strSQL, strDSN, 1
If Not (rs.BOF Or rs.EOF) Then
  rs.PageSize = 5
  rs.AbsolutePage = intPage
  intRecCount = rs.PageSize
  intPageCount = rs.PageCount
  Response.Write "<p><b>Side " & intPage & " af " & intPageCount & "</b></p>"
  Do While Not rs.EOF And intRecCount > 0

        dtmDato = rs("Dato")
        dtmDato = FormatDateTime(dtmDato,vbLongDate) & " kl. " & FormatDateTime(dtmDato,vbLongTime)
        Response.Write "<div style='border: solid 1px #fff;padding: 8px; background-color: #333333'>Den " & dtmDato & " skrev "
        If Len(rs("Email")) > 0 Then
        Response.Write "<a class='tlink' href='mailto:" & rs("Email") & "'>" & rs("Navn") & "</a><br />"
        End If
        Response.Write "<span class='overskrift5'>" & rs("Overskrift") & "</span><br />"
        strContent= smiley(rs("Kommentar"))
        Response.Write strContent & "</div><br />"
       
  intRecCount = intRecCount - 1
  rs.MoveNext
  Loop
End If
rs.Close
Set rs = Nothing

Response.Write "<p>Gå til side "
For intNum = 1 To intPageCount
  Response.Write "<a class='link2' href=/gb.asp?page=" & intNum & ">" & intNum & "</a> "
Next
%>

Erstat LCase(felt) med felt, så skulle den være der.

felt=Replace(LCase(felt),"fuck","f*ck")
felt=Replace(LCase(felt),"idiot","slettet")
felt=Replace(LCase(felt),"luder","slettet")
felt=Replace(LCase(felt),"pik","slettet")
felt=Replace(LCase(felt),"fisse","slettet")
felt=Replace(LCase(felt),"spasser","slettet")

Bare så der kun står felt=Replace(felt),"fuck","f*ck")?

Så får du jo kun erstattet "blomst" og ikke "BLOMST" eller "BlOmSt".
Du skal

    felt=Replace(felt,"blomst","slettet",1,-1,1)

for at gøre den case-in-sensitiv i replacen, men bevare de store og små bogstaver i felt.

Sådan.? felt=Replace(felt,"fuck","f*ck")

erikjacobsen, hvad gør ,1,-1,1) ?

Nå men det virker sq som det skal. Jeg har fået rette store bogstaver og at man ikke kan skrive BlOmSt :)

Må jeg ha lov til at dele point mellem jer.?

Nej tak, jeg samler ikke på point. Det sidste 1 tal betyder at den sammenligne case-in-sensitivt
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/script56/html/vsfctreplace.asp

steent og erikjacobsen, tak for hjælpen

Anytime