Udfordring :-) - Gruppering af tilfældige tal

Og det skal vaere i VB??

Ikke nødvendigvis, hvis alternativet er "almindelige" Excel formler.
Var det din tanke ?

en rutine: læg alle tal i en tekststreng
fjern det højeste (og husk det og forkort tekststreng left() og right() så dit tal er væk)
træk dit tal fra 8, og du har en diff - find det første tal med diff
hvis sum af dem giver 8, så udskriv og forfra - ellers fratræk 1 fra diff osv - der skal loopes, så du i værste fald opfanger 1+1+1+1+1+1+1+1

dvs hver tal, du finder og vælger fjernes i tekststreng, så den bliver kortere efterfølgende loop

Det skal nok tages højde for at restgruppen kan ende med en sum større end 8 (3 + 3 +3)

#4 og det stopper så også loop, tak for info

når koden er gennemtænkt, så er det nok http://people.cs.aau.dk/~normark/c-prog-06/html/notes/functions_themes-rec-fu-sec.html

Løsningen kan afhænge af i hvilken rækkefølge man tager tallene.

Eksempel:
4 3 3 3 3 2 2

Hvis man tager grupper med 4 først (som du skriver), vil man først tage (4,2,2) og så ende med (3,3,3,3)=12 i rest.

Hvis man tager 3 først (som er de "svære" at komme af med), vil man tage (3,3,2) og (3,3,2) og ende med (4) som rest.

Kan du bekræfte, at det er det først du ønsker - altså at der skal tages grupper fra startende med det/de størst mulige tal?

Tallene kommer i tilfældig rækkefølge men må gerne sorteres.  Sum vil som nævnt aldrig overstige 288

ud fra:

De skal nu grupperes, så hver gruppe giver 8
4+4 = 8
4+4 = 8
osv. til 4 ikke optræder mere

så tages de største tal først.

Rækkefølgen betyder ikke noget, så det afgørende er bare hvor mange du har af hver. I dit eksempel har du 2x1,5x2,4x3 og 5x4 = { 2,5,4,5 }.

Du fjerner
4 4
4 4
1 3 4
2 3 3
1 2 2 3
og ender med at have
2x2 tilbage.

Kode:
Sub test()
    Dim mycombi As Variant
    Dim combis As Variant
    Dim i As Integer
   
    mycombi = [ { 2,5,4,5 } ]
    combis = [ { 0,0,0,2; 1,0,1,1; 0,2,0,1; 2,1,0,1; 4,0,0,1; 0,1,2,0; 2,0,2,0; 1,2,1,0; 3,1,1,0; 5,0,1,0; 0,4,0,0; 2,3,0,0; 4,2,0,0; 6,1,0,0; 8,0,0,0 } ]

    s = "Start: " & printCombi(mycombi) & vbNewLine
    For i = 1 To UBound(combis, 1)
        Do While foundCombi(i, combis, mycombi)
            s = s & "Fjernet: " & popCombi(i, combis, mycombi) & vbNewLine
        Loop
    Next i
    s = s & "Rest: " & printCombi(mycombi)
    MsgBox s
End Sub

Function foundCombi(n As Integer, combis As Variant, mycombi As Variant) As Boolean
    Dim i As Integer
   
    foundCombi = True
   
    For i = 1 To UBound(combis, 2)
        If mycombi(i) < combis(n, i) Then
            foundCombi = False
            Exit For
        End If
    Next i
End Function

Function popCombi(n As Integer, combis As Variant, ByRef mycombi As Variant) As String
    Dim i As Integer
   
    popCombi = ""
   
    For i = 1 To UBound(combis, 2)
        mycombi(i) = mycombi(i) - combis(n, i)
        For j = 1 To combis(n, i)
            popCombi = popCombi & " " & i
        Next j
    Next i
End Function
Function printCombi(mycombi As Variant) As String
    Dim i As Integer
   
    printCombi = ""
    For i = 1 To UBound(mycombi)
        printCombi = printCombi & i & ": " & mycombi(i) & " "
    Next i
End Function