søg med lopslag

Du henviser i alle formlerne til A1 på grund af $-tegnene

LOPSLAG henter den første fundne.

Når du kopierer formlen, ændre opslagsområdet sig.

1.
opslagsområde 'Ark2'!A1:C10 Ole findes i A1
2.
opslagsområde 'Ark2'!A2:C11 Ole findes i A4
3.
opslagsområde 'Ark2'!A3:C13 Ole findes i A4
4.
opslagsområde 'Ark2'!A4:C14 Ole findes i A4
5.
opslagsområde 'Ark2'!A5:C15 Ole findes i A5 ... osv

Super text: Ja jeg bruger kun A1  som søgefelt
Store Morten: Navnene kommer i denne rækkefølge:1-10 ole ,finn,per ,ole,fin,per,ole finn.per,ole
Ole forekommer kun 1,4,7,10
når jeg låser opslagsområdet med $ i A1 og C10 så kommer kun det første fundne =1
Hvordan får jeg den til at vise at ole kun findes i 1,4,7,10 ?

Indsæt denne formel i B1 og kopier ned til B10

=HVIS(INDEKS(Ark2!$A$1:$A$10;RÆKKE())=$A$1;INDEKS(Ark2!$B$1:$B$10;RÆKKE());"")

Jens: er der nogen mulighed for at resultatet kommer lige under  hinanden , i stedet for på linie 1,4 7,10 ?

Så tror jeg det er lettere med en makro:

Sub InsertNumbers()
Dim x, y As Integer
Sheets("Ark1").Range("B1:B10").ClearContents
y = 1
For x = 1 To 10
If Sheets("Ark2").Cells(x, 1) = Sheets("Ark1").Range("A1") Then
Sheets("Ark1").Cells(y, 2) = Sheets("Ark2").Cells(x, 2)
y = y + 1
End If
Next
End Sub

Jens : hvor skal koden indsættes ark 1 eller2

Prøv med denne makro i stedet. Den kører automatisk, når der skrives i A1, hvis du højreklikker på Ark1 fanebladet og indsætter den under vis koder. Bemærk at der skelnes mellem store og små bogstaver.

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("A1")) Is Nothing Then
Dim x, y, z As Integer
z = Application.WorksheetFunction.CountA(Sheets("Ark2").Range("A:A"))
Sheets("Ark1").Range("B:B").ClearContents
y = 1
For x = 1 To z
If Sheets("Ark2").Cells(x, 1) = Sheets("Ark1").Range("A1") Then
Sheets("Ark1").Cells(y, 2) = Sheets("Ark2").Cells(x, 2)
y = y + 1
End If
Next
End If
End Sub

Jens:
Virker perfekt når der kun er 1 ting at referer til , men i virkligheden er der 10 kolonner der skal vises i ark 1 oplysningerne  ligger i Ark2 eks. B1 til K500
kan jeg få dette til at virke ved at udvide din formel ?

Makroen skelner ikke længere mellem store og små bogstaver

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("A1")) Is Nothing Then
Dim x, y, z, a As Integer
z = Application.WorksheetFunction.CountA(Sheets("Ark2").Range("A:A"))
Sheets("Ark1").Range("B:K").ClearContents
y = 1
For x = 1 To z
If UCase(Sheets("Ark2").Cells(x, 1)) = UCase(Sheets("Ark1").Range("A1")) Then
Worksheets("Ark2").Range("B" & x & ":K" & x).Copy _
    Destination:=Worksheets("Ark1").Range("B" & y)
y = y + 1
End If
Next
End If
End Sub

ok Jens nu er det helt perfekt lav lige et svar

Jens din macro virker perfekt, men hvis du vil forklare hvad der sker i hver linie , så også jeg forstår det ville dette være en stor hjælp

Her er makroen igen med kommentarer. Hvis du indsætter den, vil kommentarerne vises i grønt.

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("A1")) Is Nothing Then ' starter makroen, når der skrives i A1
Dim x, y, z, a As Integer ' variablerne defineres som integer
z = Application.WorksheetFunction.CountA(Sheets("Ark2").Range("A:A")) ' der tælles linier i kolonne A (Ark2)
Sheets("Ark1").Range("B:K").ClearContents ' de gamle data på Ark1 slettes
y = 1 ' y angiver linien der skal skrives i på Ark1
For x = 1 To z ' linierne 1 til z (sidste linie) testes. x angiver linien der testes
If UCase(Sheets("Ark2").Cells(x, 1)) = UCase(Sheets("Ark1").Range("A1")) Then ' Hvis celle Ax (Ark2) = A1 (Ark1) så:
Worksheets("Ark2").Range("B" & x & ":K" & x).Copy _
    Destination:=Worksheets("Sheet1").Range("B" & y) ' kopiering af Bx:Kx (Ark2) til By:Ky (Ark1)
y = y + 1 'y forøges med 1
End If
Next 'tilbage i sløjfen til sidste linie nås
End If
End Sub