Søg værdi ud fra år/måned

1) =SUMPRODUKT((MÅNED(A1:A2000)=12)*(B1:B2000)) giver summen af arbejdstid i december måned. (Under forudsætning af at dien datoer er indtastet som datoer, altså fx 12-2-05, ikke som du anfører 12.2.05.

2) =SUMPRODUKT((ÅR(A1:A2000)=2005)*(B1:B2000)) giver summer for året, under samme forudsætning.

Hvis du skal kunne indtaste måned i fx C1 og år i C2 skal dine formler ændres til:

=SUMPRODUKT((MÅNED(A1:A3)=C1)*(B1:B3))
og
=SUMPRODUKT((ÅR(A1:A3)=C2)*(B1:B3))

Husk, årstallet skal tastes med fire cifre.

Oki, umiddelbart får jeg en "VÆRDI" fejl men sætter mig mere ind i eksemplet senere i dag. Min formel ser sådan ud:
=SUMPRODUKT((ÅR(Logbook!A6:A2000)=2005)*(Logbook!O6:O2000))

I kolonne A6:A2000 er datoen skrevet sådan: 12-2-05(2005) men vises 12.02.2005
Dvs i formellinjen står der: 12-02-2005 hvis jeg vælger cellen 12.02.2005

Har det noget at sige?

Ifølge din beskrivelse af dato-feltet, så skulle det være godt nok.

VÆRDI-fejlen skyldes formodentligt at der er en tekst-streng i enten A6:A2000 eller O6:O2000

Umiddelbart vil det jo være nærliggende at tro, at der måske er en af dine datoer, der ikke er indlæst som en dato, men som en tekst-streng.

Du kan undersøge det ved at gøre A-kolonne BRED nok til at du kan se om værdierne er højrestillede eller venstrestillede. Så markerer du hele kolonnen, og fjerner al højrestilling og venstrestilling og centrering (kan gøres ved f.eks. at trykke på centrering to gange - første gang centreres alle felter, anden gang fjernes centreringen).

Som standard placeres tekst venstrestillet og tal højrestillet. Da datoer indlæst i datoformat er tal, skal de altså være højrestillede. Så det skulle være let at bladre dem igennem og se om der er nogen, der er venstrestillet. De venstrestillede datoer er tekst og skal rettes til rigtige datoer.

Jeg var lige væk et øjeblik, men jeg er enig med sjap i, at der formodentlig er tekst mellem dine datoer.

Eller i dine tider selvfølgelig. Det kan være begge steder.

Hmm har testet både A kolonnen og O kolonnen som beskrevet og alle tal går til højre. Men skal siges, at der er tomme celler i mellen. Har det noget at sige?

Tomme celler skulle vist ikke betyde noget, men hvis der står noget tekst (f.eks. mellemrum eller ' - som ikke kan ses) i cellerne, så giver det VÆRDI-fejlen.

Hmm ok, eksemplet før med opsætning:
(Under forudsætning af at dien datoer er indtastet som datoer, altså fx 12-2-05, ikke som du anfører 12.2.05.
Dette er for desember, ik? Og ikke februar. Skal måneden sættes først?

Nå, men har fundet frem til at VÆRDI fejlen kommer så snart jeg kommer til den første tomme celle. Nogle forslag?

Prøv at markere cellen og trykke delete - dvs. slet cellens indhold.

Stadig samme fejl. Bortset fra det, fungerer det. Så det er bare om at få ignoreret de tomme celler.

Enten må du finde ud af, hvad der står i de tomme celler, og så lave en Søg/Erstat, eller også må du manuelt slette alle de tomme celler :0(

Har markeret den tomme celle og trykket Delete. Men stadig samme fejl (tester kun med den ene tomme celle nu) Men ser om jeg kan finde ud af det. Hvis det er "nemt nok", så vender jeg tilbage og afslutter denne tråd.

Hvis det er muligt kan du evt. sende filen (eller en del af den) til sjap9000 snabela hotmail punktum com.

Desværre kan jeg ikke sende filen som den er, da det er personlige oplysninger. Men kort sagt, så er kalonne A6 til A2000 til at indsætte dato og O6 til O2000 er total arbejdstid som er baseret på møde- og sluttid.
Alle cellerne i A kolonne er samme format, og der er ikke nogle "skjulte" tegn eller mellemrum. Som jeg skrev før, så er det kun med en tom celle, jeg tester dette med, og først når den bliver inkluderet, så kommer værdi fejlen (også efter jeg har trykket Delete) Så den gør et eller andet, som gør at VÆRDI fejlen kommer.

Kan du evt. lave et udklip af arket, hvor kun kolonne A og O er med? Eventuelt blot ned til og med det tomme felt, der giver problemer?

Vil det sige, at kolonne O er resultatet af en formel? Hvis det er tilfældet, og du viser 0-værdier som blanke via en HVIS-formel - fx noget i denne stil:
=HVIS(SUM(C3:E3)=0;"";SUM(C3:E3)) vil du netop få en #VÆRDI-fejl" i SUMPRODUKT, fordi "" opfattes som en tekst.

Hmm, der har du fat i det rigtige. Det er lige hvad det er. Er der nogen måde at rette det på, uden at der kommer til at stå feks 0:00

Lad 0:00 stå, og vælg så Funktioner - Indstillinger - Vis. Fjern fluebenet fra 0-værdier.

Det bliver jeg nødt til at sige er det rigtige. Nu ved jeg bare ikke hvordan jeg accepterer svaret.
P.S. Sjap, håber du svarer emailen. Har også hjulpet. Tak til jer begge to

Eller ret din formel til

=SUMPRODUKT((ÅR(A1:A2000)=C1)*HVIS(ER:TAL((O1:O2000));O1:O2000))

Afslut med Ctrl+Skift+Enter, da den skal indtastes som matrix formel.

Sorry. ER.TAL ikke ER:TAL.

Vi skal lige lægge et svar før du kan acceptere det :-)
Bare vent på at sjap svarer, så kan du acceptere begge.

Første gang jeg bruger matrix formel. Ville bare høre om den gør noget "anden" med arket, hvis ikke, hvad er ulempen med den. Har vist set fordelen :-)

Den gør ikke andet ved arket. Ulempen er, at matrixformler bruger en anelse flere ressourcer ved genberegning, men ikke så meget at en lille matrixformel som denne vil gøre arket langsommere.

Bare giv point til jkrons - Han kom med de mest brugbare forslag :0)

Oki. Men 1000 tak til jer begge.

Velbekomme :-)

:0)

Nu kom jeg så godt i gang :=) at jeg stødte på en ny mulighed. Hvordan får en total når jeg både sætter år og måned. Feks. År i en celle og måned i en anden, så at den giver total for den måned det år. Er det en OG funtion, der bare skal sættes ind i den aktuelle.

Dette skulle gøre det - stadig som matrixformel:

=SUMPRODUKT((MÅNED(A1:A2000)=C1)*(ÅR(A1:A2000)=C2)*HVIS(ER.TAL((O1:O2000));O1:O2000))

Tast måned i C1 og år i C2.