Find unikt værdi, og fremsøg anden celle i samme række

Ja - kan en VBA-løsning anvendes?

Det vil være OK, men jeg har sikkert nogle spørgsmål efterfølgende. Jeg er nemlig ikke super stærk i VBA

Fint - er i gang med et forslag - du spørger blot, når dette er nødvendigt! :-)

Det lyder godt, glæder mig til at høre fra dig :-)

Rem Koden anbringes under Ark1 (højreklik på Ark1 / Vis programkode / indsæt denne kode)
Rem Igangsættes ved Alt+F8 - vælg "Opdater" Afspil eller forbind "Opdater" m/1 knap i Ark1.
Rem =======================================================================================
Dim a1 As Worksheet, a2 As Worksheet
Public Sub opdater()
    Application.ScreenUpdating = False
   
    opsætningAfArk
    traverserArk2
   
    MsgBox ("Opdatering af kommentarer er udført")
    a1.Activate
   
End Sub
Private Sub opsætningAfArk()
    Set a1 = ActiveWorkbook.Sheets("Ark1")
    Set a2 = ActiveWorkbook.Sheets("Ark2")
End Sub
Private Sub traverserArk2()
Dim antalRæk, nr, kom1, kom2, kom3
Dim rækA1
    a2.Activate
   
Rem find antal rækker på Ark2
    antalRæk = ActiveCell.SpecialCells(xlLastCell).Row
   
    For ræk = 1 To antalRæk
Rem hent nr fra kolonne U
        nr = a2.Range("U" & CStr(ræk)).Value
Rem Hvis nr er numerisk - hent kommentarer
        If IsNumeric(nr) = True And nr <> "" Then
            kom1 = a2.Range("E" & CStr(ræk)).Value
            kom2 = a2.Range("F" & CStr(ræk)).Value
            kom3 = a2.Range("G" & CStr(ræk)).Value
           
Rem Find Nr på Ark1
            rækA1 = findNr(nr)
            If rækA1 > 0 Then
                overførKommentarer rækA1, kom1, kom2, kom3
            End If
        End If
    Next ræk
End Sub
Private Function findNr(nr)
    With a1.Range("Q1:Q65000")
        Set c = .Find(nr, LookIn:=xlValues, LookAt:=xlWhole)
        If Not c Is Nothing Then
            findNr = c.Row
            Exit Function
        End If
    End With
    findNr = 0
End Function
Private Sub overførKommentarer(ræk, kom1, kom2, kom3)
    a1.Activate
   
    a1.Range("A" & CStr(ræk)).Value = kom1
    a1.Range("B" & CStr(ræk)).Value = kom2
    a1.Range("C" & CStr(ræk)).Value = kom3
   
    a2.Activate
End Sub

Hej

Den virker bare helt fint. Tak for hjælpen :-)

Bare for at være lidt besværlig. Hvordan ser koden ud hvis Ark1 hedder "DWH liste" og Ark2 hedder "Callback liste"

Fint - du får et svar.... & selv tak

Det er nu ikke så besværligt - juster følgende:

Private Sub opsætningAfArk()
    Set a1 = ActiveWorkbook.Sheets("DWH liste")
    Set a2 = ActiveWorkbook.Sheets("Callback liste")
End Sub

Hvis du vil give point - må du acceptere svaret...