JMail sender dobbelt

Du har ikke et loop der laver noget ged, altså noget for next eller lign.?

Jeg har tidligere været ude for, at min Outlook henter dobbelt af nogle mails, det kan ikke evt. være en Outlook fejl?

/Goose

Hvordan ser delen ud hvor du sender mailen... det du har vist definere kun mailen...

Hej drenge! :)

Haft ikke haft tid til at være her, sorry :)

goose: Nej, der er hverken loop eller fejl i opsætningen af MS Outlook. Jeg lægger scriptet, så du kan se det hele.

ellebaek: Det er rigtigt, jeg dimensionerer kun afsender, serveradresse, modtager, bcc etc. i det ovenstående. Lægger hele scriptet:

        Set JMail = Server.CreateObject("JMail.SMTPMail")
        JMail.ServerAddress = "localhost"
        JMail.Sender = "Denne_mail_kan_ikke_besvares@mydomain.dk"
        JMail.ReplyTo = "Denne_mail_kan_ikke_besvares@mydomain.dk"
        JMail.Subject = "Du er oprettet som bruger af mydomain.dk"
        JMail.AddRecipient Trim(Request.Form("email"))
        JMail.AddRecipientBCC "admin@mydomain.dk"
        JMail.Body = _
            "Hej " & Trim(Request.Form("firstname")) & "!" & vbNewLine & vbNewLine & _
            "..................................................." & vbNewLine & vbNewLine & _
            "..................................................." & vbNewLine & vbNewLine & _
            "..................................................."
        JMail.Execute


Jeg har en frygtelig mistanke om, at der er noget rod i opsætningerne på serveren hos min host. Jeg skiftede til ConCor for lidt over 2 år siden.

Det er ikke fordi du laver noget i stilen af:

if not JMail.sendMail() then
  response.write "Der skete en fejl"
end if

eller tilsvarende, for så vil den sende 2 gange....

Hmm? I umiddelbar forlængelse har jeg dette:

            Dim Dato
            Dato = Day(Date) & "/" & Month(Date) & "/" & Year(Date) & " " & Time()

            If JMail.Execute = True Then
                Conn.Execute("INSERT INTO myTable (username, pass, firstname, middlename, lastname, email, created, lastIP) VALUES (" & _
                    "'" & Trim(SQLEncode(Request.Form("username"))) & "', " & _
                    "'" & Trim(SQLEncode(Request.Form("password"))) & "', " & _
                    "'" & Trim(SQLEncode(Request.Form("firstname"))) & "', " & _
                    "'" & Trim(SQLEncode(Request.Form("middlename"))) & "', " & _
                    "'" & Trim(SQLEncode(Request.Form("lastname"))) & "', " & _
                    "'" & Trim(SQLEncode(Request.Form("email"))) & "', " & _
                    "'" & Dato & "', " & _
                    "'" & SQLEncode(Request.ServerVariables("REMOTE_ADDR")) & "')")
                Conn.Close
            Else
                Conn.Close
                Response.Redirect "/createuser.asp?msg=E-mail+med+brugeroplysninger+kunne+ikke+sendes+til+e-mailadressen,+og+brugeren+kunne+derfor+heller+ikke+oprettes.+Kig+efter+om+den+indtastede+e-mailadresse+er+korrekt,+og+prøv+igen."
            End If

            Set JMail = Nothing
            Response.Redirect "/createuser.asp?msg=Brugeren+er+blevet+oprettet.+Den+pågældende+bruger+vil+inden+for+kort+tid+modtage+en+e-mail+med+brugeroplysningerne,+som+skal+bruge+første+gang+der+logges+ind."

Så er det der den ligger....

Så skal du slette linien første gang du har din JMail.execute..

Så burde det spille for dig ;-)

problemet ligger i den her linie:
If JMail.Execute = True Then


den sender mailen for dig igen, så hvis du allerede har haft:
JMail.execute, så sender du den 2 gange...

Som jeg ser det, tjekkes der for, om JMail er ekseveret. Hvis det er tilfældet, skal variablerne fra formularfelterne indsættes i DB.

Hvordan kan man ellers lave det? Jeg vil gerne have, at administratoren får en besked, hvis der er noget galt:

Response.Redirect "/createuser.asp?msg=E-mail+med+brugeroplysninger+kunne+ikke+sendes.........

eller

Response.Redirect "/createuser.asp?msg=Brugeren+er+blevet+oprettet.+.............

Jeg prøver lige. Hvis det ikke virker, vender jeg lige tilbage :)

Ok, det var sq det! :)

Jeg kan godt tjekke på e-mailadressen på en anden måde, så smid lige et svar, ellebaek :)

Der er et svar her...

men det den helt præcis gør er at den tjekker om JMail.Execute returnerer True, altså at den ikke har fået en fejl fra serveren.
Så du kan stadig sagtens bruge if JMail.execute = true, men hvis du benytter den, så skal du ikke have JMail.execute til at starte med... for så sender du 2 gange ;-)

Så det skal se ud som noget i stilen af:


Set JMail = Server.CreateObject("JMail.SMTPMail")
        JMail.ServerAddress = "localhost"
        JMail.Sender = "Denne_mail_kan_ikke_besvares@mydomain.dk"
        JMail.ReplyTo = "Denne_mail_kan_ikke_besvares@mydomain.dk"
        JMail.Subject = "Du er oprettet som bruger af mydomain.dk"
        JMail.AddRecipient Trim(Request.Form("email"))
        JMail.AddRecipientBCC "admin@mydomain.dk"
        JMail.Body = _
            "Hej " & Trim(Request.Form("firstname")) & "!" & vbNewLine & vbNewLine & _
            "..................................................." & vbNewLine & vbNewLine & _
            "..................................................." & vbNewLine & vbNewLine & _
            "..................................................."
     

Dim Dato
            Dato = Day(Date) & "/" & Month(Date) & "/" & Year(Date) & " " & Time()

            If JMail.Execute = True Then
                Conn.Execute("INSERT INTO myTable (username, pass, firstname, middlename, lastname, email, created, lastIP) VALUES (" & _
                    "'" & Trim(SQLEncode(Request.Form("username"))) & "', " & _
                    "'" & Trim(SQLEncode(Request.Form("password"))) & "', " & _
                    "'" & Trim(SQLEncode(Request.Form("firstname"))) & "', " & _
                    "'" & Trim(SQLEncode(Request.Form("middlename"))) & "', " & _
                    "'" & Trim(SQLEncode(Request.Form("lastname"))) & "', " & _
                    "'" & Trim(SQLEncode(Request.Form("email"))) & "', " & _
                    "'" & Dato & "', " & _
                    "'" & SQLEncode(Request.ServerVariables("REMOTE_ADDR")) & "')")
                Conn.Close
            Else
                Conn.Close
                Response.Redirect "/createuser.asp?msg=E-mail+med+brugeroplysninger+kunne+ikke+sendes+til+e-mailadressen,+og+brugeren+kunne+derfor+heller+ikke+oprettes.+Kig+efter+om+den+indtastede+e-mailadresse+er+korrekt,+og+prøv+igen."
            End If

            Set JMail = Nothing
            Response.Redirect "/createuser.asp?msg=Brugeren+er+blevet+oprettet.+Den+pågældende+bruger+vil+inden+for+kort+tid+modtage+en+e-mail+med+brugeroplysningerne,+som+skal+bruge+første+gang+der+logges+ind."

Fedest, jeg prøver :)

Tak for hjælpen, også for dit input, goose :)