Lave flere excel fil om til en

Kan der tænkes andre komplikationer; fx at der er andre excel-filer i den pågældende mappe?
Hvis der ikke er det kan du hente alle excel-filnavnene ind i Access,
anbringe navn og tid i 2 felter i en tabel og lave en forespørgsel med  totaler/maximum for tid og du har den nyeste fil.

der er ikke andre excel-filer i mappen. Og hvordan

Jeg benytter mig af en funktion som først indlæser excel-filnavnet i en tabel, og derefter benytter denne tabel som identifikator for filimporten

Du får lige den komplette løsning her. Paste nedenstående ind i et modul, ret stien og tabelnavnet, så burde det spille. (Kør Test rutinen)

Option Compare Database
Option Explicit



Function FindNyesteFil() As String
  Const Mappen = "C:\Temp\"
  Dim d
  Dim NyesteFilnavn As String
  Dim NyesteDato As Date
 
  NyesteFilnavn = ""
  NyesteDato = #12/24/2000#
 
  d = Dir(Mappen & "*.xls")
  If d = "" Then
    FindNyesteFil = "???"
    Exit Function
  End If
  Do
    If FileDateTime(Mappen & d) > NyesteDato Then
      NyesteFilnavn = d
      NyesteDato = FileDateTime(Mappen & d)
    End If
    d = Dir
  Loop Until d = ""
 
  FindNyesteFil = Mappen & NyesteFilnavn
End Function

Sub SletTabel(Tn As String)
  On Error Resume Next
  CurrentDb.TableDefs.Delete Tn
  On Error GoTo 0
End Sub

Sub OpretExcelLink(Filnavn As String, TabelNavn As String, Arknavn As String)
  Dim Tdf As TableDef
 
  SletTabel (TabelNavn)
  Set Tdf = CurrentDb.CreateTableDef(TabelNavn)
  With Tdf
    .SourceTableName = Arknavn & "$"
    .Connect = "Excel 5.0;HDR=YES;IMEX=2;DATABASE=" & Filnavn
  End With
  CurrentDb.TableDefs.Append Tdf
  Set Tdf = Nothing
End Sub

Private Sub Test()
  Const MinTabel = "MineData"
  Dim F As String
 
  F = FindNyesteFil
  Call OpretExcelLink(F, MinTabel, "Ark1")
 
  MsgBox F & " er nu linket via tabellen " & MinTabel
End Sub

> jeg har rette C:\Temp\ til den rigtige sti og rette (TabelNavn) til nyt tabel navn men jeg få en fejl ved tabel navn skal der sættes komma nogen steder

Ovenstående kode kører fint her.
- Har du husket "\" i slutningen af stien?
- Har du tilrettet arknavnet? (hvis ikke det hedder Ark1)
- Tabelnavnet retter du ved
    Const MinTabel = "MineData"
  Tabellen er ikke en "rigtig" tabel; men et link til Excel filen.
  Bemærk, at den slettes og oprettes påny. Det sikrer et korrekt link.
- Hvilken fejlmeddelelse får du i øvrigt?

>> Tusind tak for hjælpen fdata det virker perfekt du har fortjent point

Jeg konkluderer, at du fandt fejlen. Super.
Tak for point.