Udregne om datoformat er mere end 2 år siden

Hvis datoen havde været formateret som dato ville det kunne have været klaret med denne formel:

=IF(A1<EOMONTH(TODAY();-25)+DAY(TODAY());"Ældre end 2 år";"")

Men da du har datoen formateret som tekst bliver det lidt mere kompliceret:

=IF(DATE(RIGHT(A1;4);MID(A1;4;2);LEFT(A1;2))<EOMONTH(TODAY();-25)+DAY(TODAY());"Ældre end 2 år";"")

Dansk oversættelse:

=HVIS(A1<SLUT.PÅ.MÅNED(IDAG();-25)+DAG(IDAG());"Ældre end 2 år";"")

=HVIS(DATO(HØJRE(A1;4);MIDT(A1;4;2);VENSTRE(A1;2))<SLUT.PÅ.MÅNED(IDAG();-25)+DAG(IDAG());"Ældre end 2 år";"")

Denne her burde også kunne klare tekstformat dato!

=HVIS(A1<=EDATO(IDAG();-24);"Ældre end 2 år";"Under 2 år")

=IF(A1<=EDATE(TODAY();-24);"Ældre end 2 år";"Under 2 år")

Ebea, det er korrekt at EDATE virker på tekstformat, men du bliver nødt til at vende formelen om så du ikke sammenligner tekst med dato:
=IF(EDATE(A1;24)<=TODAY();"Ældre end 2 år";"Under 2 år")

=HVIS(EDATO(A1;24)<=IDAG();"Ældre end 2 år";"Under 2 år")

Må jeg spørge Jens48; har du prøvet formlen?

De giver samme resultat, både med, og uden Tekst formatering.

Ja, både din og min. Din virker ikke, fordi du spørger om en tekst (A1) er lig med eller mindre end en dato (EDATE(TODAY();-24))

Tusind tak for jeres svar!

Hvis jeg skal regne ud om det er mere/mindre end to år i forhold til d. 3.marts.16 og ikke dags dato, hvordan skal den så se ud?

Det letteste vil være at skrive datoen i en celle f. eks. B1. Så vil Formelen se således ud:

=IF(EDATE(A1;24)<=B1;"Ældre end 2 år";"Under 2 år")

=HVIS(EDATO(A1;24)<=B1;"Ældre end 2 år";"Under 2 år")

Alternativet er at skrive datoen ind i formelen, selv om det ikke giver samme fleksibilitet:

=IF(EDATE(A1;24)<=DATE(2016;3;3);"Ældre end 2 år";"Under 2 år")

=HVIS(EDATO(A1;24)<=DATO(2016;3;3);"Ældre end 2 år";"Under 2 år")

=HVIS($A1<=EDATO(B1;-24);"Ældre end 2 år";"Under 2 år")

#5 - Til Jens48 - Det er lidt "mærkeligt", for formlen virker hos mig, formateret både som tekst, og dato format.
Og ovenstående virker også: -  Selvom den "er vendt om"

Så hvorfor min angivne ikke virker hos dig, kan jeg ikke forklare.

Til ebea: Hos mig skriver din formel "Under 2 år", også når det er over to år. Jeg bruger Excel 2010

Jens - Så er mysteriet da endnu større, for jeg bruger også Excel 2010. jeg har prøvet at indsætte din formel også, og den virker fuldstændig som mit eget eks.

Jeg vil da gerne sende dig eksemplet, i min opstilling (kig under profil for email).

Der er vist ikke tale om noget mysterium her, men derimod om følgende kendsgerning:

number < string < Boolean

Prøv:

=9,99999999999999E+307 < "A"

="Z" < SAND

#11 - Hvor vil du hen med det??

#1 - jeg håber at du fik et svar du kunne bruge, ud fra forslagene der var. Og "fnidderen" efterfølgende, ikke forvirrede dig.

#11 - Jeg kan ikke se overhovedet, hvor du vil hen med dit indlæg, og med din første formel i dette, (som er det højeste tilladte tal at angive i en celle). Og din formel med "Z" er (hvis du tilføjer resterende værdier) beregnet til at finde sidste tekst i et givent område.

Men det er da fint med mig, hvis du gerne vil lege overdommer.

For mig, er det som er essensen, at spørgeren får et svar og en løsning på det som spørges om.
Og da Excel kan komme med mange løsninger på samme spørgsmål, så ser jeg ikke det ene mere rigtigt, end det andet, så længe at løsningen er korrekt, ud fra det spurgte.

Men hvis du gerne vil have et ekstra point for dit bidrag, skal jeg da gerne aflevere nogle af mine til dig.

Jeg håber det her virker.

https://www.dropbox.com/s/lpo9kohcd6bf19c/No_Mysteri.xlsx?dl=0