Word til JPG via PowerPoint

Findes følgende i Office 2000?  (anvender selv 2003)

    ActiveDocument.PresentIt

--

Hvad er formålet med det ønskede - hvis man må spørge?

PresentIt findes (jeg kendte den ikke i forvejen), det ser dog ikke ud til at den kan det jeg ønsker. Jeg regner med at man skal bruge noget med CreateObject.

VBA-koden skal gøre:
1) Oprette reference til et powerpointobject
2) Formattere dias til A4-format, stående, evt. ændre marginer
3) Indsætte word-siden
4) gemme jpg-filen på et specificeret sted.

Det er meget muligt det kan gøres uden PowerPoint, men Word kan i hvert fald ikke dirkte gemme i jpg-format.

Formålet:
Ideen er at gemme journalsvar i et PACS (lagersystem til røntgenbilleder og lignende). Konvertering af word til jpg er kun første trin i en længere proces, hvor jpg'en skal pakkes ind i et DICOM-format og have tildelt et accessionnummer og dernæst sendes.

Tak for detaljerne.

Enig - PresentIt er ikke løsningen..

Jeg vil vende tilbage til udfordringen senere. Tror godt det kan lade sig gøre...

Til orientering: Er godt i gang - ser lovende ud...

Her er så lidt inspiration:

Rem Version 1
Rem =========
Rem Koden er placeret i etseparat Word-dokument
Rem Referencen til PP er indsat

Const sti = "C:\Documents and Settings\pb.KHNBPB\Skrivebord\WordJpg\"  'TEST-STI
Const ppNavn = "skabelon.ppt"                                          'PP-SKABELON TEST-NAVN
Dim pp As Object, diasPladsHolderNavn

Const WordDok = "kilde.doc"                                            'WORD-DOK TEST-NAVN
Dim dok As Object, sideNr As Integer, antalSider As Integer
Public Sub startKonvertering()
Rem åbne Word-dokument, der skal konverteres
    Set dok = CreateObject("Word.Application")
    With dok
        .Documents.Open sti & WordDok
       
        antalSider = .ActiveDocument.ActiveWindow.Panes(1).Pages.Count
    End With

Rem Åbn PowerPoint-skabelon
    Set pp = CreateObject("PowerPoint.application")
    pp.Visible = True

    With pp.Presentations
        .Open FileName:=sti + ppNavn
    End With
   
Rem find navnet på pladsholder
    With pp
        For Each c In pp.ActiveWindow.Selection.SlideRange.Shapes
            diasPladsHolderNavn = c.Name
        Next c
    End With
   
Rem kopier de enkelte sider
    For sideNr = 1 To antalSider
        If sideNr = 1 Then
            dok.ActiveDocument.Bookmarks("\page").Select
            dok.Selection.Copy
        Else
            dok.Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Count:=1
            dok.ActiveDocument.Bookmarks("\page").Select
            dok.Selection.Copy
        End If
       
        pp.ActiveWindow.Selection.SlideRange.Shapes(diasPladsHolderNavn).Select
        pp.ActiveWindow.Selection.ShapeRange.TextFrame.TextRange.Characters(Start:=1, Length:=0).Select
        pp.ActiveWindow.View.Paste
       
        gemSomJPG CStr(sideNr)
       
Rem ryd pladsholder
        pp.ActiveWindow.Selection.ShapeRange.TextFrame.TextRange.Select
        pp.ActiveWindow.Selection.TextRange.Text = ""
      Next sideNr

Rem luk object-filer
      pp.ActivePresentation.Close
      pp.Quit
      Set pp = Nothing
     
      dok.ActiveDocument.Close
      dok.Quit
      Set dok = Nothing
     
      MsgBox ("konv. udført")
End Sub
Private Sub gemSomJPG(sideNr)
    pp.ActivePresentation.SaveAs FileName:=sti & "side" & sideNr + ".jpg", FileFormat:=ppSaveAsJPG, EmbedTrueTypeFonts:=msoFalse
End Sub
Private Sub CommandButton1_Click()
    startKonvertering
End Sub

Tak, supertekst for dit store arbejde, jeg arbejder videre med dit forslag.
Husk svar, så får du dine point.

Selv tak - svaret er her..