Samle ark men uden formel og med billeder?

Denne makro laver en kopi af det ark der er aktivt når den køres. Kopien bliver lagt over i en ny fil. Derfra kan du så hente den.

Sub CreateDeadSheet()
  Dim l As Long, t As Long, y
  Dim C As ChartObject
  Dim q
  Dim cur As Range
  Dim r, k
  If ActiveSheet.ChartObjects.Count > 0 Then
      q = MsgBox("Som vist på skærm ? (Yes) " & vbCrLf & "eller som printet ? (No)", vbYesNoCancel, "Hvordan skal grafer behandles")
      If q = vbCancel Then Exit Sub
  End If
  Application.ScreenUpdating = False
  ActiveSheet.Copy
  Cells.Copy
  Cells.PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:= _
                      False, Transpose:=False


  If ActiveSheet.ChartObjects.Count > 0 Then
      For Each C In ActiveSheet.ChartObjects
        With ActiveSheet.Shapes(C.Name)
            t = .Top
            l = .Left
        End With
        If q = vbNo Then
            C.CopyPicture Appearance:=xlPrinter, Format:=xlPicture
        Else
            C.CopyPicture Appearance:=xlScreen, Format:=xlPicture
        End If
        Set y = ActiveSheet.Pictures.Paste
        With y
            .Top = t
            .Left = l
        End With
        C.Delete
      Next
  End If

  Set cur = ActiveSheet.UsedRange
  For Each r In cur.Rows
      If r.Hidden = True Then r.EntireRow.Clear
  Next
  For Each k In cur.Columns
      If k.Hidden = True Then k.EntireColumn.Clear
  Next


  Application.CutCopyMode = False
  Application.ScreenUpdating = True

End Sub