En Makro der kan konvertere fra Word til Excel

Hvor befinder du dig, når du vil indsætte teksten? I Word (filen med teksten), i Excel (i filen, hvor teksten skal indsættes) - eller noget helt andet?

Er det et udsnit af en tekst eller al tekst i en bestemt fil?

Hvor skal det hen i Excel-filen?

Jeg befinder mig i Excel filen og vil så læse teksten fra word filen ind på en celle i Excel.

har du en makro der kan løse det for mig?

Jeg kan da i hvertfald lave den, hvis du svarer på de andre af mine spørgsmål.

hej igen....Det er hele teksten der skal med....og det skal så importeres til en celle i excel regneark

Fiks og færdig :-) Husk at tilrette filnavn samt den celle, hvor du ønsker teksten indsat. Sæt også en reference til Word i vba (Tools-References).
-------
Public Sub InsertTextFromWord()
    Dim objWord As Word.Application
    Dim objWDocument As Word.Document
    Dim objCell As Range
    Dim strWordFile As String
    Dim blnCreateWord As Boolean
   
    On Error GoTo InsertTextFromWord_Error
    strWordFile = "C:\HentTekst.doc"
   
    If Dir(strWordFile) = "" Then
        MsgBox "Filen " & strWordFile & " eksisterer ikke.", vbCritical
        Exit Sub
    End If
   
    Set objCell = ActiveWorkbook.Sheets(1).Cells(1, 1)
   
    On Error Resume Next
    Set objWord = GetObject(, "Word.application")
   
    On Error GoTo InsertTextFromWord_Error
    If objWord Is Nothing Then
        Set objWord = CreateObject("Word.application")
        blnCreateWord = True
    End If
   
    Set objWDocument = objWord.Documents.Open(strWordFile)
   
    objWDocument.Range.Copy
    objCell.PasteSpecial xlPasteValues
   
InsertTextFromWord_End:
    On Error GoTo 0
   
    If Not objWDocument Is Nothing Then
        objWDocument.Close False
    End If
   
    If Not objWord Is Nothing Then
        If blnCreateWord = True Then
            objWord.Quit
        End If
        Set objWord = Nothing
    End If
   
    Set objCell = Nothing
   
    Exit Sub

InsertTextFromWord_Error:
    MsgBox "Der er sket en fejl." & vbCr & Err.Number & vbCr & Err.Description, vbExclamation
    Resume InsertTextFromWord_End
End Sub

Det virker super.....send et svar så jeg kan overføre points til dig :)

Lyder godt, at det virker, som du gerne vil have det :-)