Return i en sub eller function

Function NavnPaaFunktion()
    NavnPaaFunktion = værdi
End Function

En sub kan ikke returnere noget

Forskellen på en sub og en funktion er at en sub ikke returnerer en værdi men en funktion gør
---
<%
Call sub_udskriv("hej")

response.write funktion_udskriv("børge")

Sub sub_udskriv(ord)
  response.write "ord")
End Sub

Function funktion_udskriv(ord)
  funktion_udskriv = "hej"&ord
End Function
%>

se i øvrigt
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/script56/html/vsstmsub.asp
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/script56/html/vsstmfunction.asp

Vil det sige at jeg ikke kan gøre følgende:


Function Query(sql)
    rs.Open sqlStr, cn
    Query = rs
End Function

rs = Query("Select * From Test1")

hmm jo det burde du så netop fordi det er en funktion
Og du siger at funktionen skal returnere rs

men du skal selvfølgelig kalde den med sql og ikke sqlStr  når det er den du giver i parameter
---
Function Query(sql)
    rs.Open sql, cn
    Query = rs
End Function
---
og tilsvarende så skal den vide hvad "cn" er
Med mindre du har defineret "cn" globalt så skal den også med som parameter

ja og tilsvarende med rs.open, det kræver at rs er defineret globalt

Jeg får denne fejl:

Der opstod en Microsoft VBScript-kørselsfejl (0x800A01C2)
Antallet af argumenter er forkert eller egenskabstildelingen er ugyldig: 'rs'

Men altså, hvis det var mig så ville jeg erklære rs, cn med mere og benytte en sub til at tildele dem ala
---
Dim rs,cn
Set rs = //noget create recordset
Set cn = //hvad den nu skal være
Sub query(sql)
  rs.open sql,cn
End Sub
---
så vil du udenfor bare kunne kalde
query("Select * From Test1")
og så kan du nu direkte bruge rs da den er Dim´et globalt

Ok måske jeg vil gøre det sådan, men kan du se hvorfor det her sker:


Set rs = CreateObject("ADODB.Recordset")
Set cn = CreateObject("ADODB.Connection")
cn.Open "DRIVER={SQL Server};SERVER=mssql.test.com;DATABASE=test;UID=hem;PWD=hem"                   
               
rs = Query("Select * From Test")     
           
Function Query(sqlStr)
    rs.Open sqlStr, cn 
    Query = rs   
End Function



Dette får denne fejl:
Der opstod en Microsoft VBScript-kørselsfejl (0x800A01C2)
Antallet af argumenter er forkert eller egenskabstildelingen er ugyldig: 'rs'

hmm ikke umiddelbart, hvilken linje er fejlen i?
Jeg kender ikke så meget til den måde at åbne recordset på desværre
Men det kunne også måske tyde på at man så ikke kan lave en funktion returnere et recordset, det kan jeg bare ikke lige forstå hvis man ikke kan, ville jeg mene man kunne

men altså der er da vist ingen grund til at have en funktion
Da du har erklæret rs højere oppe så er den jo tilgængelig
---
Set rs = CreateObject("ADODB.Recordset")
Set cn = CreateObject("ADODB.Connection")
cn.Open "DRIVER={SQL Server};SERVER=mssql.test.com;DATABASE=test;UID=hem;PWD=hem"                 
             
Query("Select * From Test")   
         
Sub Query(sqlStr)
    rs.Open sqlStr, cn
End Sub
-----
Burde være lige så godt og så kan du bruge rs som du vil

rs er et objekt, dvs der skal benyttes Set ved return

Set Query = rs

Personlig ville jeg nok bruge cn.Execute

Function Query(sqlStr)
    Set Query = cn.Execute(sqlStr)
End Function

Set rs = Query("...")
...
rs.Close

Det virker glimrende, tak begge. Smider i et svar?

oki godt det virker :o)

Bare til orientering kan en sub godt returnere en værdi, hvis variablen er defineret udenfor sub'en... fx.

dim returnvalue

sub tester(ord)
  returnvalue = ord
end sub

call tester("hej")
Response.write returnvalue

Men er lidt mere besværlig....

Det vil jeg så godt nok ikke kalde at 'returnere' en værdi :o

Hvis man skal have en Sub til at "returnere" en værdi, ville jeg nok bruge denne metode:

Hvis ByVal ikke angives explicit, vil rs pege på vores variabel udenfor

Sub Query(sqlStr, rs)
    Set rs = Conn.Execute(sqlStr)
End Sub

Dim rs
Call Query("select * from tal", rs)

ttopholm >> returnere, det må vist slås op i en ordbog ;o) For det der er ikke at returnere en værdi, det er at ændre en værdi. I min verden uden at slå det op i en ordbog så betyder returnere "at komme hjem"/"vende tilbage", på samme måde som ordet "return".
Du kan sende børnene i byen og enten kan de komme hjem med vare (returnere en vædi), eller også kan de spise dem undervejs (ikke returnere en værdi), men din pung bliver tom uanset hvad (den globale variabel) :o)

ja.. det er nu rigtigt...