Åbne xml side igennem asp side.

Jeg har prøvet med følgende:

Dim objSvrHTTP
Dim PostData

Set objSvrHTTP = Server.CreateObject("Msxml2.ServerXMLHTTP.4.0")
objSvrHTTP.open "GET", Url, false
objSvrHTTP.send
Response.Write objSvrHTTP.responseText

Men den tekst jeg sender over bliver konverteret således at specielle tegn bliver lavet om:
æ bliver til Al
å bliver til aY (med 2 streger over y'et)

Skal jeg sende mine parameter over på en anden måde end igennem min url, eller skal jeg konverter mine tegn til et andet format eller fortælle hvilket format jeg sender i?

Faldt over denne funktion:
Server.URLEncode()

Er den god nok til det, og får modtageren det så stadig I et format han kan læse?

Jeg tror det har noget med encoding at gøre (det er altid et godt sted at starte når man arbejder med XML og videresendelse af informationer :))...

Du kan se hvilken encoding din server sender XML'en med ved at udskrive/aflæse objSvrHTTP.getAllResponseHeaders. Det kan være du kan finde noget interessant information om charset og encoding deri. Dine egen encoding skal gerne passe til den encoding som XML'en har eller er der lagt op til problemer...

Det vil jeg lige undersøge ... kan du hjælpe med delen med at læse de ting der står i xlm'en jeg åbner?

Det vil jeg tro, men prøv at kaste det i min retning, så må vi se hvad jeg formår... :)

Fik løst problemet med min querystring vha Server.URLEncode(). Nu mangler jeg bare lidt hjælp til at læse fra xml siden.

For lige at ridse op igen, så ser XML dokumentet således ud:
<Root><version>3.0</Version></Root>

Og det jeg gerne vil kunne få fat i er det der står i version således at jeg kan lave en variabel der hedder:
xml_version = [3.0 fra xml siden]

"kaste det i din retning" ... forstår ikke lige hvad du mener?

Det er vel bare sådan et kikset slang for at hvis du vil have hjælpe skal jeg gerne prøve :)

ServerHttp returnerer såvidt jeg har forstået en responseXml som er et DOM-document. Det kan du foretage søgninger i med XPath via selectSingleNode og selectNodes. selectSingleNode returnerer en xmlnode og selectNodes returnerer en liste af nodes.

I dit tilfælde skal du jo nok bruge selectSingleNode, nogenlunde således:

set objXml = objSvrHTTP.responseXml
set objVersion = objXml.documentElement.selectSingleNode("/Root/version")
versionText = objVersion.text

versionText skulle så gerne indeholde den versionsinformation som du eftersøger (nævner lige med det samme at det er aldeles utestet, så forbehold for variationer i den faktiske brug og syntaks - men prøv dette først)...

Det giver:
Object required: 'objXml.documentElement'

Prøv denne istedet:

set objVersion = objXml.selectSingleNode("/Root/version")

Det giver:
Object required: 'objVersion'

i denne linie:
versionText = objVersion.text

Det er fordi den ikke finder det den søger og så returnerer den nothing. Prøv dels at udskriv indholdet af responseXML (jeg tror du kan gøre det via xml-egenskaben på objXml), dels at ændre XPath til //Root/version.

Husk at xml og søgning i xml er case-sensitiv, så det er vigtigt at få skrevet sine XPath's korrekt :)

har pøvet det hele men det hjælper ikke ... får stadig en object required.

Det er nok fordi der er fejl i XML-formatet og det dermed ikke bliver indlæst i responseXML. Hvis det er det XML du har postet tidligere, så er åbnings-tag for version med små bogstaver og luknings-tag (er det virkelig noget der hedder det!?) med stort V (</Version>)...

Det ser således ud:

Det xml retursvar jeg får lige nu er:

<?xml version="1.0" encoding="iso-8859-1" ?>
  <ROOT>
  <ERROR>Authentication failed.</ERROR>
  <PROCESSINGTIME>0.09446692</PROCESSINGTIME>
  <VERSION>3.0</VERSION>
  </ROOT>

Og min kode ser pt. således ud:
Dim objSvrHTTP
Dim PostData

Set objSvrHTTP = Server.CreateObject("Msxml2.ServerXMLHTTP.4.0")
objSvrHTTP.open "GET", Url, false
objSvrHTTP.send

set objXml = objSvrHTTP.responseXml
set objVersion = objXml.selectSingleNode("/ROOT/VERSION")
versionText = objVersion.text

Og jeg får følgende fejl:
Object required: 'objVersion'

I denne linie:
versionText = objVersion.text

...og

set objVersion = objXml.selectSingleNode("//ROOT/VERSION")

gav heller ikke noget positivt resultat?

Nope ... det giver:
Object required: 'objVersion'

Det var da ligegodt s.....!!!

Vil du ud med hvilken adresse/URL du spørger på?

http://smsc.comsms.dk/

Jeg kan simpelthen ikke få det til at fungere med responseXML-egenskaben på objSvrHTTP-objektet, så jeg har gjort det på en anden måde. Således:

set objSvrXML = Server.CreateObject("MSXML2.ServerXMLHTTP.3.0")
objSvrXML.open "GET", Url, false
objSvrXML.send

set objXml = Server.CreateObject("MSXML2.DOMDocument.3.0")
objXml.LoadXML(objSvrXML.responseText)
set objVer = objXml.selectSingleNode("//VERSION")
versionText = objVer.text
set objXml = nothing

set objSvrXML = nothing

Det virker noget bedre, har dog lige en sidste ting jeg skal have hjælp til. Jeg skal gerne have lavet så hvis der findes en node ERROR så skal der udsendes en mail. Det umidelbare problem er bare at der kun findes ERROR noden hvis der er fejl, og det er derfor ikke altid at denne vil blive fundet. Jeg har prøvet med følgende:

set objSvrXML = Server.CreateObject("MSXML2.ServerXMLHTTP.3.0")
objSvrXML.open "GET", Url, false
objSvrXML.send

Svar = Replace(Replace(objSvrXML.responseText, """", ""), "<?xml version=1.0 encoding=iso-8859-1?>", "")

set objXml = Server.CreateObject("MSXML2.DOMDocument.3.0")
objXml.LoadXML(objSvrXML.responseText)
set objinfo = objXml.selectSingleNode("//ERROR")
Fejl = objinfo.text

' Rydder op
set objXml     = nothing
set objSvrXML     = nothing

' Ved fejl sendes en mail med oplysninger om fejlen
If Fejl & "X" <> "X" Then
    Send_email_resultat = Send_email("-", "asd@asd.com", "Fejl", Url & "<br><br>" & Svar, "asd@asd.com")
End If

Response.write Svar

Det virker fint når retur xml'et indeholder <ERROR> men når feltet ikke er en del af svaret så hænger min kode og jeg får aldrig udskrivet "Svar" på min side. Hvordan kan jeg lige lave den undersøgelse der finde ud af om <ERROR> findes i xml svaret?

Du skal checke på om

objXml.selectSingleNode("//ERROR")


returnerer nothing. Nogenlunde således:

if objXml.selectSingleNode("//ERROR") is nothing then
  ' så er der ikke nogen fejl-node
else
  ' så er der en fejl-node
end if

Super. Så er den hjemme!

Mange tak for hjælpen. Smid et svar.

Velbekomme :)

Tak for point :)