Record sidst opdateret

Du skal selv ind og opdatere feltet når du indsætter/opdatere rækken. Du smider den bare med på SQL'en:

conn.execute("update DinTabel set felt1='abc', datoFelt=now() where ID=123")

Jamen det lyder da logisk :-)
Mit datofelt hedder "date" men jeg kan ikke rigtig se hvor det skal placeres i koden? Skal lige sig det er ikke jeg der har lavet koden, men jeg sidder og øver mig på at få den til at virke - den virker. Har sat ekstra felter på og pillet nogle fra...og det virker stadig :-)
Kan du vise mig hvor jeg bør sætte din kode ind på scriptet? Den har jeg ikke kunnet løse.
På forhånd tak!
<%@LANGUAGE="VBSCRIPT" CODEPAGE="1252"%>
<%if not session("AdminOk")="true" then response.Redirect "login.asp" %>
<!--#Include file="cn.asp"-->
<!--#include File="upload.asp"-->

<%
    dim productname
    dim price
    dim price1
    dim price2
    dim category
    dim details
    dim filename

    dim msg
    Set Uploader = New FileUploader
    Uploader.Upload()


    if Uploader.Form("submit")<>"" then
        productname = Uploader.Form("name")
        price = Uploader.Form("Price")
        price1 = Uploader.Form("Price1")
        price2 = Uploader.Form("Price2")
        category = Uploader.Form("Category")
        details = Uploader.Form("details")
        call SaveRecord()
    End if

    if request.QueryString("id")<>"" then
        call GetRecord()
    End if


Sub SaveRecord()

    dim rs
    dim cn

    set cn = server.CreateObject("Adodb.Connection")
    set rs = server.CreateObject("Adodb.Recordset")

    cn.Open conn

    if Uploader.Files.count <> 0 then
        File = Uploader.Files.Items()
        File(0).SavetoDisk Server.MapPath("images\products")
        filename = File(0).Filename
    else
        filename = ""
    End if


        if Uploader.Form("id")="" then
            rs.open "Select * From Products",cn,2,3
            rs.addnew
            rs.fields("productname") = productname
            rs.fields("price") = price
            rs.fields("price1") = price1
            rs.fields("price2") = price2
            if filename <>"" then rs.fields("image") = filename
            rs.fields("details") = details
            rs.fields("categoryid") = category
            rs.update
            msg = "Produktet er tilføjet"
            saved = true
        else
            rs.open "Select * From Products Where ProductID=" & Uploader.Form("id"),cn,2,3
            rs.fields("productname") = productname
            rs.fields("price") = price
            rs.fields("price1") = price1
            rs.fields("price2") = price2
            rs.fields("details") = details
            rs.fields("categoryid") = category
            if filename <>"" then rs.fields("image") = filename
            rs.update
            msg = "Produktet er opdateret"
            saved = true
        End if


    rs.close
    cn.close
    set rs = nothing
    set cn = nothing

End Sub


Sub GetRecord()

    dim rs
    dim cn

    set cn = server.CreateObject("Adodb.Connection")
    set rs = server.CreateObject("Adodb.Recordset")

    cn.Open conn
    rs.open "Select * From Products Where ProductID=" & request.QueryString("id"),cn
    if not rs.eof then
        productname = rs.fields("productname")
        price = rs.fields("price")
        price1 = rs.fields("price1")
        price2 = rs.fields("price2")
        details = rs.fields("details")
        category = rs.fields("categoryid")
        filename = rs.fields("image")
    End If
    rs.close
    cn.close
    set rs = nothing
    set cn = nothing
    msg = "Produktlinien er loaded."
End Sub

%>

<html>
<head>
<title>Admin</title>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<link href="style.css" rel="stylesheet" type="text/css">
</head>

<body>
<p align="center"><strong>Online Produkt Katalog administration</strong></p>
<p align="center"> <font color="#FF0000"><%= msg%> </font></p>
<form action="" method="post" enctype="multipart/form-data" name="form1">
  <table width="56%" height="237" border="1" align="center" cellpadding="1" cellspacing="1" bordercolor="#CCCCCC">
    <tr>
      <td height="23" colspan="2" bgcolor="#CCCCCC"><font size="2" face="Verdana, Arial, Helvetica, sans-serif"><strong>Tilføj nyt produkt</strong></font></td>
    </tr>
    <tr>
      <td height="23">&nbsp;</td>
      <td>&nbsp;</td>
    </tr>
    <tr>
      <td width="37%" height="23"><font size="2" face="Verdana, Arial, Helvetica, sans-serif">Produkt
        Navn </font></td>
      <td width="63%"><input name="name" type="text" id="name3" value="<%=productname%>">
      </td>
    </tr>
    <tr>
      <td height="26"><font size="2" face="Verdana, Arial, Helvetica, sans-serif">pris</font></td>
      <td><input name="price" type="text" id="name" value="<%=price%>"></td>
    </tr>
    <tr>
      <td height="26"><font size="2" face="Verdana, Arial, Helvetica, sans-serif">pris1</font></td>
      <td><input name="price1" type="text" id="name1" value="<%=price1%>"></td>
    </tr>
    <tr>
      <td height="26"><font size="2" face="Verdana, Arial, Helvetica, sans-serif">pris2</font></td>
      <td><input name="price2" type="text" id="name2" value="<%=price2%>"></td>
    </tr>
    <tr>
      <td height="26"><font size="2" face="Verdana, Arial, Helvetica, sans-serif">Kategori</font></td>
      <td><select name="category" id="category">
          <%
dim rs1
dim cn1
set cn1 = server.CreateObject("Adodb.Connection")
set rs1 = server.CreateObject("Adodb.Recordset")
cn1.Open conn
rs1.open "Select * From ProductCategories",cn1
%>
          <option value="0" selected >Vælg</option>
          <option value="0" >-</option>
          <%if not rs1.eof then
          while not rs1.eof%>
          <option value="<%=rs1.fields("CategoryID")%>" <%if CLng(Category)=rs1.fields("CategoryID") then response.Write("Selected")%>><%=rs1.fields("CategoryName")%></option>
          <%
rs1.movenext
wend
end if
%>
        </select> </td>
    </tr>
    <tr>
      <td height="26" valign="top"><font size="2" face="Verdana, Arial, Helvetica, sans-serif">Billede</font></td>
      <td><input type="file" name="file">
        <font color="#FF0000"><%= filename%></font></td>
    </tr>
    <tr>
      <td height="26" valign="top"><font size="2" face="Verdana, Arial, Helvetica, sans-serif">Beskrivelse</font></td>
      <td><textarea name="details" cols="40" rows="5" id="name3"><%=details%></textarea></td>
    </tr>
    <tr>
      <td height="26">&nbsp;</td>
      <td>&nbsp;</td>
    </tr>
    <tr>
      <td height="26">&nbsp;</td>
      <td><input type="submit" name="Submit" value="OK"> <input type="reset" name="Submit2" value="Reset">
      </td>
    </tr>
  </table>
  <input name="id" type="hidden" id="id" value="<%=request.querystring("id")%>">
</form>
<p>&nbsp; </p>
<p><a href="listproducts.asp">Vis </a></p>
<p>&nbsp;</p>
<p>Tilbage til <a href="admin.asp">Hovedmenu</a></p>
</body>
</html>

Dit script bruger en anden metode til at updatere/indsætte, så det skal se sådan ud:


        if Uploader.Form("id")="" then
            rs.open "Select * From Products",cn,2,3
            rs.addnew
            rs.fields("productname") = productname
            rs.fields("price") = price
            rs.fields("price1") = price1
            rs.fields("price2") = price2
            if filename <>"" then rs.fields("image") = filename
            rs.fields("details") = details
            rs.fields("categoryid") = category
            rs.update
            msg = "Produktet er tilføjet"
            saved = true
        else
            rs.open "Select * From Products Where ProductID=" & Uploader.Form("id"),cn,2,3
            rs.fields("productname") = productname
            rs.fields("price") = price
            rs.fields("price1") = price1
            rs.fields("price2") = price2
            rs.fields("details") = details
            rs.fields("categoryid") = category
            rs.fields("date") = now()  '<-- Denne linje skal indsættes.
            if filename <>"" then rs.fields("image") = filename
            rs.update
            msg = "Produktet er opdateret"
            saved = true
        End if

Bingo! Det virker bare - ørste gang. Jeg er imponeret, og glæder mig til at kunne se en kode og løse den med det samme....- selvom det virker som om det har lange udsigter :-)Øvelse gør mester.
Tusind tak for hjælpen.
Hav en fortsat god dag.