Macro/vb til .txt!?

Sub LagreSomTekstfil()
  Dim filnavn As String
  Dim rngCopyRange As Range
  Set rngCopyRange = ThisWorkbook.Sheets(1).Range("A1:A20")
  filnavn = ThisWorkbook.Sheets(1).Cells(2, 2).Value
 
  With Workbooks.Add
    With Sheets(1)
      .Range("A1:A20").Value = rngCopyRange.Value
      ActiveWorkbook.SaveAs Filename:="C:\NavnetPÅDinMappe\" & filnavn & ".txt", _
      FileFormat:=xlText, CreateBackup:=False
    End With
    Application.DisplayAlerts = False
    .Close
    Application.DisplayAlerts = True
  End With
End Sub

denne koden forutsetter at du skriver inn navnet på teksfilen,
i samme ark som du har data
for eksempel hvis du har skrevet filnavnet i "B2" ( celle(2,2) )
filnavn = ThisWorkbook.Sheets(1).Cells(2, 2).Value
du må også skrive inn navnet på din mappe her:
ActiveWorkbook.SaveAs Filename:="C:\NavnetPÅDinMappe\" &

Det virker... Kan man gøre at den skriver Lager +filnavn = ThisWorkbook.Sheets(1).Cells(2, 2).Value

Så det kommer til at se sådan her ud "Lager Filnavn.txt

Og hvis det fil navn som er i B2 er der som en .txt kan man ikke gøre at den skriver Lager2 3 4 5 6 7 8 9 osv for ikke at over skrive!?

hvis du har win2000 eller senere,
kan vi finne en løsning der filnavnet genereres automatisk.
feks lager1, lager2 koden sjekker hvilke filer som ligger i mappen fra før.
Så legger det til første ledige tall

har 2000 og xp... og excel xp og 2003

Men hvis den bare skriver lager + Værdien i B2, Hvis den fil er der op forhånd skal den skrive Lager NR B2.txt el. Lager B2 Nr.txt

' Denne krever at du i menyen går inn i Tools-> References..
' krysset av for  Microsoft Scripting Runtime
' husk også å skrive inn hele navnet på din mappe

Sub LagreSomTekstfil()
 
  Dim fso As FileSystemObject
  Dim fsoFld As folder
  Dim fsoFil As File
 
  Dim filnavn As String
  Dim rngCopyRange As Range
  Dim n As Variant
  Dim s As String
  s = ""
  Set rngCopyRange = ThisWorkbook.Sheets(1).Range("A1:A20")
  filnavn = "Lager Nr " & ThisWorkbook.Sheets(1).Cells(2, 2).Value & ".txt"
 
  Set fso = CreateObject("Scripting.FileSystemObject")
  Set fsoFld = fso.GetFolder("C:\SKRIV NAVNET PÅ DIN MAPPE HER\")
 
  If fso.FileExists(fsoFld & "\" & filnavn) Then
    n = 1
    Do While fso.FileExists(fsoFld & "\" & Left( _
      filnavn, Len(filnavn) - 4) & " " & n & ".txt")
      n = n + 1
    Loop
    s = " "
  End If
  filnavn = Left(filnavn, Len(filnavn) - 4) & s & n & ".txt"
 
  With Workbooks.Add
    With Sheets(1)
      .Range("A1:A20").Value = rngCopyRange.Value
      ActiveWorkbook.SaveAs Filename:=fsoFld & "\" & filnavn, FileFormat:=xlText
    End With
    Application.DisplayAlerts = False
    .Close
    Application.DisplayAlerts = True
  End With
 
  Set fso = Nothing
  Set fsoFld = Nothing
End Sub

laver fejl 400. ellers virker den laver filen men dør lige efter med en fejl popup 400 !?

Jo den kunne bare ikke være på "C.\" Skulle være i en mappe... :D lækkert
kom med et svar

har den også laget tekstfilen?

:o)

Jep den køre som min tanke ville have det... :D