HVIS-formel skal kun udføres, betinget af værdien af anden udregning.

=HVIS(L1<R1;"L";HVIS(L1>R1;HVIS(L2>0;"L";"Å")))
eller
=HVIS(L1>R1;HVIS(L2>0;"L";"Å");"L")

Hvis L1<R1, skal resultatet være "L".

=HVIS(L1<R1;"L";"din formel")

Så har du en formel indsat: Hvis L1>R1
HVIS(L2>0;"L";"Å") som giver "L" Hvis L2>0 hvis L2<0 giver den "Å"

1. Hvis L1<R1 = L
2. Hvis ikke L1<R1 så kikkes på L2
3. Hvis L2>0 = L
4. Hvis L2<0 = Å
=HVIS(L1<R1;"L";HVIS(L2>0;"L";"Å"))

Hej vejmand

Din formel virker fint, men jeg skal have sat den ind til sidst i en lang formel.
Jeg troede, at jeg selv kunne få det til at virke, men den kommer hele tiden ud med "FALSK".
Den formel du har lavet, står til sidst i den lange formel.
Jeg har stadig "L" stående efter L1<R1. Ved godt, at det vist ikke skal stå  der, men har ladet det stå, for at præciserer hvad der skal sket, hvis L1<R1.

=HVIS(OG(V47=0;W47=0);TÆL(BQ7:BQ17)-$Y$47=0;HVIS(AA47>0;HVIS(L1<R1;"L";HVIS(L1>R1;HVIS(L2>0;"L";"Å")))))

Laugesen

Denne del forstår jeg ikke: -$Y$47=0

Det er en kontrol.
Det tælles celler med positiv værdi i BQ7:BQ17 og antallet skal være lige med værdien i Y47.

Sorry, jeg forstår den ikke.....
Jeg forstår ikke det minus-tegn foran $Y$47=0

Hej igen

Jeg blev hele tiden logget af siden i nat. Håber det går bedre nu.

Det er en kontrol af, at en handling er udført i mit ark.

Antallet af celler med positiv værdi tælles i BQ7:BQ17 og resultatet skal være lig med værdien af Y47.

Så det er en udregning af:
Antal celler med pos. værdi(BQ7:BQ17) minus (Y47),
hvis resultatet er lig 0 er udsagnet SAND.

Okay, jeg er først tilbage sent i aften. Så vil jeg kigge på det igen, hvis ikke andre har løst gåden inden.

Din formel er usammenhængende. Husk at der er 3 værdier i enhver HVIS()-funktion:
HVIS(Betingelsen; hvis SAND; hvis FALSK)
Du mangler indtil flere af disse værdier, og hver gang din formel rammer en af disse, vil der blive vist resultatet FALSK, da der jo ikke er noget at vise.

Prøv at beskrive hvad det er, du ønsker formlen skal vise - med ganske almindeliug tekst.

Ja, det er rigtigt at der mangler nogle elementer i formlen, jeg har rette den til.
Det den skal tjekke, er nogle forskellige udregninger i hele mit ark.
Dette for, at arket har en status efter månedens afslutning, enten åben eller lukket.

Hvis alle udsagn er sande, kan arket for den pågældende måned have en status lukket "L".

Opdeling at min formel og en beskrivelse af hvad den skal udfører:

HVIS(OG(V47=0;W47=0);
-Hvis V47 og W47 begge er lig med 0, skal udsagnet være "L", ellers "Å"

HVIS(TÆL(BQ7:BQ17)-$Y$47=0;
-Hvis antallet af celler med positiv værdi i BQ7:BQ17 er det samme som værdien i Y47, skal udsagnet være "L", ellers "Å"

HVIS(AA47>0;
-Hvis værdien af AA47>0, skal udsagnet være "L", ellers "Å"

HVIS(L1>R1;HVIS(L2>0;"L";"Å"))))))
-Hvis L1>R1 og L2>0, skal udsagnet være "L", ellers "Å".
Men denne udregning skal kun foretages hvis L1>R1, hvis dette ikke er tilfældet, skal udsagnet være "L", eller også skal denne sidst del af hele formlen bare ikke udføres (altså hvis L1<L2).

Laugesen

Et gæt:
=HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0;HVIS(L1>R1;OG(L1>R1;L2>0)));"L";"Å")

Hej Morten

Jeg har prøvet formlen, men desværre virker den ikke helt efter hensigten.

Den melder ikke FALSK, men "Å" selvom alle kriterier er opfyldt og den dermed skal melde "L".
Forstår ikke helt hvorfor L1>R1 skal komme to gange efter hinanden, adskilt af "OG", er det korrekt?

erikjuul har skrevet, at der mangler nogle "HVIS" i formlen.

Har selv indsat "HVIS" før "TÆL(BQ7:BQ17)-$Y$47=0". Ved ikke om det er rigtigt ?

Laugesen

Det er nok fordi jeg ikke forstår:
"Men denne udregning skal kun foretages hvis L1>R1, hvis dette ikke er tilfældet, skal udsagnet være "L", eller også skal denne sidst del af hele formlen bare ikke udføres (altså hvis L1<L2)."

Jeg ser #10
Som der er 6 udsagn, når alle er SAND = L
Hvis bare et udsagn er FALSK = Å

=OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0;L1>R1;L2>0)
giver SAND når alle er sande.

Sat i en HVIS formel for at få L eller Å
=HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0;L1>R1;L2>0);"L";"Å")

Ja, det er korrekt med de 6 udsagn:

Når alle er SAND = L
Hvis bare et udsagn er FALSK = Å

#13
Nederst?

Formlen virker hvis: (L1>R1;L2>0) dette giver "L"
Men hvis (L1<R1), er resultatet "Å", og det er meningen at det skal være "L".

???

# 14
Ja, det er korrekt med de 6 udsagn:

Når alle er SAND = L
Hvis bare et udsagn er FALSK = Å

=HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0;L1>R1;L2>0);"L";"Å")

HVIS:
1. V47=0
2. W47=0
3. TÆL(BQ7:BQ17)-$Y$47
4. AA47>0
5. L1>R1
6. L2>0
Alle er SAND skrives L
Hvis en eller flere er FALSK skrives Å

#16
Virker hvis: (L1>R1) dette giver "L" (OK)
Men hvis:  (L1<R1), er resultatet "Å" (OK),
og det er meningen at det skal være "L". (Modsigelse, kan ikke give L i begge tilfælde)

Ellers skift L1>R1 ud med L1<>R1
L1 er mindre eller større end R1 = L
L1=R1 = Å

Her skal alle 6 udsag vare sande, og virker
=HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0;L1>R1;L2>0);"L";"Å")

Skal denne 'Overstyres' af L1<R1 ?

Som du starter med i #0
"Jeg har følgende formel der ikke skal udføres, hvis L1<R1."

Hvis L1<R1 skrives "L" (Slut på 1. HVIS formel)
Ellers skal alle 6 udsagn vare SAND og der skrives "L"
Hvis en eller flere er FALSK skrives "Å" (Slut på 2. HVIS formel)

=HVIS(L1<R1;"L";HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0;L1>R1;L2>0);"L";"Å"))

Alle 6 udsagn skal være sande?
=HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0;L1>R1;L2>0);"L";"Å")

Ja, det er korrekt og det skal give "L".
Den formel virker med alle de 6 udsagn.

Skal denne 'overstyres' af L1<R1 ?
Nej, (L1<R1) skal ikke overstyre hele formlen, det er kun den sidste del af formlen den skal overstyre.

Hvis den overstyrer hele formlen, så sker der det, at hvis (L1<R1), så vil resultatet blive "L", ligegyldigt om et af de 5 andre udsagn ikke er sande. Det er ikke meningen.

Vejmand har lavet den del af formlen, og her overstyrer (L1<R1).
=HVIS(L1<R1;"L";HVIS(L1>R1;HVIS(L2>0;"L";"Å")))

Den virker når jeg bruger den alene, men jeg kan ikke få den til at virke, når jeg sætter den bagerste i hele formlen


Laugesen

=HVIS(L1<R1;"L";HVIS(L1>R1;HVIS(L2>0;"L";"Å")))

"erikjuul har skrevet, at der mangler nogle "HVIS" i formlen."

Hvis L1=R1 retuneres FALSK
Hvis det kan forekomme? =HVIS(L1<R1;"L";HVIS(L1>R1;HVIS(L2>0;"L";"Å");"Lig med"))
"Lig med" kan erstattes med noget andet.

Hvis du vil sætte den ind i den anden formel:

F.eks. =HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0;L1>R1;L2>0);"L";"Å")
Så prøv dette: Kopier den formlen du vil sætte ind (uden = tegnet)
Klik på cellen med den formel du vil sætte ind i.
På formelinjen klikker du på OG i formlen,
klik derefter på knappen fx lige foran =tegnet, så kan du se de 6 udsagn.
Indsæt din formel i stedet for det udsagn den skal 'overstyre'

Håber det er til at forstå :-)

Vent lidt med overstående, det er hvis noget vrøvl :-),
Vender tilbage senere, skal på job.
Vi giver ikke op i nu :-)

Hej Morten

"erikjuul har skrevet, at der mangler nogle "HVIS" i formlen."

Men det er i min lange formel han mente det, ikke i den som vejmand har lavet, #1
Begge formler fungerer hver for sig

Så det er følgende to formler der skal fungere sammen:

=HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0);"L";"Å")

=HVIS(L1<R1;"L";HVIS(L1>R1;HVIS(L2>0;"L";"Å")))

Hvor den sidste formel skal sættes til sidst i den lange formel.

Eksempler:
Hvis alle udsagn i den lange formel er sande og (L1<R1), resultat "L"

Hvis bare ét udsagn i den lange formel er falsk og (L1<R1), resultat "Å"

Hvis alle udsagn i den lange formel er sande og (L1>R1) og (L2>0), resultat "L"

Hvis alle udsagn i den lange formel er sande og (L1>R1) og (L2<0), resultat "Å"

Hvis bare ét udsagn i den lange formel er falsk og (L1>R1) og (L2>0), resultat "Å"

Laugesen

Test denne:
=HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0);HVIS(L1<R1;"L";HVIS(L1>R1;HVIS(L2>0;"L";"Å")));"Å")

Det virker som det skal, formlen fungerer helt efter hensigt nu.
Super godt og mange mange tak for hjælpen.

Jeg vil gerne giver dig flere point end de 30, du har brugt meget tid på denne besværlige formel.
Kan man gå ind og redigere i antal points, som man satte spørgsmålet til ved oprettelse?

Laugesen

Det var godt :-)
Velbekomme.
http://www.eksperten.dk/faq#faq-5-3

"erikjuul har skrevet, at der mangler nogle "HVIS" i formlen."

HVIS(1-logisk_test,2- [værdi_hvis_sand], 3-[værdi_hvis_falsk])
1- Hvis et eller andet er rigtig -->
2- Så gør en ting -->
3- Ellers gør en anden ting.

=HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0);HVIS(L1<R1;"L";HVIS(L1>R1;HVIS(L2>0;"L";"Å")));"Å")

Mangler en 3-er?
Test: L1 =0, R2 =0,  V47 =0, W47 =0, Y47 =0 og AA47 =1 Resultat: FALSK
Hvis dette er et problem skal du bare finde hvor 3-eren manger ;-)

Mangler en 3-er?
Test: L1 =0, R2 =0,  V47 =0, W47 =0, Y47 =0 og AA47 =1 Resultat: FALSK

Som jeg forstår det, skal der i min formel ikke bare stå fx. (>),men (>=), for at undgå, at der kommer en situation, hvor der mangler en 3´er-[værdi_hvis_falsk]

Nej. :-)

Test: L1 =0, R2 =0,  V47 =0, W47 =0, Y47 =0 og AA47 =1 Resultat: FALSK

=HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0);HVIS(L1<R1;"L";HVIS(L1>R1;HVIS(L2>0;"L";"Å");"Her: FALSK kommer hvis der ikke står noget"));"Å")

=HVIS(OG(V47=0;W47=0;TÆL(BQ7:BQ17)-$Y$47=0;AA47>0);HVIS(L1<R1;"L";HVIS(L1>R1;HVIS(L2>0;"L";"Å")));"Å")
                      I
              Mangler en 3-er?

Men du har ret, hvis der i bare står (>=) i stedet for (>), så retuneres denne manglende 3-er ikke.

Ja, nu forstår jeg hvor det præcist er i formlen.
Jeg tror ikke det umiddelbart bliver et problem, men jeg har indsat (>=) for at sikre mig, at det ikke sker.

Endnu en gang tak for din hjælp, der er rigtig godt at min formel fungerer nu.

Jeg opretter et ekstra spørgsmål for tildeling at ekstra point til dig.

God weekend

Laugesen