Udskrift afhængig af feltværdi

Tillæg: Det hele skulle gerne fungere ved tryk på en knap.

"Ud fra værdier i et par felter" - hvordan forestiller du dig, at der vælges?

Det er meningen, at der skal udskrives antallet af feltet A27 i sheet'et "IT-Udstyrsark" af sheet "arbejdsseddel - Desktop" og antal print af "arbejdsseddel - Laptop" i henhold til værdien af A28 i sheet'et "IT-Udstyrsark".

Forslag:

Rem Koden indsættes i ThisWorkbook
Rem ==============================
Sub udskrivMedAntal()
Dim antalPrt, arkNavn, Dantal, Lantal
Rem hent mulige antal fra arket IT-udstyrsark
    With ActiveWorkbook.Sheets("IT-Udstyrsark")
        Dantal = .Range("A27")
        Lantal = .Range("A28")
    End With
   
Rem Hvilket ark er det aktive?
    arkNavn = LCase(ActiveSheet.Name)
   
    antalPrt = 0
   
    If arkNavn = "arbejdsseddel - desktop" Then
        antalPrt = Dantal
    Else
        If arkNavn = "arbejdsseddel - laptop" Then
            antalPrt = Lantal
        End If
    End If
   
    If antalPrt > 0 Then
        ActiveSheet.PrintOut Copies:=antalPrt, Collate:=True
    End If
End Sub

Jeg er vist for dum til det her.

Det er meningen, at jeg vil have en knap i sheet'et 'IT-udstyrsark' der altid udskriver sheet'et 'checkliste' og som før beskrevet 2 andre ark, alt efter antallet i felterne.

Jeg har uploaded filen her:  http://rapidshare.com/files/127022712/Ny_Franchisetager_-_DK_-test_2.xls

Ser på det lidt senere...

Har hentet filen..

Du nævnte tidligere: "Det er meningen, at der skal udskrives antallet af feltet A27 i sheet'et "IT-Udstyrsark" af sheet "arbejdsseddel - Desktop" og antal print af "arbejdsseddel - Laptop" i henhold til værdien af A28 i sheet'et "IT-Udstyrsark"."

A27 & 28 - antal?? - er det korrekt???

Skulle det være B27 & B28?

Version 2: Ret evt. selv <------

Rem Koden indsættes i arket "IT-Udstyrsark"
Rem Opret selv knap *)
Rem =======================================
Sub udskrivArk()
Dim Dantal, Lantal

    With ActiveWorkbook.Sheets("IT-Udstyrsark")
        Dantal = .Range("B27")                      '<------ kan ændres
        Lantal = .Range("B28")                      '<------ -"-
    End With
       
Rem Udskrivning af 3 ark
    udskriv "Checkliste", 1
    udskriv "arbejdsseddel - Desktop", Dantal
    udskriv "arbejdsseddel - Laptop", Lantal
End Sub
Private Sub udskriv(ark, antal)
    If antal > 0 Then
        ActiveWorkbook.Sheets(ark).Activate
        ActiveSheet.PrintOut Copies:=antal, Collate:=True
    End If
End Sub
Private Sub CommandButton1_Click()  'Knap (kontrolelement) indsat på arket "IT-Udstyrsark"
    udskrivArk
End Sub

Jeg bukker og takker. Det fungerer perfekt. Du får alle points.

Send et svar, supertekst.

Det var godt det lykkedes - selv tak & et svar...