Programmering af BAT fil

du skal via vbs for at få ugedage med.

Alternativt kunne ugedagen tilføjes i efterfølgende opgavestyring via lidt VBA - eller evt. samle alt i VBA.

Hvor skal ugedagen placeres i filnavnet?

f.eks:

Const filDerKopieres = "Filen.txt"
Dim sti As String, fraFil As String, tilFil As String
Dim ugedag As String
Private Sub Workbook_Open()
    ugedag = WeekdayName(Weekday(Date, vbMonday))
    sti = ActiveWorkbook.Path
   
    fraFil = sti & "\" & filDerKopieres
    tilFil = sti & "\" & "kopiAfFilen" & Format(Now, "dd-mm-yy") & "_" & ugedag

    FileCopy fraFil, tilFil
End Sub

For ikke at lave lort i nogen af vores ting tro jeg den rigtige løsning vil være at lave en VBA som kan sætte Dags navnet sidst i enden på alle filerne i en mappe hvor CSV filerne ligger.
Den skal altså ikke lave en kopi af filerne, men kun sætte Dagen ind.
Hvordan vil en VBA se ud som sætter Dagen på alle filerne i en mappe?

Så skal der vel også tages højde for de filer som på sigt har fået tilsat ugedag?

Hvis det er nemt at gøre vil det være fint. Men ellers så vil det godt kunne fungere med at den sætter ugedag på alle filer.
Det er en speciel mappe som de vil ligge i, og den vil blive tømt når man har kørt den rapport som du hjalp med at lave i sidste uge.

En helt anden vej er at ændret det i Windows' regionale indstillinger. Her kan du sætte ugedagen på.

Dim ugedag As String
Dim sti As String, filnavn As String, linje As String, tabel As Variant
Dim dato As Date, ptNavn As String, nytNavn As String
Public Sub tilsætUgedag()
    sti = ActiveWorkbook.Path & "\"
   
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(sti)
    Set fc = f.Files
   
Rem traverser den aktuelle mappe - find filer med extension .dat
    For Each f1 In fc
        filnavn = LCase(f1.Name)
        If LCase(Right(filnavn, 3)) <> "dag" And InStr(LCase(filnavn), "tilsætugedag") = 0 Then
            dato = Right(filnavn, 8)
            ugedag = WeekdayName(Weekday(dato, vbMonday))
           
            ptNavn = sti & filnavn: nytNavn = sti & filnavn & ugedag
            Name ptNavn As nytNavn
        End If
    Next
   
    MsgBox "Gennemløb afsluttet"
End Sub

Kan ikke helt få den til at fungere. Men kan også se i den grønne tekst at der står at at den finder filer med extension .dat
Det er CSV filer som der skal laves om på.

Når jeg køre makroen er det denne linie som bliver GUL:

dato = Right(filnavn, 8)

Og når jeg holder musen henover står der følgende:

Dato = 00:00:00
Filnavn = Kostrapport_2013-06-05

Er det fordi den ikke kan genkende datoen?

Hvis du har mulighed for at sende et lille udvalg af filerne - hvis flere typer - så instruks herom.

Const filDataSti = "C:\Users\peter\Desktop\Klas\"  '<---- justeres
Dim ugedag As String
Dim sti As String, filnavn As String
Dim filDato As String, dato As Date, ptNavn As String, nytNavn As String
Public Sub tilsætUgedag()
    sti = filDataSti
   
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(sti)
    Set fc = f.Files
   
Rem traverser den aktuelle mappe - find filer med extension .dat
    For Each f1 In fc
        filnavn = Replace(LCase(f1.Name), ".csv", "")
       
        If LCase(Right(filnavn, 3)) <> "dag" And InStr(LCase(filnavn), "tilsætugedag") = 0 Then
            filDato = Right(filnavn, 10)
            ugedag = WeekdayName(Weekday(filDato, vbMonday))
           
            ptNavn = sti & filnavn & ".csv": nytNavn = sti & filnavn & "_" & ugedag & ".csv"
            Name ptNavn As nytNavn
        End If
    Next
   
    MsgBox "Gennemløb afsluttet"
End Sub

Et svar