Compare af data

du vil altså kunne sammenligne 2 poster og vise de kolonner, somer forskellige? Er det korrekt forstået?

Ja er det.

Denne funktion sammenligner 2 poster og udskriver en msgbox med de felter, som er forskellige:

Public Function CompareRecords(ID1 As Long, ID2 As Long)
    Dim rs1 As DAO.Recordset
    Dim rs2 As DAO.Recordset
    Dim Besked As String, n As Byte
    Set rs1 = CurrentDb.OpenRecordset("Select * From [DinTabel] Where ID = " & ID1, dbOpenSnapshot)
    Set rs2 = CurrentDb.OpenRecordset("Select * From [DinTabel] Where ID = " & ID2, dbOpenSnapshot)
    For n = 0 To rs1.Fields.Count - 1
        If rs1(n) <> rs2(n) Then
            Besked = Besked & rs1(n).Name & " indeholder værdierne " & rs1(n) & " og " & rs2(n) & vbNewLine
        End If
    Next n
    MsgBox Besked
    rs1.Close
    rs2.Close
    Set rs1 = Nothing
    Set rs2 = Nothing
End Function

Funktionen skal selvfølgelig tilpasses din tabel og dine nøglefelter.
Edvidere forudsætter den at ID er primærnøglen (eller i hvert fald unik)

ID erstattes med dit nøglefelt
[DinTabel] erstattes med tabelnavnet

Er du med på hvordan du bruger funktionen?

Msgbox("Diff = " & Dlookup("komponenter", "tblkomponenter", "ID = " & InputBox("Indast start",,"")) - Dlookup("komponenter", "tblkomponenter", "ID = " & InputBox("Indast slut",,""))  )

You can place this in the on click event for a buton on a form

Via Visual Basic right?

Men funktionen skal køres via en knap man trykker på og den skal hente de 2 id´er fra to felter.

Så er i gang med at prøve at lave den om så den virker.

You will need to alter some of the names

Dlookup("komponenter", "tblkomponenter", "ID =

komponenter = name of field you want to compare
tblkomponenter = name of table
ID = the field containing number you want to compare

ok, det er klart, at den skal tilpasses. På knappens Click-event, kan du f.eks. skrive:

Private Sub cmdFindForskelle_Click()
  Call CompareRecords(Me!ID1, Me!ID2)
End sub

Endvidere bør man også udskrive en besked, hvis der slet ikke er nogle forskelle (hvis dette overhovedet kan forkomme?) Det kan løses ved at lave den sidste del af funktionen således:
...
Next n
    If Len(Besked) = 0 then
      msgbox "Der er ingen forskelle!", vbinformation
    else
      MsgBox Besked
    endif
    rs1.Close
    rs2.Close
    Set rs1 = Nothing
    Set rs2 = Nothing
End Function

Og du er selvfølgelig med på, at du skal have en reference til DAO!?

Næææ... faktisk ikke :)

hvilken version af Access bruger du?

Hvis du brugfer Access 97, skal du ikke spekulere på det.
Hvir du bruger en senere version, skal du (fra VBA-editoren) aktivere menuen Tools->References og kontrollere at der er et kryds i "Microsoft DAO 3.x Object Library". Hvis der ikke er, skal du finde den på listen og sætte kryds i den.

Well, jeg er lige på vej til en kunde, men vil checke om ½-1 times tid igen, hvis du skulle have nogle spørgsmål....

Ahh.. okay :)
Men den melder fejl når jeg trykker på knappen. Den siger Microsoft Access cant find the field 'ID1' referred to in your expression.
Det er i Call'en. Altså:

Private Sub cmdFindForskelle_Click()
  Call CompareRecords(Me!ID1, Me!ID2)
End sub

cc2000>have you tried my soultion?

Terry no. But i can try. :)

Terry...
name of field you want to compare <--- its not a static value so i cant use your solution, if i read it right what you have written.

Thomas... jeg har prøvet at ændre ID1 og ID2 til henholdsvis Soeg og Compare som mine felter hedder. Så siger den Type mismatch.

Are yousaying that there is more than one field you want to compare ?

Terry... yeah... there is about 20-30 fields.

OK! Hard to see from your question!

Yeah... sorry :)

Har du prøvet:
Call CompareRecords(Me!Soeg, Me!Compare)

Hi Terry->
Hvis du læser mit første indlæg (27/05-2002 08:25:56) så fremgår det heraf og af cc2000's efterfølgende svar :o)

Jups... type mismatch

kan du prøve at indsætte funktioenen som den ser ud hos dig?

og hvor stiller Access sig, når den kommer med den fejl? Hvilken linie/ord er markeret?

Public Function CompareRecords(ID1 As Long, ID2 As Long)
    Dim rs1 As DAO.Recordset
    Dim rs2 As DAO.Recordset
    Dim Besked As String, n As Byte
    Set rs1 = CurrentDb.OpenRecordset("Select * From OLS Where CODE = " & ID1, dbOpenSnapshot)
    Set rs2 = CurrentDb.OpenRecordset("Select * From OLS Where CODE = " & ID2, dbOpenSnapshot)
    For n = 0 To rs1.Fields.Count - 1
        If rs1(n) <> rs2(n) Then
            Besked = Besked & rs1(n).Name & " indeholder værdierne " & rs1(n) & " og " & rs2(n) & vbNewLine
        End If
    Next n
    MsgBox Besked
    rs1.Close
    rs2.Close
    Set rs1 = Nothing
    Set rs2 = Nothing
End Function

Private Sub Compare_Knap_Click()
    Call CompareRecords(Me!Soeg, Me!Compare)
End Sub

Call CompareRecords(Me!Soeg, Me!Compare)
den linje

undskyld det er uden Call ordet egentlig :)

hmm.. underligt... mente det var uden call ordet... det er faktisk hele sætningen endda. Mig og min hukommelse ;)

øhh, hvad mener du? Markere Access hele sætningen?

Hvor har du funktionen liggende? I et modul? Eller i formularen?

Access markerer Call CompareRecords(Me!Soeg, Me!Compare)
Altså gennem Microsoft Visual Basic.
Det ligger i formularen.

Prøv at vælge menuen Debug->Compile&#8230;. Og se om den kommer med en fejl?

Debug->Compile...

ingen fejl

Prøv at omdøbe feltet Compare til f.eks. txtCompare.
Og derefter koden:
Call CompareRecords(Me!Soeg, Me!txtCompare)

Compare er måske et reserveret ord!

har prøvet at omdøbe soeg og compare til id1 og id2 og så lade være med at rette i koden og der melder den om samme fejl. Altså Runtime Error 13. Type mismatch.

Men du har rettet
Call CompareRecords(Me!Soeg, Me!txtCompare)
til
Call CompareRecords(Me!ID1, Me!ID2)

Ja

hmmm....går lige i tænkeboks ;o)

Tror nok jeg har fundet fejlen. Glemte at fortælle at det ID der bruges indeholder bogstaver. Har det ikke noget med det at gøre? *fløjt*

Næste fejl
Syntax Error (missing operator) in query expression 'Code = 152b0001'.

Runtime Error: 3075

Hvad hvis du afprøver koden direkte fra VBA-editoeren?
Prøv at trykke Ctrl+G
Herefter skriver du: Call CompareRecords(123, 456)
Ovenstående 2 numre skal selvfølgelig erstattes med nogle eksisterende numre.

Bogstaver...ja i høj grad...vent...

Jeg har prøvet at ændre den til String istedet for Long :)

Prøv denne så:

Public Function CompareRecords(ID1 As String, ID2 As String)
    Dim rs1 As DAO.Recordset
    Dim rs2 As DAO.Recordset
    Dim Besked As String, n As Byte
    Set rs1 = CurrentDb.OpenRecordset("Select * From OLS Where CODE = '" & ID1 & "'", dbOpenSnapshot)
    Set rs2 = CurrentDb.OpenRecordset("Select * From OLS Where CODE = '" & ID2 & "'", dbOpenSnapshot)
    For n = 0 To rs1.Fields.Count - 1
        If rs1(n) <> rs2(n) Then
            Besked = Besked & rs1(n).Name & " indeholder værdierne '" & rs1(n) & "' og '" & rs2(n) & "'" & vbNewLine
        End If
    Next n
    MsgBox Besked
    rs1.Close
    rs2.Close
    Set rs1 = Nothing
    Set rs2 = Nothing
End Function

ja, men der skal lige lidt mere end String til...disse 2 linier skal også rettes:
Set rs1 = CurrentDb.OpenRecordset("Select * From OLS Where CODE = '" & ID1 & "'", dbOpenSnapshot)
    Set rs2 = CurrentDb.OpenRecordset("Select * From OLS Where CODE = '" & ID2 & "'", dbOpenSnapshot)

Jups det virker :))
Takker :)

Ja det så jeg :)

pyh :o)

tak for point !! :)