5000 separate "søg og erstat"

Hej,

Jeg er ikke hundrede på om jeg kan hjælpe og forstår ikke helt dit spørgsmål.

Umiddelbart lyder det som om at C1 skal være lig B1, C2 lig B2 osv. Kan du evt. uddybe.

Hej,

Jeg skal have excel til at søge i kolonne C efter værdien fra celle A1. Denne værdi skal så erstattes med værdien i celle B1.

Det er faktisk det helt samme, som når jeg bruger ctrl+h (søg og erstat)
Jeg skriver søg efter værdien fra celle A1 og erstat alle forekomster i kolonne C med værdien fra celle B1.

Derefter skal det gøres med A2 og B2, A3 og B3 osv.

Problemet er bare at jeg har 5000 forskellige værdier det skal gøres med.

Med VBA skulle det ikke være noget problem - hvis det altså må være det?

Kan alle værdier i C findes i A?

Forslag - VBA-koden anbringes under relevante ark - kan kaldes via Alt+F8 /marker makroen FindOgSøg / afspil Makro

Const startRæk = 1                                  'justeres evt.

Dim antalræk As Long, ræk As Long, Aræk As Long
Sub findOgSøg()
    antalræk = ActiveCell.SpecialCells(xlLastCell).Row
   
    Application.ScreenUpdating = False
   
    For ræk = startRæk To antalræk
        tal = Cells(ræk, 3)                        'hent tal fra kolonne C
       
        Aræk = findTalKolonneA(tal)
        If Aræk > 0 Then
            Cells(ræk, 3) = Cells(Aræk, 2)          'indsæt tal fra kolonne B
        End If
    Next ræk
   
    Application.ScreenUpdating = True
   
    MsgBox "Søg & erstat er afsluttet"
End Sub
Private Function findTalKolonneA(tal)
    With ActiveSheet.Range("A:A")
        Set c = .Find(tal, LookIn:=xlValues, LookAt:=xlWhole)
        If Not c Is Nothing Then
            findTalKolonneA = c.Row
        Else
            findTalKolonneA = 0
        End If
    End With
End Function

Hej supertekst,

Det virkede faktisk præcis, som jeg beskrev det skulle!

Nogle af cellerne i kolonne C indeholder flere numre, som er adskilt af en #
Er det muligt at få den til at se det som flere tal i stedet for bare at se på cellen?

Fx hvis tallet fra celle A1 indgår et sted imellem tallene i kolonne C adskilt af #, erstatter den også det.

Takker for din hjælp!

Ja - det skulle nok være muligt. Prøv at vise, hvordan disse #-celler ser ud.

Rem Version 2
Rem =========
Const startRæk = 2                                  'justeres evt.

Dim antalræk As Long, ræk As Long, Aræk As Long
Sub findOgSøg()
    antalræk = ActiveCell.SpecialCells(xlLastCell).Row
   
    Application.ScreenUpdating = False
   
    For ræk = startRæk To antalræk
        tal = Cells(ræk, 3)                        'hent tal fra kolonne C
       
        If InStr(tal, "#") > 0 Then
            adskilTal tal
        Else
            Aræk = findTalKolonneA(tal)
            If Aræk > 0 Then
                Cells(ræk, 3) = Cells(Aræk, 2)          'indsæt tal fra kolonne B
            End If
        End If
    Next ræk
   
    Application.ScreenUpdating = True
   
    MsgBox "Søg & erstat er afsluttet"
End Sub
Private Function findTalKolonneA(tal)
    With ActiveSheet.Range("A:A")
        Set c = .Find(tal, LookIn:=xlValues, LookAt:=xlWhole)
        If Not c Is Nothing Then
            findTalKolonneA = c.Row
        Else
            findTalKolonneA = 0
        End If
    End With
End Function
Private Sub adskilTal(tal)
Dim flereTal As Variant, f As Byte
    flereTal = Split(tal, "#")
   
    For f = 0 To UBound(flereTal)
        Aræk = findTalKolonneA(flereTal(f))
        If Aræk > 0 Then
            flereTal(f) = Cells(Aræk, 2)
        End If
    Next f
    Cells(ræk, 3) = Join(flereTal, "#")
End Sub

Det får jeg ikke helt til at virke.
Her er et eksempel på hvordan det kunne se ud:
http://spreadsheets.google.com/ccc?key=tKVzdDr_8xgkKkS1c4dI4BQ&hl=en#gid=0

hvad er det, der ikke virker?

Den erstatter ikke ind i mellem #
fx bliver 1062 ikke erstattet med 2319 i celle C3

Det sker nu alligevel, når jeg kører VERSION 2 (#7 d.d.)

FØR
500535    500598    1062#1069#1124#1138#1164#1171#1323#1363#1365#1387#1435#1453#1464#1466#1468#1471#1527#1528#3676#500056#500057#500197#500484#500496#5441#5518       
1062    2319    500535#500715       
3574    8937    500535#500716       
500057    88736    500717       
               
EFTER                       
500535    500598    2319#1069#1124#1138#1164#1171#1323#1363#1365#1387#1435#1453#1464#1466#1468#1471#1527#1528#3676#500056#88736#500197#500484#500496#5441#5518       
1062    2319    500598#500715       
3574    8937    500598#500716       
500057    88736    500717

Nu fik jeg det til at virke!
Det var fordi at den kun søger i rækker der står nedenfor.
Det fik jeg løst ved at forskyde kolonne C, så værdierne kommer under de værdier der ligger i kolonne A og B

Mange tak for hjælpen!

Ok - og selv tak..